git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.HTML
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.CommonAPI.Utils
  15   alias Pleroma.Web.MastodonAPI.AccountView
  16   alias Pleroma.Web.MastodonAPI.StatusView
  17   alias Pleroma.Web.MediaProxy
  18
  19   # TODO: Add cached version.
  20   defp get_replied_to_activities(activities) do
  21     activities
  22     |> Enum.map(fn
  23       %{data: %{"type" => "Create", "object" => object}} ->
  24         object = Object.normalize(object)
  25         object.data["inReplyTo"] != "" && object.data["inReplyTo"]
  26
  27       _ ->
  28         nil
  29     end)
  30     |> Enum.filter(& &1)
  31     |> Activity.create_by_object_ap_id()
  32     |> Repo.all()
  33     |> Enum.reduce(%{}, fn activity, acc ->
  34       object = Object.normalize(activity)
  35       Map.put(acc, object.data["id"], activity)
  36     end)
  37   end
  38
  39   defp get_user(ap_id) do
  40     cond do
  41       user = User.get_cached_by_ap_id(ap_id) ->
  42         user
  43
  44       user = User.get_by_guessed_nickname(ap_id) ->
  45         user
  46
  47       true ->
  48         User.error_user(ap_id)
  49     end
  50   end
  51
  52   defp get_context_id(%{data: %{"context_id" => context_id}}) when not is_nil(context_id),
  53     do: context_id
  54
  55   defp get_context_id(%{data: %{"context" => context}}) when is_binary(context),
  56     do: Utils.context_to_conversation_id(context)
  57
  58   defp get_context_id(_), do: nil
  59
  60   defp reblogged?(activity, user) do
  61     object = Object.normalize(activity) || %{}
  62     present?(user && user.ap_id in (object.data["announcements"] || []))
  63   end
  64
  65   def render("index.json", opts) do
  66     replied_to_activities = get_replied_to_activities(opts.activities)
  67
  68     opts.activities
  69     |> safe_render_many(
  70       StatusView,
  71       "status.json",
  72       Map.put(opts, :replied_to_activities, replied_to_activities)
  73     )
  74   end
  75
  76   def render(
  77         "status.json",
  78         %{activity: %{data: %{"type" => "Announce", "object" => _object}} = activity} = opts
  79       ) do
  80     user = get_user(activity.data["actor"])
  81     created_at = Utils.to_masto_date(activity.data["published"])
  82     activity_object = Object.normalize(activity)
  83
  84     reblogged_activity =
  85       Activity.create_by_object_ap_id(activity_object.data["id"])
  86       |> Activity.with_preloaded_bookmark(opts[:for])
  87       |> Repo.one()
  88
  89     reblogged = render("status.json", Map.put(opts, :activity, reblogged_activity))
  90
  91     favorited = opts[:for] && opts[:for].ap_id in (activity_object.data["likes"] || [])
  92
  93     bookmarked = Activity.get_bookmark(reblogged_activity, opts[:for]) != nil
  94
  95     mentions =
  96       activity.recipients
  97       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  98       |> Enum.filter(& &1)
  99       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 100
 101     %{
 102       id: to_string(activity.id),
 103       uri: activity_object.data["id"],
 104       url: activity_object.data["id"],
 105       account: AccountView.render("account.json", %{user: user}),
 106       in_reply_to_id: nil,
 107       in_reply_to_account_id: nil,
 108       reblog: reblogged,
 109       content: reblogged[:content] || "",
 110       created_at: created_at,
 111       reblogs_count: 0,
 112       replies_count: 0,
 113       favourites_count: 0,
 114       reblogged: reblogged?(reblogged_activity, opts[:for]),
 115       favourited: present?(favorited),
 116       bookmarked: present?(bookmarked),
 117       muted: false,
 118       pinned: pinned?(activity, user),
 119       sensitive: false,
 120       spoiler_text: "",
 121       visibility: "public",
 122       media_attachments: reblogged[:media_attachments] || [],
 123       mentions: mentions,
 124       tags: reblogged[:tags] || [],
 125       application: %{
 126         name: "Web",
 127         website: nil
 128       },
 129       language: nil,
 130       emojis: [],
 131       pleroma: %{
 132         local: activity.local
 133       }
 134     }
 135   end
 136
 137   def render("status.json", %{activity: %{data: %{"object" => _object}} = activity} = opts) do
 138     object = Object.normalize(activity)
 139
 140     user = get_user(activity.data["actor"])
 141
 142     like_count = object.data["like_count"] || 0
 143     announcement_count = object.data["announcement_count"] || 0
 144
 145     tags = object.data["tag"] || []
 146     sensitive = object.data["sensitive"] || Enum.member?(tags, "nsfw")
 147
 148     mentions =
 149       activity.recipients
 150       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 151       |> Enum.filter(& &1)
 152       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 153
 154     favorited = opts[:for] && opts[:for].ap_id in (object.data["likes"] || [])
 155
 156     bookmarked = Activity.get_bookmark(activity, opts[:for]) != nil
 157
 158     attachment_data = object.data["attachment"] || []
 159     attachments = render_many(attachment_data, StatusView, "attachment.json", as: :attachment)
 160
 161     created_at = Utils.to_masto_date(object.data["published"])
 162
 163     reply_to = get_reply_to(activity, opts)
 164
 165     reply_to_user = reply_to && get_user(reply_to.data["actor"])
 166
 167     content =
 168       object
 169       |> render_content()
 170
 171     content_html =
 172       content
 173       |> HTML.get_cached_scrubbed_html_for_activity(
 174         User.html_filter_policy(opts[:for]),
 175         activity,
 176         "mastoapi:content"
 177       )
 178
 179     content_plaintext =
 180       content
 181       |> HTML.get_cached_stripped_html_for_activity(
 182         activity,
 183         "mastoapi:content"
 184       )
 185
 186     summary = object.data["summary"] || ""
 187
 188     summary_html =
 189       summary
 190       |> HTML.get_cached_scrubbed_html_for_activity(
 191         User.html_filter_policy(opts[:for]),
 192         activity,
 193         "mastoapi:summary"
 194       )
 195
 196     summary_plaintext =
 197       summary
 198       |> HTML.get_cached_stripped_html_for_activity(
 199         activity,
 200         "mastoapi:summary"
 201       )
 202
 203     card = render("card.json", Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity))
 204
 205     url =
 206       if user.local do
 207         Pleroma.Web.Router.Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
 208       else
 209         object.data["external_url"] || object.data["id"]
 210       end
 211
 212     %{
 213       id: to_string(activity.id),
 214       uri: object.data["id"],
 215       url: url,
 216       account: AccountView.render("account.json", %{user: user}),
 217       in_reply_to_id: reply_to && to_string(reply_to.id),
 218       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 219       reblog: nil,
 220       card: card,
 221       content: content_html,
 222       created_at: created_at,
 223       reblogs_count: announcement_count,
 224       replies_count: object.data["repliesCount"] || 0,
 225       favourites_count: like_count,
 226       reblogged: reblogged?(activity, opts[:for]),
 227       favourited: present?(favorited),
 228       bookmarked: present?(bookmarked),
 229       muted: CommonAPI.thread_muted?(user, activity) || User.mutes?(opts[:for], user),
 230       pinned: pinned?(activity, user),
 231       sensitive: sensitive,
 232       spoiler_text: summary_html,
 233       visibility: get_visibility(object),
 234       media_attachments: attachments,
 235       poll: render("poll.json", %{object: object, for: opts[:for]}),
 236       mentions: mentions,
 237       tags: build_tags(tags),
 238       application: %{
 239         name: "Web",
 240         website: nil
 241       },
 242       language: nil,
 243       emojis: build_emojis(object.data["emoji"]),
 244       pleroma: %{
 245         local: activity.local,
 246         conversation_id: get_context_id(activity),
 247         in_reply_to_account_acct: reply_to_user && reply_to_user.nickname,
 248         content: %{"text/plain" => content_plaintext},
 249         spoiler_text: %{"text/plain" => summary_plaintext}
 250       }
 251     }
 252   end
 253
 254   def render("status.json", _) do
 255     nil
 256   end
 257
 258   def render("card.json", %{rich_media: rich_media, page_url: page_url}) do
 259     page_url_data = URI.parse(page_url)
 260
 261     page_url_data =
 262       if rich_media[:url] != nil do
 263         URI.merge(page_url_data, URI.parse(rich_media[:url]))
 264       else
 265         page_url_data
 266       end
 267
 268     page_url = page_url_data |> to_string
 269
 270     image_url =
 271       if rich_media[:image] != nil do
 272         URI.merge(page_url_data, URI.parse(rich_media[:image]))
 273         |> to_string
 274       else
 275         nil
 276       end
 277
 278     site_name = rich_media[:site_name] || page_url_data.host
 279
 280     %{
 281       type: "link",
 282       provider_name: site_name,
 283       provider_url: page_url_data.scheme <> "://" <> page_url_data.host,
 284       url: page_url,
 285       image: image_url |> MediaProxy.url(),
 286       title: rich_media[:title],
 287       description: rich_media[:description],
 288       pleroma: %{
 289         opengraph: rich_media
 290       }
 291     }
 292   end
 293
 294   def render("card.json", _) do
 295     nil
 296   end
 297
 298   def render("attachment.json", %{attachment: attachment}) do
 299     [attachment_url | _] = attachment["url"]
 300     media_type = attachment_url["mediaType"] || attachment_url["mimeType"] || "image"
 301     href = attachment_url["href"] |> MediaProxy.url()
 302
 303     type =
 304       cond do
 305         String.contains?(media_type, "image") -> "image"
 306         String.contains?(media_type, "video") -> "video"
 307         String.contains?(media_type, "audio") -> "audio"
 308         true -> "unknown"
 309       end
 310
 311     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 312
 313     %{
 314       id: to_string(attachment["id"] || hash_id),
 315       url: href,
 316       remote_url: href,
 317       preview_url: href,
 318       text_url: href,
 319       type: type,
 320       description: attachment["name"],
 321       pleroma: %{mime_type: media_type}
 322     }
 323   end
 324
 325   # TODO: Add tests for this view
 326   def render("poll.json", %{object: object} = opts) do
 327     {multiple, options} =
 328       case object.data do
 329         %{"anyOf" => options} when is_list(options) -> {true, options}
 330         %{"oneOf" => options} when is_list(options) -> {false, options}
 331         _ -> {nil, nil}
 332       end
 333
 334     if options do
 335       end_time =
 336         (object.data["closed"] || object.data["endTime"])
 337         |> NaiveDateTime.from_iso8601!()
 338
 339       votes_count = object.data["votes_count"] || 0
 340
 341       expired =
 342         end_time
 343         |> NaiveDateTime.compare(NaiveDateTime.utc_now())
 344         |> case do
 345           :lt -> true
 346           _ -> false
 347         end
 348
 349       options =
 350         Enum.map(options, fn %{"name" => name} = option ->
 351           name =
 352             HTML.filter_tags(
 353               name,
 354               User.html_filter_policy(opts[:for])
 355             )
 356
 357           %{title: name, votes_count: option["replies"]["votes_count"] || 0}
 358         end)
 359
 360       %{
 361         # Mastodon uses separate ids for polls, but an object can't have more than one poll embedded so object id is fine
 362         id: object.id,
 363         expires_at: Utils.to_masto_date(end_time),
 364         expired: expired,
 365         multiple: multiple,
 366         votes_count: votes_count,
 367         options: options,
 368         voted: false,
 369         emojis: build_emojis(object.data["emoji"])
 370       }
 371     else
 372       nil
 373     end
 374   end
 375
 376   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 377     object = Object.normalize(activity)
 378
 379     with nil <- replied_to_activities[object.data["inReplyTo"]] do
 380       # If user didn't participate in the thread
 381       Activity.get_in_reply_to_activity(activity)
 382     end
 383   end
 384
 385   def get_reply_to(%{data: %{"object" => _object}} = activity, _) do
 386     object = Object.normalize(activity)
 387
 388     if object.data["inReplyTo"] && object.data["inReplyTo"] != "" do
 389       Activity.get_create_by_object_ap_id(object.data["inReplyTo"])
 390     else
 391       nil
 392     end
 393   end
 394
 395   def get_visibility(object) do
 396     public = "https://www.w3.org/ns/activitystreams#Public"
 397     to = object.data["to"] || []
 398     cc = object.data["cc"] || []
 399
 400     cond do
 401       public in to ->
 402         "public"
 403
 404       public in cc ->
 405         "unlisted"
 406
 407       # this should use the sql for the object's activity
 408       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 409         "private"
 410
 411       length(cc) > 0 ->
 412         "private"
 413
 414       true ->
 415         "direct"
 416     end
 417   end
 418
 419   def render_content(%{data: %{"type" => "Video"}} = object) do
 420     with name when not is_nil(name) and name != "" <- object.data["name"] do
 421       "<p><a href=\"#{object.data["id"]}\">#{name}</a></p>#{object.data["content"]}"
 422     else
 423       _ -> object.data["content"] || ""
 424     end
 425   end
 426
 427   def render_content(%{data: %{"type" => object_type}} = object)
 428       when object_type in ["Article", "Page"] do
 429     with summary when not is_nil(summary) and summary != "" <- object.data["name"],
 430          url when is_bitstring(url) <- object.data["url"] do
 431       "<p><a href=\"#{url}\">#{summary}</a></p>#{object.data["content"]}"
 432     else
 433       _ -> object.data["content"] || ""
 434     end
 435   end
 436
 437   def render_content(object), do: object.data["content"] || ""
 438
 439   @doc """
 440   Builds a dictionary tags.
 441
 442   ## Examples
 443
 444   iex> Pleroma.Web.MastodonAPI.StatusView.build_tags(["fediverse", "nextcloud"])
 445   [{"name": "fediverse", "url": "/tag/fediverse"},
 446    {"name": "nextcloud", "url": "/tag/nextcloud"}]
 447
 448   """
 449   @spec build_tags(list(any())) :: list(map())
 450   def build_tags(object_tags) when is_list(object_tags) do
 451     object_tags = for tag when is_binary(tag) <- object_tags, do: tag
 452
 453     Enum.reduce(object_tags, [], fn tag, tags ->
 454       tags ++ [%{name: tag, url: "/tag/#{tag}"}]
 455     end)
 456   end
 457
 458   def build_tags(_), do: []
 459
 460   @doc """
 461   Builds list emojis.
 462
 463   Arguments: `nil` or list tuple of name and url.
 464
 465   Returns list emojis.
 466
 467   ## Examples
 468
 469   iex> Pleroma.Web.MastodonAPI.StatusView.build_emojis([{"2hu", "corndog.png"}])
 470   [%{shortcode: "2hu", static_url: "corndog.png", url: "corndog.png", visible_in_picker: false}]
 471
 472   """
 473   @spec build_emojis(nil | list(tuple())) :: list(map())
 474   def build_emojis(nil), do: []
 475
 476   def build_emojis(emojis) do
 477     emojis
 478     |> Enum.map(fn {name, url} ->
 479       name = HTML.strip_tags(name)
 480
 481       url =
 482         url
 483         |> HTML.strip_tags()
 484         |> MediaProxy.url()
 485
 486       %{shortcode: name, url: url, static_url: url, visible_in_picker: false}
 487     end)
 488   end
 489
 490   defp present?(nil), do: false
 491   defp present?(false), do: false
 492   defp present?(_), do: true
 493
 494   defp pinned?(%Activity{id: id}, %User{info: %{pinned_activities: pinned_activities}}),
 495     do: id in pinned_activities
 496 end