git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     relationships_opt =
  17       cond do
  18         Map.has_key?(opts, :relationships) ->
  19           opts[:relationships]
  20
  21         is_nil(opts[:for]) ->
  22           UserRelationship.view_relationships_option(nil, [])
  23
  24         true ->
  25           UserRelationship.view_relationships_option(opts[:for], users)
  26       end
  27
  28     opts = Map.put(opts, :relationships, relationships_opt)
  29
  30     users
  31     |> render_many(AccountView, "show.json", opts)
  32     |> Enum.filter(&Enum.any?/1)
  33   end
  34
  35   def render("show.json", %{user: user} = opts) do
  36     if User.visible_for?(user, opts[:for]),
  37       do: do_render("show.json", opts),
  38       else: %{}
  39   end
  40
  41   def render("mention.json", %{user: user}) do
  42     %{
  43       id: to_string(user.id),
  44       acct: user.nickname,
  45       username: username_from_nickname(user.nickname),
  46       url: user.uri || user.ap_id
  47     }
  48   end
  49
  50   def render("relationship.json", %{user: nil, target: _target}) do
  51     %{}
  52   end
  53
  54   def render(
  55         "relationship.json",
  56         %{user: %User{} = reading_user, target: %User{} = target} = opts
  57       ) do
  58     user_relationships = get_in(opts, [:relationships, :user_relationships])
  59     following_relationships = get_in(opts, [:relationships, :following_relationships])
  60
  61     follow_state =
  62       if following_relationships do
  63         user_to_target_following_relation =
  64           FollowingRelationship.find(following_relationships, reading_user, target)
  65
  66         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  67       else
  68         User.get_follow_state(reading_user, target)
  69       end
  70
  71     followed_by =
  72       if following_relationships do
  73         case FollowingRelationship.find(following_relationships, target, reading_user) do
  74           %{state: "accept"} -> true
  75           _ -> false
  76         end
  77       else
  78         User.following?(target, reading_user)
  79       end
  80
  81     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
  82     %{
  83       id: to_string(target.id),
  84       following: follow_state == "accept",
  85       followed_by: followed_by,
  86       blocking:
  87         UserRelationship.exists?(
  88           user_relationships,
  89           :block,
  90           reading_user,
  91           target,
  92           &User.blocks_user?(&1, &2)
  93         ),
  94       blocked_by:
  95         UserRelationship.exists?(
  96           user_relationships,
  97           :block,
  98           target,
  99           reading_user,
 100           &User.blocks_user?(&1, &2)
 101         ),
 102       muting:
 103         UserRelationship.exists?(
 104           user_relationships,
 105           :mute,
 106           reading_user,
 107           target,
 108           &User.mutes?(&1, &2)
 109         ),
 110       muting_notifications:
 111         UserRelationship.exists?(
 112           user_relationships,
 113           :notification_mute,
 114           reading_user,
 115           target,
 116           &User.muted_notifications?(&1, &2)
 117         ),
 118       subscribing:
 119         UserRelationship.exists?(
 120           user_relationships,
 121           :inverse_subscription,
 122           target,
 123           reading_user,
 124           &User.subscribed_to?(&2, &1)
 125         ),
 126       requested: follow_state == "pending",
 127       domain_blocking: User.blocks_domain?(reading_user, target),
 128       showing_reblogs:
 129         not UserRelationship.exists?(
 130           user_relationships,
 131           :reblog_mute,
 132           reading_user,
 133           target,
 134           &User.muting_reblogs?(&1, &2)
 135         ),
 136       endorsed: false
 137     }
 138   end
 139
 140   def render("relationships.json", %{user: user, targets: targets} = opts) do
 141     relationships_opt =
 142       cond do
 143         Map.has_key?(opts, :relationships) ->
 144           opts[:relationships]
 145
 146         is_nil(opts[:for]) ->
 147           UserRelationship.view_relationships_option(nil, [])
 148
 149         true ->
 150           UserRelationship.view_relationships_option(user, targets)
 151       end
 152
 153     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 154     render_many(targets, AccountView, "relationship.json", render_opts)
 155   end
 156
 157   defp do_render("show.json", %{user: user} = opts) do
 158     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 159     display_name = user.name || user.nickname
 160
 161     image = User.avatar_url(user) |> MediaProxy.url()
 162     header = User.banner_url(user) |> MediaProxy.url()
 163
 164     following_count =
 165       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 166         user.following_count || 0
 167       else
 168         0
 169       end
 170
 171     followers_count =
 172       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 173         user.follower_count || 0
 174       else
 175         0
 176       end
 177
 178     bot = user.actor_type in ["Application", "Service"]
 179
 180     emojis =
 181       (user.source_data["tag"] || [])
 182       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 183       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 184         %{
 185           "shortcode" => String.trim(name, ":"),
 186           "url" => MediaProxy.url(url),
 187           "static_url" => MediaProxy.url(url),
 188           "visible_in_picker" => false
 189         }
 190       end)
 191
 192     relationship =
 193       render("relationship.json", %{
 194         user: opts[:for],
 195         target: user,
 196         relationships: opts[:relationships]
 197       })
 198
 199     %{
 200       id: to_string(user.id),
 201       username: username_from_nickname(user.nickname),
 202       acct: user.nickname,
 203       display_name: display_name,
 204       locked: user.locked,
 205       created_at: Utils.to_masto_date(user.inserted_at),
 206       followers_count: followers_count,
 207       following_count: following_count,
 208       statuses_count: user.note_count,
 209       note: user.bio || "",
 210       url: user.uri || user.ap_id,
 211       avatar: image,
 212       avatar_static: image,
 213       header: header,
 214       header_static: header,
 215       emojis: emojis,
 216       fields: user.fields,
 217       bot: bot,
 218       source: %{
 219         note: (user.bio || "") |> String.replace(~r(<br */?>), "\n") |> Pleroma.HTML.strip_tags(),
 220         sensitive: false,
 221         fields: user.raw_fields,
 222         pleroma: %{
 223           discoverable: user.discoverable,
 224           actor_type: user.actor_type
 225         }
 226       },
 227
 228       # Pleroma extension
 229       pleroma: %{
 230         confirmation_pending: user.confirmation_pending,
 231         tags: user.tags,
 232         hide_followers_count: user.hide_followers_count,
 233         hide_follows_count: user.hide_follows_count,
 234         hide_followers: user.hide_followers,
 235         hide_follows: user.hide_follows,
 236         hide_favorites: user.hide_favorites,
 237         relationship: relationship,
 238         skip_thread_containment: user.skip_thread_containment,
 239         background_image: image_url(user.background) |> MediaProxy.url()
 240       }
 241     }
 242     |> maybe_put_role(user, opts[:for])
 243     |> maybe_put_settings(user, opts[:for], opts)
 244     |> maybe_put_notification_settings(user, opts[:for])
 245     |> maybe_put_settings_store(user, opts[:for], opts)
 246     |> maybe_put_chat_token(user, opts[:for], opts)
 247     |> maybe_put_activation_status(user, opts[:for])
 248     |> maybe_put_follow_requests_count(user, opts[:for])
 249     |> maybe_put_allow_following_move(user, opts[:for])
 250     |> maybe_put_unread_conversation_count(user, opts[:for])
 251   end
 252
 253   defp username_from_nickname(string) when is_binary(string) do
 254     hd(String.split(string, "@"))
 255   end
 256
 257   defp username_from_nickname(_), do: nil
 258
 259   defp maybe_put_follow_requests_count(
 260          data,
 261          %User{id: user_id} = user,
 262          %User{id: user_id}
 263        ) do
 264     count =
 265       User.get_follow_requests(user)
 266       |> length()
 267
 268     data
 269     |> Kernel.put_in([:follow_requests_count], count)
 270   end
 271
 272   defp maybe_put_follow_requests_count(data, _, _), do: data
 273
 274   defp maybe_put_settings(
 275          data,
 276          %User{id: user_id} = user,
 277          %User{id: user_id},
 278          _opts
 279        ) do
 280     data
 281     |> Kernel.put_in([:source, :privacy], user.default_scope)
 282     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 283     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 284   end
 285
 286   defp maybe_put_settings(data, _, _, _), do: data
 287
 288   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 289          with_pleroma_settings: true
 290        }) do
 291     data
 292     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 293   end
 294
 295   defp maybe_put_settings_store(data, _, _, _), do: data
 296
 297   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 298          with_chat_token: token
 299        }) do
 300     data
 301     |> Kernel.put_in([:pleroma, :chat_token], token)
 302   end
 303
 304   defp maybe_put_chat_token(data, _, _, _), do: data
 305
 306   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 307     data
 308     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 309     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 310   end
 311
 312   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 313     data
 314     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 315     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 316   end
 317
 318   defp maybe_put_role(data, _, _), do: data
 319
 320   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 321     Kernel.put_in(data, [:pleroma, :notification_settings], user.notification_settings)
 322   end
 323
 324   defp maybe_put_notification_settings(data, _, _), do: data
 325
 326   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 327     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 328   end
 329
 330   defp maybe_put_allow_following_move(data, _, _), do: data
 331
 332   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 333     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 334   end
 335
 336   defp maybe_put_activation_status(data, _, _), do: data
 337
 338   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 339     data
 340     |> Kernel.put_in(
 341       [:pleroma, :unread_conversation_count],
 342       user.unread_conversation_count
 343     )
 344   end
 345
 346   defp maybe_put_unread_conversation_count(data, _, _), do: data
 347
 348   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 349   defp image_url(_), do: nil
 350 end