git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.HTML
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MastodonAPI.AccountView
  12   alias Pleroma.Web.MediaProxy
  13
  14   def render("accounts.json", %{users: users} = opts) do
  15     users
  16     |> render_many(AccountView, "account.json", opts)
  17     |> Enum.filter(&Enum.any?/1)
  18   end
  19
  20   def render("account.json", %{user: user} = opts) do
  21     if User.visible_for?(user, opts[:for]),
  22       do: do_render("account.json", opts),
  23       else: %{}
  24   end
  25
  26   def render("mention.json", %{user: user}) do
  27     %{
  28       id: to_string(user.id),
  29       acct: user.nickname,
  30       username: username_from_nickname(user.nickname),
  31       url: user.ap_id
  32     }
  33   end
  34
  35   def render("relationship.json", %{user: nil, target: _target}) do
  36     %{}
  37   end
  38
  39   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  40     follow_activity = Pleroma.Web.ActivityPub.Utils.fetch_latest_follow(user, target)
  41
  42     requested =
  43       if follow_activity do
  44         follow_activity.data["state"] == "pending"
  45       else
  46         false
  47       end
  48
  49     %{
  50       id: to_string(target.id),
  51       following: User.following?(user, target),
  52       followed_by: User.following?(target, user),
  53       blocking: User.blocks?(user, target),
  54       muting: User.mutes?(user, target),
  55       muting_notifications: false,
  56       requested: requested,
  57       domain_blocking: false,
  58       showing_reblogs: User.showing_reblogs?(user, target),
  59       endorsed: false
  60     }
  61   end
  62
  63   def render("relationships.json", %{user: user, targets: targets}) do
  64     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  65   end
  66
  67   defp do_render("account.json", %{user: user} = opts) do
  68     image = User.avatar_url(user) |> MediaProxy.url()
  69     header = User.banner_url(user) |> MediaProxy.url()
  70     user_info = User.user_info(user)
  71     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  72
  73     emojis =
  74       (user.info.source_data["tag"] || [])
  75       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  76       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  77         %{
  78           "shortcode" => String.trim(name, ":"),
  79           "url" => MediaProxy.url(url),
  80           "static_url" => MediaProxy.url(url),
  81           "visible_in_picker" => false
  82         }
  83       end)
  84
  85     fields =
  86       (user.info.source_data["attachment"] || [])
  87       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  88       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  89
  90     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
  91
  92     relationship = render("relationship.json", %{user: opts[:for], target: user})
  93
  94     %{
  95       id: to_string(user.id),
  96       username: username_from_nickname(user.nickname),
  97       acct: user.nickname,
  98       display_name: user.name || user.nickname,
  99       locked: user_info.locked,
 100       created_at: Utils.to_masto_date(user.inserted_at),
 101       followers_count: user_info.follower_count,
 102       following_count: user_info.following_count,
 103       statuses_count: user_info.note_count,
 104       note: bio || "",
 105       url: user.ap_id,
 106       avatar: image,
 107       avatar_static: image,
 108       header: header,
 109       header_static: header,
 110       emojis: emojis,
 111       fields: fields,
 112       bot: bot,
 113       source: %{
 114         note: "",
 115         privacy: user_info.default_scope,
 116         sensitive: false
 117       },
 118
 119       # Pleroma extension
 120       pleroma: %{
 121         confirmation_pending: user_info.confirmation_pending,
 122         tags: user.tags,
 123         is_moderator: user.info.is_moderator,
 124         is_admin: user.info.is_admin,
 125         relationship: relationship
 126       }
 127     }
 128   end
 129
 130   defp username_from_nickname(string) when is_binary(string) do
 131     hd(String.split(string, "@"))
 132   end
 133
 134   defp username_from_nickname(_), do: nil
 135 end