git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/instance_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.InstanceView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Web.ActivityPub.MRF
  10
  11   @mastodon_api_level "2.7.2"
  12
  13   def render("show.json", _) do
  14     instance = Config.get(:instance)
  15
  16     %{
  17       uri: Pleroma.Web.Endpoint.url(),
  18       title: Keyword.get(instance, :name),
  19       description: Keyword.get(instance, :description),
  20       version: "#{@mastodon_api_level} (compatible; #{Pleroma.Application.named_version()})",
  21       email: Keyword.get(instance, :email),
  22       urls: %{
  23         streaming_api: Pleroma.Web.Endpoint.websocket_url()
  24       },
  25       stats: Pleroma.Stats.get_stats(),
  26       thumbnail:
  27         URI.merge(Pleroma.Web.Endpoint.url(), Keyword.get(instance, :instance_thumbnail))
  28         |> to_string,
  29       languages: ["en"],
  30       registrations: Keyword.get(instance, :registrations_open),
  31       approval_required: Keyword.get(instance, :account_approval_required),
  32       # Extra (not present in Mastodon):
  33       max_toot_chars: Keyword.get(instance, :limit),
  34       poll_limits: Keyword.get(instance, :poll_limits),
  35       upload_limit: Keyword.get(instance, :upload_limit),
  36       avatar_upload_limit: Keyword.get(instance, :avatar_upload_limit),
  37       background_upload_limit: Keyword.get(instance, :background_upload_limit),
  38       banner_upload_limit: Keyword.get(instance, :banner_upload_limit),
  39       background_image: Pleroma.Web.Endpoint.url() <> Keyword.get(instance, :background_image),
  40       shout_limit: Config.get([:shout, :limit]),
  41       description_limit: Keyword.get(instance, :description_limit),
  42       pleroma: %{
  43         metadata: %{
  44           account_activation_required: Keyword.get(instance, :account_activation_required),
  45           features: features(),
  46           federation: federation(),
  47           fields_limits: fields_limits(),
  48           post_formats: Config.get([:instance, :allowed_post_formats])
  49         },
  50         stats: %{mau: Pleroma.User.active_user_count()},
  51         vapid_public_key: Keyword.get(Pleroma.Web.Push.vapid_config(), :public_key)
  52       }
  53     }
  54   end
  55
  56   def features do
  57     [
  58       "pleroma_api",
  59       "mastodon_api",
  60       "mastodon_api_streaming",
  61       "polls",
  62       "pleroma_explicit_addressing",
  63       "shareable_emoji_packs",
  64       "multifetch",
  65       "pleroma:api/v1/notifications:include_types_filter",
  66       if Config.get([:media_proxy, :enabled]) do
  67         "media_proxy"
  68       end,
  69       if Config.get([:gopher, :enabled]) do
  70         "gopher"
  71       end,
  72       # backwards compat
  73       if Config.get([:shout, :enabled]) do
  74         "chat"
  75       end,
  76       if Config.get([:shout, :enabled]) do
  77         "shout"
  78       end,
  79       if Config.get([:instance, :allow_relay]) do
  80         "relay"
  81       end,
  82       if Config.get([:instance, :safe_dm_mentions]) do
  83         "safe_dm_mentions"
  84       end,
  85       "pleroma_emoji_reactions",
  86       "pleroma_chat_messages"
  87     ]
  88     |> Enum.filter(& &1)
  89   end
  90
  91   def federation do
  92     quarantined = Config.get([:instance, :quarantined_instances], [])
  93
  94     if Config.get([:mrf, :transparency]) do
  95       {:ok, data} = MRF.describe()
  96
  97       data
  98       |> Map.merge(%{quarantined_instances: quarantined})
  99     else
 100       %{}
 101     end
 102     |> Map.put(:enabled, Config.get([:instance, :federating]))
 103   end
 104
 105   def fields_limits do
 106     %{
 107       max_fields: Config.get([:instance, :max_account_fields]),
 108       max_remote_fields: Config.get([:instance, :max_remote_account_fields]),
 109       name_length: Config.get([:instance, :account_field_name_length]),
 110       value_length: Config.get([:instance, :account_field_value_length])
 111     }
 112   end
 113 end