git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     reading_user = opts[:for]
  17
  18     # Note: :skip_relationships option is currently intentionally not supported for accounts
  19     relationships_opt =
  20       cond do
  21         Map.has_key?(opts, :relationships) ->
  22           opts[:relationships]
  23
  24         is_nil(reading_user) ->
  25           UserRelationship.view_relationships_option(nil, [])
  26
  27         true ->
  28           UserRelationship.view_relationships_option(reading_user, users)
  29       end
  30
  31     opts = Map.put(opts, :relationships, relationships_opt)
  32
  33     users
  34     |> render_many(AccountView, "show.json", opts)
  35     |> Enum.filter(&Enum.any?/1)
  36   end
  37
  38   def render("show.json", %{user: user} = opts) do
  39     if User.visible_for?(user, opts[:for]) do
  40       do_render("show.json", opts)
  41     else
  42       %{}
  43     end
  44   end
  45
  46   def render("mention.json", %{user: user}) do
  47     %{
  48       id: to_string(user.id),
  49       acct: user.nickname,
  50       username: username_from_nickname(user.nickname),
  51       url: user.uri || user.ap_id
  52     }
  53   end
  54
  55   def render("relationship.json", %{user: nil, target: _target}) do
  56     %{}
  57   end
  58
  59   def render(
  60         "relationship.json",
  61         %{user: %User{} = reading_user, target: %User{} = target} = opts
  62       ) do
  63     user_relationships = get_in(opts, [:relationships, :user_relationships])
  64     following_relationships = get_in(opts, [:relationships, :following_relationships])
  65
  66     follow_state =
  67       if following_relationships do
  68         user_to_target_following_relation =
  69           FollowingRelationship.find(following_relationships, reading_user, target)
  70
  71         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  72       else
  73         User.get_follow_state(reading_user, target)
  74       end
  75
  76     followed_by =
  77       if following_relationships do
  78         case FollowingRelationship.find(following_relationships, target, reading_user) do
  79           %{state: :follow_accept} -> true
  80           _ -> false
  81         end
  82       else
  83         User.following?(target, reading_user)
  84       end
  85
  86     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
  87     %{
  88       id: to_string(target.id),
  89       following: follow_state == :follow_accept,
  90       followed_by: followed_by,
  91       blocking:
  92         UserRelationship.exists?(
  93           user_relationships,
  94           :block,
  95           reading_user,
  96           target,
  97           &User.blocks_user?(&1, &2)
  98         ),
  99       blocked_by:
 100         UserRelationship.exists?(
 101           user_relationships,
 102           :block,
 103           target,
 104           reading_user,
 105           &User.blocks_user?(&1, &2)
 106         ),
 107       muting:
 108         UserRelationship.exists?(
 109           user_relationships,
 110           :mute,
 111           reading_user,
 112           target,
 113           &User.mutes?(&1, &2)
 114         ),
 115       muting_notifications:
 116         UserRelationship.exists?(
 117           user_relationships,
 118           :notification_mute,
 119           reading_user,
 120           target,
 121           &User.muted_notifications?(&1, &2)
 122         ),
 123       subscribing:
 124         UserRelationship.exists?(
 125           user_relationships,
 126           :inverse_subscription,
 127           target,
 128           reading_user,
 129           &User.subscribed_to?(&2, &1)
 130         ),
 131       requested: follow_state == :follow_pending,
 132       domain_blocking: User.blocks_domain?(reading_user, target),
 133       showing_reblogs:
 134         not UserRelationship.exists?(
 135           user_relationships,
 136           :reblog_mute,
 137           reading_user,
 138           target,
 139           &User.muting_reblogs?(&1, &2)
 140         ),
 141       endorsed: false
 142     }
 143   end
 144
 145   def render("relationships.json", %{user: user, targets: targets} = opts) do
 146     relationships_opt =
 147       cond do
 148         Map.has_key?(opts, :relationships) ->
 149           opts[:relationships]
 150
 151         is_nil(user) ->
 152           UserRelationship.view_relationships_option(nil, [])
 153
 154         true ->
 155           UserRelationship.view_relationships_option(user, targets)
 156       end
 157
 158     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 159     render_many(targets, AccountView, "relationship.json", render_opts)
 160   end
 161
 162   defp do_render("show.json", %{user: user} = opts) do
 163     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 164     display_name = user.name || user.nickname
 165
 166     image = User.avatar_url(user) |> MediaProxy.url()
 167     header = User.banner_url(user) |> MediaProxy.url()
 168
 169     following_count =
 170       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 171         user.following_count || 0
 172       else
 173         0
 174       end
 175
 176     followers_count =
 177       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 178         user.follower_count || 0
 179       else
 180         0
 181       end
 182
 183     bot = user.actor_type in ["Application", "Service"]
 184
 185     emojis =
 186       Enum.map(user.emoji, fn {shortcode, url} ->
 187         %{
 188           "shortcode" => shortcode,
 189           "url" => url,
 190           "static_url" => url,
 191           "visible_in_picker" => false
 192         }
 193       end)
 194
 195     relationship =
 196       if opts[:skip_relationships] do
 197         %{}
 198       else
 199         render("relationship.json", %{
 200           user: opts[:for],
 201           target: user,
 202           relationships: opts[:relationships]
 203         })
 204       end
 205
 206     %{
 207       id: to_string(user.id),
 208       username: username_from_nickname(user.nickname),
 209       acct: user.nickname,
 210       display_name: display_name,
 211       locked: user.locked,
 212       created_at: Utils.to_masto_date(user.inserted_at),
 213       followers_count: followers_count,
 214       following_count: following_count,
 215       statuses_count: user.note_count,
 216       note: user.bio || "",
 217       url: user.uri || user.ap_id,
 218       avatar: image,
 219       avatar_static: image,
 220       header: header,
 221       header_static: header,
 222       emojis: emojis,
 223       fields: user.fields,
 224       bot: bot,
 225       source: %{
 226         note: prepare_user_bio(user),
 227         sensitive: false,
 228         fields: user.raw_fields,
 229         pleroma: %{
 230           discoverable: user.discoverable,
 231           actor_type: user.actor_type
 232         }
 233       },
 234
 235       # Pleroma extension
 236       pleroma: %{
 237         confirmation_pending: user.confirmation_pending,
 238         tags: user.tags,
 239         hide_followers_count: user.hide_followers_count,
 240         hide_follows_count: user.hide_follows_count,
 241         hide_followers: user.hide_followers,
 242         hide_follows: user.hide_follows,
 243         hide_favorites: user.hide_favorites,
 244         relationship: relationship,
 245         skip_thread_containment: user.skip_thread_containment,
 246         background_image: image_url(user.background) |> MediaProxy.url()
 247       }
 248     }
 249     |> maybe_put_role(user, opts[:for])
 250     |> maybe_put_settings(user, opts[:for], opts)
 251     |> maybe_put_notification_settings(user, opts[:for])
 252     |> maybe_put_settings_store(user, opts[:for], opts)
 253     |> maybe_put_chat_token(user, opts[:for], opts)
 254     |> maybe_put_activation_status(user, opts[:for])
 255     |> maybe_put_follow_requests_count(user, opts[:for])
 256     |> maybe_put_allow_following_move(user, opts[:for])
 257     |> maybe_put_unread_conversation_count(user, opts[:for])
 258     |> maybe_put_unread_notification_count(user, opts[:for])
 259   end
 260
 261   defp prepare_user_bio(%User{bio: ""}), do: ""
 262
 263   defp prepare_user_bio(%User{bio: bio}) when is_binary(bio) do
 264     bio
 265     |> String.replace(~r(<br */?>), "\n")
 266     |> Pleroma.HTML.strip_tags()
 267     |> HtmlEntities.decode()
 268   end
 269
 270   defp prepare_user_bio(_), do: ""
 271
 272   defp username_from_nickname(string) when is_binary(string) do
 273     hd(String.split(string, "@"))
 274   end
 275
 276   defp username_from_nickname(_), do: nil
 277
 278   defp maybe_put_follow_requests_count(
 279          data,
 280          %User{id: user_id} = user,
 281          %User{id: user_id}
 282        ) do
 283     count =
 284       User.get_follow_requests(user)
 285       |> length()
 286
 287     data
 288     |> Kernel.put_in([:follow_requests_count], count)
 289   end
 290
 291   defp maybe_put_follow_requests_count(data, _, _), do: data
 292
 293   defp maybe_put_settings(
 294          data,
 295          %User{id: user_id} = user,
 296          %User{id: user_id},
 297          _opts
 298        ) do
 299     data
 300     |> Kernel.put_in([:source, :privacy], user.default_scope)
 301     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 302     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 303   end
 304
 305   defp maybe_put_settings(data, _, _, _), do: data
 306
 307   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 308          with_pleroma_settings: true
 309        }) do
 310     data
 311     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 312   end
 313
 314   defp maybe_put_settings_store(data, _, _, _), do: data
 315
 316   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 317          with_chat_token: token
 318        }) do
 319     data
 320     |> Kernel.put_in([:pleroma, :chat_token], token)
 321   end
 322
 323   defp maybe_put_chat_token(data, _, _, _), do: data
 324
 325   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 326     data
 327     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 328     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 329   end
 330
 331   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 332     data
 333     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 334     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 335   end
 336
 337   defp maybe_put_role(data, _, _), do: data
 338
 339   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 340     Kernel.put_in(
 341       data,
 342       [:pleroma, :notification_settings],
 343       Map.from_struct(user.notification_settings)
 344     )
 345   end
 346
 347   defp maybe_put_notification_settings(data, _, _), do: data
 348
 349   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 350     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 351   end
 352
 353   defp maybe_put_allow_following_move(data, _, _), do: data
 354
 355   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 356     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 357   end
 358
 359   defp maybe_put_activation_status(data, _, _), do: data
 360
 361   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 362     data
 363     |> Kernel.put_in(
 364       [:pleroma, :unread_conversation_count],
 365       user.unread_conversation_count
 366     )
 367   end
 368
 369   defp maybe_put_unread_conversation_count(data, _, _), do: data
 370
 371   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 372     Kernel.put_in(
 373       data,
 374       [:pleroma, :unread_notifications_count],
 375       Pleroma.Notification.unread_notifications_count(user)
 376     )
 377   end
 378
 379   defp maybe_put_unread_notification_count(data, _, _), do: data
 380
 381   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 382   defp image_url(_), do: nil
 383 end