git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.HTML
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MastodonAPI.AccountView
  12   alias Pleroma.Web.MediaProxy
  13
  14   def render("accounts.json", %{users: users} = opts) do
  15     users
  16     |> render_many(AccountView, "account.json", opts)
  17     |> Enum.filter(&Enum.any?/1)
  18   end
  19
  20   def render("account.json", %{user: user} = opts) do
  21     if User.visible_for?(user, opts[:for]),
  22       do: do_render("account.json", opts),
  23       else: %{}
  24   end
  25
  26   def render("mention.json", %{user: user}) do
  27     %{
  28       id: to_string(user.id),
  29       acct: user.nickname,
  30       username: username_from_nickname(user.nickname),
  31       url: User.profile_url(user)
  32     }
  33   end
  34
  35   def render("relationship.json", %{user: nil, target: _target}) do
  36     %{}
  37   end
  38
  39   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  40     follow_activity = Pleroma.Web.ActivityPub.Utils.fetch_latest_follow(user, target)
  41
  42     requested =
  43       if follow_activity && !User.following?(target, user) do
  44         follow_activity.data["state"] == "pending"
  45       else
  46         false
  47       end
  48
  49     %{
  50       id: to_string(target.id),
  51       following: User.following?(user, target),
  52       followed_by: User.following?(target, user),
  53       blocking: User.blocks_ap_id?(user, target),
  54       blocked_by: User.blocks_ap_id?(target, user),
  55       muting: User.mutes?(user, target),
  56       muting_notifications: User.muted_notifications?(user, target),
  57       subscribing: User.subscribed_to?(user, target),
  58       requested: requested,
  59       domain_blocking: User.blocks_domain?(user, target),
  60       showing_reblogs: User.showing_reblogs?(user, target),
  61       endorsed: false
  62     }
  63   end
  64
  65   def render("relationships.json", %{user: user, targets: targets}) do
  66     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  67   end
  68
  69   defp do_render("account.json", %{user: user} = opts) do
  70     display_name = HTML.strip_tags(user.name || user.nickname)
  71
  72     image = User.avatar_url(user) |> MediaProxy.url()
  73     header = User.banner_url(user) |> MediaProxy.url()
  74     user_info = User.get_cached_user_info(user)
  75
  76     following_count =
  77       ((!user.info.hide_follows or opts[:for] == user) && user_info.following_count) || 0
  78
  79     followers_count =
  80       ((!user.info.hide_followers or opts[:for] == user) && user_info.follower_count) || 0
  81
  82     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  83
  84     emojis =
  85       (user.info.source_data["tag"] || [])
  86       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  87       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  88         %{
  89           "shortcode" => String.trim(name, ":"),
  90           "url" => MediaProxy.url(url),
  91           "static_url" => MediaProxy.url(url),
  92           "visible_in_picker" => false
  93         }
  94       end)
  95
  96     fields =
  97       user.info
  98       |> User.Info.fields()
  99       |> Enum.map(fn %{"name" => name, "value" => value} ->
 100         %{
 101           "name" => Pleroma.HTML.strip_tags(name),
 102           "value" => Pleroma.HTML.filter_tags(value, Pleroma.HTML.Scrubber.LinksOnly)
 103         }
 104       end)
 105
 106     raw_fields = Map.get(user.info, :raw_fields, [])
 107
 108     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
 109     relationship = render("relationship.json", %{user: opts[:for], target: user})
 110
 111     %{
 112       id: to_string(user.id),
 113       username: username_from_nickname(user.nickname),
 114       acct: user.nickname,
 115       display_name: display_name,
 116       locked: user_info.locked,
 117       created_at: Utils.to_masto_date(user.inserted_at),
 118       followers_count: followers_count,
 119       following_count: following_count,
 120       statuses_count: user_info.note_count,
 121       note: bio || "",
 122       url: User.profile_url(user),
 123       avatar: image,
 124       avatar_static: image,
 125       header: header,
 126       header_static: header,
 127       emojis: emojis,
 128       fields: fields,
 129       bot: bot,
 130       source: %{
 131         note: HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
 132         sensitive: false,
 133         fields: raw_fields,
 134         pleroma: %{}
 135       },
 136
 137       # Pleroma extension
 138       pleroma: %{
 139         confirmation_pending: user_info.confirmation_pending,
 140         tags: user.tags,
 141         hide_followers: user.info.hide_followers,
 142         hide_follows: user.info.hide_follows,
 143         hide_favorites: user.info.hide_favorites,
 144         relationship: relationship,
 145         skip_thread_containment: user.info.skip_thread_containment,
 146         background_image: image_url(user.info.background) |> MediaProxy.url()
 147       }
 148     }
 149     |> maybe_put_role(user, opts[:for])
 150     |> maybe_put_settings(user, opts[:for], user_info)
 151     |> maybe_put_notification_settings(user, opts[:for])
 152     |> maybe_put_settings_store(user, opts[:for], opts)
 153     |> maybe_put_chat_token(user, opts[:for], opts)
 154     |> maybe_put_activation_status(user, opts[:for])
 155   end
 156
 157   defp username_from_nickname(string) when is_binary(string) do
 158     hd(String.split(string, "@"))
 159   end
 160
 161   defp username_from_nickname(_), do: nil
 162
 163   defp maybe_put_settings(
 164          data,
 165          %User{id: user_id} = user,
 166          %User{id: user_id},
 167          user_info
 168        ) do
 169     data
 170     |> Kernel.put_in([:source, :privacy], user_info.default_scope)
 171     |> Kernel.put_in([:source, :pleroma, :show_role], user.info.show_role)
 172     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.info.no_rich_text)
 173   end
 174
 175   defp maybe_put_settings(data, _, _, _), do: data
 176
 177   defp maybe_put_settings_store(data, %User{info: info, id: id}, %User{id: id}, %{
 178          with_pleroma_settings: true
 179        }) do
 180     data
 181     |> Kernel.put_in([:pleroma, :settings_store], info.pleroma_settings_store)
 182   end
 183
 184   defp maybe_put_settings_store(data, _, _, _), do: data
 185
 186   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 187          with_chat_token: token
 188        }) do
 189     data
 190     |> Kernel.put_in([:pleroma, :chat_token], token)
 191   end
 192
 193   defp maybe_put_chat_token(data, _, _, _), do: data
 194
 195   defp maybe_put_role(data, %User{info: %{show_role: true}} = user, _) do
 196     data
 197     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 198     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 199   end
 200
 201   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 202     data
 203     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 204     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 205   end
 206
 207   defp maybe_put_role(data, _, _), do: data
 208
 209   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 210     Kernel.put_in(data, [:pleroma, :notification_settings], user.info.notification_settings)
 211   end
 212
 213   defp maybe_put_notification_settings(data, _, _), do: data
 214
 215   defp maybe_put_activation_status(data, user, %User{info: %{is_admin: true}}) do
 216     Kernel.put_in(data, [:pleroma, :deactivated], user.info.deactivated)
 217   end
 218
 219   defp maybe_put_activation_status(data, _, _), do: data
 220
 221   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 222   defp image_url(_), do: nil
 223 end