git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 defmodule Pleroma.Web.MastodonAPI.AccountView do
   2   use Pleroma.Web, :view
   3   alias Pleroma.User
   4   alias Pleroma.Web.MastodonAPI.AccountView
   5   alias Pleroma.Web.CommonAPI.Utils
   6   alias Pleroma.Web.MediaProxy
   7
   8   def render("accounts.json", %{users: users} = opts) do
   9     render_many(users, AccountView, "account.json", opts)
  10   end
  11
  12   def render("account.json", %{user: user}) do
  13     image = User.avatar_url(user) |> MediaProxy.url()
  14     header = User.banner_url(user) |> MediaProxy.url()
  15     user_info = User.user_info(user)
  16     bot = (user.info["source_data"]["type"] || "Person") in ["Application", "Service"]
  17
  18     emojis =
  19       (user.info["source_data"]["tag"] || [])
  20       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  21       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  22         %{
  23           "shortcode" => String.trim(name, ":"),
  24           "url" => MediaProxy.url(url),
  25           "static_url" => MediaProxy.url(url),
  26           "visible_in_picker" => false
  27         }
  28       end)
  29
  30     fields =
  31       (user.info["source_data"]["attachment"] || [])
  32       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  33       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  34
  35     %{
  36       id: to_string(user.id),
  37       username: hd(String.split(user.nickname, "@")),
  38       acct: user.nickname,
  39       display_name: user.name || user.nickname,
  40       locked: user_info.locked,
  41       created_at: Utils.to_masto_date(user.inserted_at),
  42       followers_count: user_info.follower_count,
  43       following_count: user_info.following_count,
  44       statuses_count: user_info.note_count,
  45       note: HtmlSanitizeEx.basic_html(user.bio) || "",
  46       url: user.ap_id,
  47       avatar: image,
  48       avatar_static: image,
  49       header: header,
  50       header_static: header,
  51       emojis: emojis,
  52       fields: fields,
  53       bot: bot,
  54       source: %{
  55         note: "",
  56         privacy: "public",
  57         sensitive: "false"
  58       }
  59     }
  60   end
  61
  62   def render("mention.json", %{user: user}) do
  63     %{
  64       id: to_string(user.id),
  65       acct: user.nickname,
  66       username: hd(String.split(user.nickname, "@")),
  67       url: user.ap_id
  68     }
  69   end
  70
  71   def render("relationship.json", %{user: user, target: target}) do
  72     %{
  73       id: to_string(target.id),
  74       following: User.following?(user, target),
  75       followed_by: User.following?(target, user),
  76       blocking: User.blocks?(user, target),
  77       muting: false,
  78       requested: false,
  79       domain_blocking: false
  80     }
  81   end
  82
  83   def render("relationships.json", %{user: user, targets: targets}) do
  84     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  85   end
  86 end