git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     relationships_opt =
  17       if Map.has_key?(opts, :relationships) do
  18         opts[:relationships]
  19       else
  20         UserRelationship.view_relationships_option(opts[:for], users)
  21       end
  22
  23     opts = Map.put(opts, :relationships, relationships_opt)
  24
  25     users
  26     |> render_many(AccountView, "show.json", opts)
  27     |> Enum.filter(&Enum.any?/1)
  28   end
  29
  30   def render("show.json", %{user: user} = opts) do
  31     if User.visible_for?(user, opts[:for]),
  32       do: do_render("show.json", opts),
  33       else: %{}
  34   end
  35
  36   def render("mention.json", %{user: user}) do
  37     %{
  38       id: to_string(user.id),
  39       acct: user.nickname,
  40       username: username_from_nickname(user.nickname),
  41       url: User.profile_url(user)
  42     }
  43   end
  44
  45   def render("relationship.json", %{user: nil, target: _target}) do
  46     %{}
  47   end
  48
  49   def render(
  50         "relationship.json",
  51         %{user: %User{} = reading_user, target: %User{} = target} = opts
  52       ) do
  53     user_relationships = get_in(opts, [:relationships, :user_relationships])
  54     following_relationships = get_in(opts, [:relationships, :following_relationships])
  55
  56     follow_state =
  57       if following_relationships do
  58         user_to_target_following_relation =
  59           FollowingRelationship.find(following_relationships, reading_user, target)
  60
  61         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  62       else
  63         User.get_follow_state(reading_user, target)
  64       end
  65
  66     followed_by =
  67       if following_relationships do
  68         case FollowingRelationship.find(following_relationships, target, reading_user) do
  69           %{state: "accept"} -> true
  70           _ -> false
  71         end
  72       else
  73         User.following?(target, reading_user)
  74       end
  75
  76     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
  77     %{
  78       id: to_string(target.id),
  79       following: follow_state == "accept",
  80       followed_by: followed_by,
  81       blocking:
  82         UserRelationship.exists?(
  83           user_relationships,
  84           :block,
  85           reading_user,
  86           target,
  87           &User.blocks_user?(&1, &2)
  88         ),
  89       blocked_by:
  90         UserRelationship.exists?(
  91           user_relationships,
  92           :block,
  93           target,
  94           reading_user,
  95           &User.blocks_user?(&1, &2)
  96         ),
  97       muting:
  98         UserRelationship.exists?(
  99           user_relationships,
 100           :mute,
 101           reading_user,
 102           target,
 103           &User.mutes?(&1, &2)
 104         ),
 105       muting_notifications:
 106         UserRelationship.exists?(
 107           user_relationships,
 108           :notification_mute,
 109           reading_user,
 110           target,
 111           &User.muted_notifications?(&1, &2)
 112         ),
 113       subscribing:
 114         UserRelationship.exists?(
 115           user_relationships,
 116           :inverse_subscription,
 117           target,
 118           reading_user,
 119           &User.subscribed_to?(&2, &1)
 120         ),
 121       requested: follow_state == "pending",
 122       domain_blocking: User.blocks_domain?(reading_user, target),
 123       showing_reblogs:
 124         not UserRelationship.exists?(
 125           user_relationships,
 126           :reblog_mute,
 127           reading_user,
 128           target,
 129           &User.muting_reblogs?(&1, &2)
 130         ),
 131       endorsed: false
 132     }
 133   end
 134
 135   def render("relationships.json", %{user: user, targets: targets} = opts) do
 136     relationships_opt =
 137       if Map.has_key?(opts, :relationships) do
 138         opts[:relationships]
 139       else
 140         UserRelationship.view_relationships_option(user, targets)
 141       end
 142
 143     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 144     render_many(targets, AccountView, "relationship.json", render_opts)
 145   end
 146
 147   defp do_render("show.json", %{user: user} = opts) do
 148     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 149     display_name = user.name || user.nickname
 150
 151     image = User.avatar_url(user) |> MediaProxy.url()
 152     header = User.banner_url(user) |> MediaProxy.url()
 153
 154     following_count =
 155       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 156         user.following_count || 0
 157       else
 158         0
 159       end
 160
 161     followers_count =
 162       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 163         user.follower_count || 0
 164       else
 165         0
 166       end
 167
 168     bot = user.actor_type in ["Application", "Service"]
 169
 170     emojis =
 171       (user.source_data["tag"] || [])
 172       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 173       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 174         %{
 175           "shortcode" => String.trim(name, ":"),
 176           "url" => MediaProxy.url(url),
 177           "static_url" => MediaProxy.url(url),
 178           "visible_in_picker" => false
 179         }
 180       end)
 181
 182     relationship =
 183       render("relationship.json", %{
 184         user: opts[:for],
 185         target: user,
 186         relationships: opts[:relationships]
 187       })
 188
 189     %{
 190       id: to_string(user.id),
 191       username: username_from_nickname(user.nickname),
 192       acct: user.nickname,
 193       display_name: display_name,
 194       locked: user.locked,
 195       created_at: Utils.to_masto_date(user.inserted_at),
 196       followers_count: followers_count,
 197       following_count: following_count,
 198       statuses_count: user.note_count,
 199       note: user.bio || "",
 200       url: User.profile_url(user),
 201       avatar: image,
 202       avatar_static: image,
 203       header: header,
 204       header_static: header,
 205       emojis: emojis,
 206       fields: user.fields,
 207       bot: bot,
 208       source: %{
 209         note: (user.bio || "") |> String.replace(~r(<br */?>), "\n") |> Pleroma.HTML.strip_tags(),
 210         sensitive: false,
 211         fields: user.raw_fields,
 212         pleroma: %{
 213           discoverable: user.discoverable,
 214           actor_type: user.actor_type
 215         }
 216       },
 217
 218       # Pleroma extension
 219       pleroma: %{
 220         confirmation_pending: user.confirmation_pending,
 221         tags: user.tags,
 222         hide_followers_count: user.hide_followers_count,
 223         hide_follows_count: user.hide_follows_count,
 224         hide_followers: user.hide_followers,
 225         hide_follows: user.hide_follows,
 226         hide_favorites: user.hide_favorites,
 227         relationship: relationship,
 228         skip_thread_containment: user.skip_thread_containment,
 229         background_image: image_url(user.background) |> MediaProxy.url()
 230       }
 231     }
 232     |> maybe_put_role(user, opts[:for])
 233     |> maybe_put_settings(user, opts[:for], opts)
 234     |> maybe_put_notification_settings(user, opts[:for])
 235     |> maybe_put_settings_store(user, opts[:for], opts)
 236     |> maybe_put_chat_token(user, opts[:for], opts)
 237     |> maybe_put_activation_status(user, opts[:for])
 238     |> maybe_put_follow_requests_count(user, opts[:for])
 239     |> maybe_put_allow_following_move(user, opts[:for])
 240     |> maybe_put_unread_conversation_count(user, opts[:for])
 241   end
 242
 243   defp username_from_nickname(string) when is_binary(string) do
 244     hd(String.split(string, "@"))
 245   end
 246
 247   defp username_from_nickname(_), do: nil
 248
 249   defp maybe_put_follow_requests_count(
 250          data,
 251          %User{id: user_id} = user,
 252          %User{id: user_id}
 253        ) do
 254     count =
 255       User.get_follow_requests(user)
 256       |> length()
 257
 258     data
 259     |> Kernel.put_in([:follow_requests_count], count)
 260   end
 261
 262   defp maybe_put_follow_requests_count(data, _, _), do: data
 263
 264   defp maybe_put_settings(
 265          data,
 266          %User{id: user_id} = user,
 267          %User{id: user_id},
 268          _opts
 269        ) do
 270     data
 271     |> Kernel.put_in([:source, :privacy], user.default_scope)
 272     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 273     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 274   end
 275
 276   defp maybe_put_settings(data, _, _, _), do: data
 277
 278   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 279          with_pleroma_settings: true
 280        }) do
 281     data
 282     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 283   end
 284
 285   defp maybe_put_settings_store(data, _, _, _), do: data
 286
 287   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 288          with_chat_token: token
 289        }) do
 290     data
 291     |> Kernel.put_in([:pleroma, :chat_token], token)
 292   end
 293
 294   defp maybe_put_chat_token(data, _, _, _), do: data
 295
 296   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 297     data
 298     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 299     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 300   end
 301
 302   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 303     data
 304     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 305     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 306   end
 307
 308   defp maybe_put_role(data, _, _), do: data
 309
 310   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 311     Kernel.put_in(data, [:pleroma, :notification_settings], user.notification_settings)
 312   end
 313
 314   defp maybe_put_notification_settings(data, _, _), do: data
 315
 316   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 317     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 318   end
 319
 320   defp maybe_put_allow_following_move(data, _, _), do: data
 321
 322   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 323     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 324   end
 325
 326   defp maybe_put_activation_status(data, _, _), do: data
 327
 328   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 329     data
 330     |> Kernel.put_in(
 331       [:pleroma, :unread_conversation_count],
 332       user.unread_conversation_count
 333     )
 334   end
 335
 336   defp maybe_put_unread_conversation_count(data, _, _), do: data
 337
 338   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 339   defp image_url(_), do: nil
 340 end