git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 defmodule Pleroma.Web.MastodonAPI.StatusView do
   2   use Pleroma.Web, :view
   3   alias Pleroma.Web.MastodonAPI.{AccountView, StatusView}
   4   alias Pleroma.{User, Activity}
   5   alias Pleroma.Web.CommonAPI.Utils
   6   alias Pleroma.Web.MediaProxy
   7   alias Pleroma.Repo
   8
   9   # TODO: Add cached version.
  10   defp get_replied_to_activities(activities) do
  11     activities
  12     |> Enum.map(fn
  13       %{data: %{"type" => "Create", "object" => %{"inReplyTo" => inReplyTo}}} ->
  14         inReplyTo != "" && inReplyTo
  15
  16       _ ->
  17         nil
  18     end)
  19     |> Enum.filter(& &1)
  20     |> Activity.create_activity_by_object_id_query()
  21     |> Repo.all()
  22     |> Enum.reduce(%{}, fn activity, acc ->
  23       Map.put(acc, activity.data["object"]["id"], activity)
  24     end)
  25   end
  26
  27   def render("index.json", opts) do
  28     replied_to_activities = get_replied_to_activities(opts.activities)
  29
  30     render_many(
  31       opts.activities,
  32       StatusView,
  33       "status.json",
  34       Map.put(opts, :replied_to_activities, replied_to_activities)
  35     )
  36   end
  37
  38   def render(
  39         "status.json",
  40         %{activity: %{data: %{"type" => "Announce", "object" => object}} = activity} = opts
  41       ) do
  42     user = User.get_cached_by_ap_id(activity.data["actor"])
  43     created_at = Utils.to_masto_date(activity.data["published"])
  44
  45     reblogged = Activity.get_create_activity_by_object_ap_id(object)
  46     reblogged = render("status.json", Map.put(opts, :activity, reblogged))
  47
  48     mentions =
  49       activity.recipients
  50       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  51       |> Enum.filter(& &1)
  52       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
  53
  54     %{
  55       id: to_string(activity.id),
  56       uri: object,
  57       # TODO: This might be wrong, check with mastodon.
  58       url: nil,
  59       account: AccountView.render("account.json", %{user: user}),
  60       in_reply_to_id: nil,
  61       in_reply_to_account_id: nil,
  62       reblog: reblogged,
  63       content: reblogged[:content],
  64       created_at: created_at,
  65       reblogs_count: 0,
  66       favourites_count: 0,
  67       reblogged: false,
  68       favourited: false,
  69       muted: false,
  70       sensitive: false,
  71       spoiler_text: "",
  72       visibility: "public",
  73       media_attachments: [],
  74       mentions: mentions,
  75       tags: [],
  76       application: %{
  77         name: "Web",
  78         website: nil
  79       },
  80       language: nil,
  81       emojis: []
  82     }
  83   end
  84
  85   def render("status.json", %{activity: %{data: %{"object" => object}} = activity} = opts) do
  86     user = User.get_cached_by_ap_id(activity.data["actor"])
  87
  88     like_count = object["like_count"] || 0
  89     announcement_count = object["announcement_count"] || 0
  90
  91     tags = object["tag"] || []
  92     sensitive = object["sensitive"] || Enum.member?(tags, "nsfw")
  93
  94     mentions =
  95       activity.recipients
  96       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  97       |> Enum.filter(& &1)
  98       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
  99
 100     repeated = opts[:for] && opts[:for].ap_id in (object["announcements"] || [])
 101     favorited = opts[:for] && opts[:for].ap_id in (object["likes"] || [])
 102
 103     attachments =
 104       render_many(object["attachment"] || [], StatusView, "attachment.json", as: :attachment)
 105
 106     created_at = Utils.to_masto_date(object["published"])
 107
 108     reply_to = get_reply_to(activity, opts)
 109     reply_to_user = reply_to && User.get_cached_by_ap_id(reply_to.data["actor"])
 110
 111     emojis =
 112       (activity.data["object"]["emoji"] || [])
 113       |> Enum.map(fn {name, url} ->
 114         name = HtmlSanitizeEx.strip_tags(name)
 115
 116         url =
 117           HtmlSanitizeEx.strip_tags(url)
 118           |> MediaProxy.url()
 119
 120         %{shortcode: name, url: url, static_url: url}
 121       end)
 122
 123     %{
 124       id: to_string(activity.id),
 125       uri: object["id"],
 126       url: object["external_url"] || object["id"],
 127       account: AccountView.render("account.json", %{user: user}),
 128       in_reply_to_id: reply_to && reply_to.id,
 129       in_reply_to_account_id: reply_to_user && reply_to_user.id,
 130       reblog: nil,
 131       content: HtmlSanitizeEx.basic_html(object["content"]),
 132       created_at: created_at,
 133       reblogs_count: announcement_count,
 134       favourites_count: like_count,
 135       reblogged: !!repeated,
 136       favourited: !!favorited,
 137       muted: false,
 138       sensitive: sensitive,
 139       spoiler_text: object["summary"] || "",
 140       visibility: get_visibility(object),
 141       media_attachments: attachments |> Enum.take(4),
 142       mentions: mentions,
 143       # fix,
 144       tags: [],
 145       application: %{
 146         name: "Web",
 147         website: nil
 148       },
 149       language: nil,
 150       emojis: emojis
 151     }
 152   end
 153
 154   def render("attachment.json", %{attachment: attachment}) do
 155     [%{"mediaType" => media_type, "href" => href} | _] = attachment["url"]
 156
 157     type =
 158       cond do
 159         String.contains?(media_type, "image") -> "image"
 160         String.contains?(media_type, "video") -> "video"
 161         String.contains?(media_type, "audio") -> "audio"
 162         true -> "unknown"
 163       end
 164
 165     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 166
 167     %{
 168       id: to_string(attachment["id"] || hash_id),
 169       url: MediaProxy.url(href),
 170       remote_url: href,
 171       preview_url: MediaProxy.url(href),
 172       text_url: href,
 173       type: type
 174     }
 175   end
 176
 177   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 178     _id = activity.data["object"]["inReplyTo"]
 179     replied_to_activities[activity.data["object"]["inReplyTo"]]
 180   end
 181
 182   def get_reply_to(%{data: %{"object" => object}}, _) do
 183     if object["inReplyTo"] && object["inReplyTo"] != "" do
 184       Activity.get_create_activity_by_object_ap_id(object["inReplyTo"])
 185     else
 186       nil
 187     end
 188   end
 189
 190   def get_visibility(object) do
 191     public = "https://www.w3.org/ns/activitystreams#Public"
 192     to = object["to"] || []
 193     cc = object["cc"] || []
 194
 195     cond do
 196       public in to -> "public"
 197       public in cc -> "unlisted"
 198           # this should use the sql for the object's activity
 199       Enum.any?(to, &String.contains?(&1, "/followers")) -> "private"
 200       true -> "direct"
 201     end
 202   end
 203 end