git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/notification_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.NotificationView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Notification
  10   alias Pleroma.User
  11   alias Pleroma.UserRelationship
  12   alias Pleroma.Web.CommonAPI
  13   alias Pleroma.Web.MastodonAPI.AccountView
  14   alias Pleroma.Web.MastodonAPI.NotificationView
  15   alias Pleroma.Web.MastodonAPI.StatusView
  16
  17   def render("index.json", %{notifications: notifications, for: reading_user} = opts) do
  18     activities = Enum.map(notifications, & &1.activity)
  19
  20     parent_activities =
  21       activities
  22       |> Enum.filter(
  23         &(Activity.mastodon_notification_type(&1) in [
  24             "favourite",
  25             "reblog",
  26             "pleroma:emoji_reaction"
  27           ])
  28       )
  29       |> Enum.map(& &1.data["object"])
  30       |> Activity.create_by_object_ap_id()
  31       |> Activity.with_preloaded_object(:left)
  32       |> Pleroma.Repo.all()
  33
  34     relationships_opt =
  35       if Map.has_key?(opts, :relationships) do
  36         opts[:relationships]
  37       else
  38         move_activities_targets =
  39           activities
  40           |> Enum.filter(&(Activity.mastodon_notification_type(&1) == "move"))
  41           |> Enum.map(&User.get_cached_by_ap_id(&1.data["target"]))
  42
  43         actors =
  44           activities
  45           |> Enum.map(fn a -> User.get_cached_by_ap_id(a.data["actor"]) end)
  46           |> Enum.filter(& &1)
  47           |> Kernel.++(move_activities_targets)
  48
  49         UserRelationship.view_relationships_option(reading_user, actors)
  50       end
  51
  52     opts = %{
  53       for: reading_user,
  54       parent_activities: parent_activities,
  55       relationships: relationships_opt
  56     }
  57
  58     safe_render_many(notifications, NotificationView, "show.json", opts)
  59   end
  60
  61   def render(
  62         "show.json",
  63         %{
  64           notification: %Notification{activity: activity} = notification,
  65           for: reading_user
  66         } = opts
  67       ) do
  68     actor = User.get_cached_by_ap_id(activity.data["actor"])
  69
  70     parent_activity_fn = fn ->
  71       if opts[:parent_activities] do
  72         Activity.Queries.find_by_object_ap_id(opts[:parent_activities], activity.data["object"])
  73       else
  74         Activity.get_create_by_object_ap_id(activity.data["object"])
  75       end
  76     end
  77
  78     mastodon_type = Activity.mastodon_notification_type(activity)
  79
  80     with %{id: _} = account <-
  81            AccountView.render("show.json", %{
  82              user: actor,
  83              for: reading_user,
  84              relationships: opts[:relationships]
  85            }) do
  86       response = %{
  87         id: to_string(notification.id),
  88         type: mastodon_type,
  89         created_at: CommonAPI.Utils.to_masto_date(notification.inserted_at),
  90         account: account,
  91         pleroma: %{
  92           is_seen: notification.seen
  93         }
  94       }
  95
  96       relationships_opt = %{relationships: opts[:relationships]}
  97
  98       case mastodon_type do
  99         "mention" ->
 100           put_status(response, activity, reading_user, relationships_opt)
 101
 102         "favourite" ->
 103           put_status(response, parent_activity_fn.(), reading_user, relationships_opt)
 104
 105         "reblog" ->
 106           put_status(response, parent_activity_fn.(), reading_user, relationships_opt)
 107
 108         "move" ->
 109           put_target(response, activity, reading_user, relationships_opt)
 110
 111         "follow" ->
 112           response
 113
 114         "pleroma:emoji_reaction" ->
 115           response
 116           |> put_status(parent_activity_fn.(), reading_user, relationships_opt)
 117           |> put_emoji(activity)
 118
 119         _ ->
 120           nil
 121       end
 122     else
 123       _ -> nil
 124     end
 125   end
 126
 127   defp put_emoji(response, activity) do
 128     Map.put(response, :emoji, activity.data["content"])
 129   end
 130
 131   defp put_status(response, activity, reading_user, opts) do
 132     status_render_opts = Map.merge(opts, %{activity: activity, for: reading_user})
 133     status_render = StatusView.render("show.json", status_render_opts)
 134
 135     Map.put(response, :status, status_render)
 136   end
 137
 138   defp put_target(response, activity, reading_user, opts) do
 139     target_user = User.get_cached_by_ap_id(activity.data["target"])
 140     target_render_opts = Map.merge(opts, %{user: target_user, for: reading_user})
 141     target_render = AccountView.render("show.json", target_render_opts)
 142
 143     Map.put(response, :target, target_render)
 144   end
 145 end