git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.HTML
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MastodonAPI.AccountView
  12   alias Pleroma.Web.MediaProxy
  13
  14   def render("accounts.json", %{users: users} = opts) do
  15     users
  16     |> render_many(AccountView, "account.json", opts)
  17     |> Enum.filter(&Enum.any?/1)
  18   end
  19
  20   def render("account.json", %{user: user} = opts) do
  21     if User.visible_for?(user, opts[:for]),
  22       do: do_render("account.json", opts),
  23       else: %{}
  24   end
  25
  26   def render("mention.json", %{user: user}) do
  27     %{
  28       id: to_string(user.id),
  29       acct: user.nickname,
  30       username: username_from_nickname(user.nickname),
  31       url: User.profile_url(user)
  32     }
  33   end
  34
  35   def render("relationship.json", %{user: nil, target: _target}) do
  36     %{}
  37   end
  38
  39   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  40     follow_activity = Pleroma.Web.ActivityPub.Utils.fetch_latest_follow(user, target)
  41
  42     requested =
  43       if follow_activity && !User.following?(target, user) do
  44         follow_activity.data["state"] == "pending"
  45       else
  46         false
  47       end
  48
  49     %{
  50       id: to_string(target.id),
  51       following: User.following?(user, target),
  52       followed_by: User.following?(target, user),
  53       blocking: User.blocks_ap_id?(user, target),
  54       blocked_by: User.blocks_ap_id?(target, user),
  55       muting: User.mutes?(user, target),
  56       muting_notifications: User.muted_notifications?(user, target),
  57       subscribing: User.subscribed_to?(user, target),
  58       requested: requested,
  59       domain_blocking: User.blocks_domain?(user, target),
  60       showing_reblogs: User.showing_reblogs?(user, target),
  61       endorsed: false
  62     }
  63   end
  64
  65   def render("relationships.json", %{user: user, targets: targets}) do
  66     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  67   end
  68
  69   defp do_render("account.json", %{user: user} = opts) do
  70     display_name = HTML.strip_tags(user.name || user.nickname)
  71
  72     image = User.avatar_url(user) |> MediaProxy.url()
  73     header = User.banner_url(user) |> MediaProxy.url()
  74     user_info = User.get_cached_user_info(user)
  75
  76     following_count =
  77       ((!user.info.hide_follows or opts[:for] == user) && user_info.following_count) || 0
  78
  79     followers_count =
  80       ((!user.info.hide_followers or opts[:for] == user) && user_info.follower_count) || 0
  81
  82     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  83
  84     emojis =
  85       (user.info.source_data["tag"] || [])
  86       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  87       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  88         %{
  89           "shortcode" => String.trim(name, ":"),
  90           "url" => MediaProxy.url(url),
  91           "static_url" => MediaProxy.url(url),
  92           "visible_in_picker" => false
  93         }
  94       end)
  95
  96     fields = User.Info.fields(user.info)
  97     fields_html = Enum.map(fields, fn f -> Map.update!(f, "value", &AutoLinker.link(&1)) end)
  98
  99     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
 100
 101     relationship = render("relationship.json", %{user: opts[:for], target: user})
 102
 103     %{
 104       id: to_string(user.id),
 105       username: username_from_nickname(user.nickname),
 106       acct: user.nickname,
 107       display_name: display_name,
 108       locked: user_info.locked,
 109       created_at: Utils.to_masto_date(user.inserted_at),
 110       followers_count: followers_count,
 111       following_count: following_count,
 112       statuses_count: user_info.note_count,
 113       note: bio || "",
 114       url: User.profile_url(user),
 115       avatar: image,
 116       avatar_static: image,
 117       header: header,
 118       header_static: header,
 119       emojis: emojis,
 120       fields: fields_html,
 121       bot: bot,
 122       source: %{
 123         note: HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
 124         sensitive: false,
 125         fields: fields,
 126         pleroma: %{}
 127       },
 128
 129       # Pleroma extension
 130       pleroma: %{
 131         confirmation_pending: user_info.confirmation_pending,
 132         tags: user.tags,
 133         hide_followers: user.info.hide_followers,
 134         hide_follows: user.info.hide_follows,
 135         hide_favorites: user.info.hide_favorites,
 136         relationship: relationship,
 137         skip_thread_containment: user.info.skip_thread_containment,
 138         background_image: image_url(user.info.background) |> MediaProxy.url()
 139       }
 140     }
 141     |> maybe_put_role(user, opts[:for])
 142     |> maybe_put_settings(user, opts[:for], user_info)
 143     |> maybe_put_notification_settings(user, opts[:for])
 144     |> maybe_put_settings_store(user, opts[:for], opts)
 145     |> maybe_put_chat_token(user, opts[:for], opts)
 146     |> maybe_put_activation_status(user, opts[:for])
 147   end
 148
 149   defp username_from_nickname(string) when is_binary(string) do
 150     hd(String.split(string, "@"))
 151   end
 152
 153   defp username_from_nickname(_), do: nil
 154
 155   defp maybe_put_settings(
 156          data,
 157          %User{id: user_id} = user,
 158          %User{id: user_id},
 159          user_info
 160        ) do
 161     data
 162     |> Kernel.put_in([:source, :privacy], user_info.default_scope)
 163     |> Kernel.put_in([:source, :pleroma, :show_role], user.info.show_role)
 164     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.info.no_rich_text)
 165   end
 166
 167   defp maybe_put_settings(data, _, _, _), do: data
 168
 169   defp maybe_put_settings_store(data, %User{info: info, id: id}, %User{id: id}, %{
 170          with_pleroma_settings: true
 171        }) do
 172     data
 173     |> Kernel.put_in([:pleroma, :settings_store], info.pleroma_settings_store)
 174   end
 175
 176   defp maybe_put_settings_store(data, _, _, _), do: data
 177
 178   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 179          with_chat_token: token
 180        }) do
 181     data
 182     |> Kernel.put_in([:pleroma, :chat_token], token)
 183   end
 184
 185   defp maybe_put_chat_token(data, _, _, _), do: data
 186
 187   defp maybe_put_role(data, %User{info: %{show_role: true}} = user, _) do
 188     data
 189     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 190     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 191   end
 192
 193   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 194     data
 195     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 196     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 197   end
 198
 199   defp maybe_put_role(data, _, _), do: data
 200
 201   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 202     Kernel.put_in(data, [:pleroma, :notification_settings], user.info.notification_settings)
 203   end
 204
 205   defp maybe_put_notification_settings(data, _, _), do: data
 206
 207   defp maybe_put_activation_status(data, user, %User{info: %{is_admin: true}}) do
 208     Kernel.put_in(data, [:pleroma, :deactivated], user.info.deactivated)
 209   end
 210
 211   defp maybe_put_activation_status(data, _, _), do: data
 212
 213   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 214   defp image_url(_), do: nil
 215 end