git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     reading_user = opts[:for]
  17
  18     relationships_opt =
  19       cond do
  20         Map.has_key?(opts, :relationships) ->
  21           opts[:relationships]
  22
  23         is_nil(reading_user) || !opts[:embed_relationships] ->
  24           UserRelationship.view_relationships_option(nil, [])
  25
  26         true ->
  27           UserRelationship.view_relationships_option(reading_user, users)
  28       end
  29
  30     opts = Map.put(opts, :relationships, relationships_opt)
  31
  32     users
  33     |> render_many(AccountView, "show.json", opts)
  34     |> Enum.filter(&Enum.any?/1)
  35   end
  36
  37   def render("show.json", %{user: user} = opts) do
  38     if User.visible_for?(user, opts[:for]) do
  39       do_render("show.json", opts)
  40     else
  41       %{}
  42     end
  43   end
  44
  45   def render("mention.json", %{user: user}) do
  46     %{
  47       id: to_string(user.id),
  48       acct: user.nickname,
  49       username: username_from_nickname(user.nickname),
  50       url: user.uri || user.ap_id
  51     }
  52   end
  53
  54   def render("relationship.json", %{user: nil, target: _target}) do
  55     %{}
  56   end
  57
  58   def render(
  59         "relationship.json",
  60         %{user: %User{} = reading_user, target: %User{} = target} = opts
  61       ) do
  62     user_relationships = get_in(opts, [:relationships, :user_relationships])
  63     following_relationships = get_in(opts, [:relationships, :following_relationships])
  64
  65     follow_state =
  66       if following_relationships do
  67         user_to_target_following_relation =
  68           FollowingRelationship.find(following_relationships, reading_user, target)
  69
  70         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  71       else
  72         User.get_follow_state(reading_user, target)
  73       end
  74
  75     followed_by =
  76       if following_relationships do
  77         case FollowingRelationship.find(following_relationships, target, reading_user) do
  78           %{state: :follow_accept} -> true
  79           _ -> false
  80         end
  81       else
  82         User.following?(target, reading_user)
  83       end
  84
  85     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
  86     %{
  87       id: to_string(target.id),
  88       following: follow_state == :follow_accept,
  89       followed_by: followed_by,
  90       blocking:
  91         UserRelationship.exists?(
  92           user_relationships,
  93           :block,
  94           reading_user,
  95           target,
  96           &User.blocks_user?(&1, &2)
  97         ),
  98       blocked_by:
  99         UserRelationship.exists?(
 100           user_relationships,
 101           :block,
 102           target,
 103           reading_user,
 104           &User.blocks_user?(&1, &2)
 105         ),
 106       muting:
 107         UserRelationship.exists?(
 108           user_relationships,
 109           :mute,
 110           reading_user,
 111           target,
 112           &User.mutes?(&1, &2)
 113         ),
 114       muting_notifications:
 115         UserRelationship.exists?(
 116           user_relationships,
 117           :notification_mute,
 118           reading_user,
 119           target,
 120           &User.muted_notifications?(&1, &2)
 121         ),
 122       subscribing:
 123         UserRelationship.exists?(
 124           user_relationships,
 125           :inverse_subscription,
 126           target,
 127           reading_user,
 128           &User.subscribed_to?(&2, &1)
 129         ),
 130       requested: follow_state == :follow_pending,
 131       domain_blocking: User.blocks_domain?(reading_user, target),
 132       showing_reblogs:
 133         not UserRelationship.exists?(
 134           user_relationships,
 135           :reblog_mute,
 136           reading_user,
 137           target,
 138           &User.muting_reblogs?(&1, &2)
 139         ),
 140       endorsed: false
 141     }
 142   end
 143
 144   def render("relationships.json", %{user: user, targets: targets} = opts) do
 145     relationships_opt =
 146       cond do
 147         Map.has_key?(opts, :relationships) ->
 148           opts[:relationships]
 149
 150         is_nil(user) ->
 151           UserRelationship.view_relationships_option(nil, [])
 152
 153         true ->
 154           UserRelationship.view_relationships_option(user, targets)
 155       end
 156
 157     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 158     render_many(targets, AccountView, "relationship.json", render_opts)
 159   end
 160
 161   defp do_render("show.json", %{user: user} = opts) do
 162     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 163     display_name = user.name || user.nickname
 164
 165     image = User.avatar_url(user) |> MediaProxy.url()
 166     header = User.banner_url(user) |> MediaProxy.url()
 167
 168     following_count =
 169       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 170         user.following_count || 0
 171       else
 172         0
 173       end
 174
 175     followers_count =
 176       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 177         user.follower_count || 0
 178       else
 179         0
 180       end
 181
 182     bot = user.actor_type in ["Application", "Service"]
 183
 184     emojis =
 185       Enum.map(user.emoji, fn {shortcode, url} ->
 186         %{
 187           "shortcode" => shortcode,
 188           "url" => url,
 189           "static_url" => url,
 190           "visible_in_picker" => false
 191         }
 192       end)
 193
 194     relationship =
 195       if opts[:embed_relationships] do
 196         render("relationship.json", %{
 197           user: opts[:for],
 198           target: user,
 199           relationships: opts[:relationships]
 200         })
 201       else
 202         %{}
 203       end
 204
 205     %{
 206       id: to_string(user.id),
 207       username: username_from_nickname(user.nickname),
 208       acct: user.nickname,
 209       display_name: display_name,
 210       locked: user.locked,
 211       created_at: Utils.to_masto_date(user.inserted_at),
 212       followers_count: followers_count,
 213       following_count: following_count,
 214       statuses_count: user.note_count,
 215       note: user.bio || "",
 216       url: user.uri || user.ap_id,
 217       avatar: image,
 218       avatar_static: image,
 219       header: header,
 220       header_static: header,
 221       emojis: emojis,
 222       fields: user.fields,
 223       bot: bot,
 224       source: %{
 225         note: prepare_user_bio(user),
 226         sensitive: false,
 227         fields: user.raw_fields,
 228         pleroma: %{
 229           discoverable: user.discoverable,
 230           actor_type: user.actor_type
 231         }
 232       },
 233
 234       # Pleroma extension
 235       pleroma: %{
 236         ap_id: user.ap_id,
 237         confirmation_pending: user.confirmation_pending,
 238         tags: user.tags,
 239         hide_followers_count: user.hide_followers_count,
 240         hide_follows_count: user.hide_follows_count,
 241         hide_followers: user.hide_followers,
 242         hide_follows: user.hide_follows,
 243         hide_favorites: user.hide_favorites,
 244         relationship: relationship,
 245         skip_thread_containment: user.skip_thread_containment,
 246         background_image: image_url(user.background) |> MediaProxy.url()
 247       }
 248     }
 249     |> maybe_put_role(user, opts[:for])
 250     |> maybe_put_settings(user, opts[:for], opts)
 251     |> maybe_put_notification_settings(user, opts[:for])
 252     |> maybe_put_settings_store(user, opts[:for], opts)
 253     |> maybe_put_chat_token(user, opts[:for], opts)
 254     |> maybe_put_activation_status(user, opts[:for])
 255     |> maybe_put_follow_requests_count(user, opts[:for])
 256     |> maybe_put_allow_following_move(user, opts[:for])
 257     |> maybe_put_unread_conversation_count(user, opts[:for])
 258     |> maybe_put_unread_notification_count(user, opts[:for])
 259   end
 260
 261   defp prepare_user_bio(%User{bio: ""}), do: ""
 262
 263   defp prepare_user_bio(%User{bio: bio}) when is_binary(bio) do
 264     bio
 265     |> String.replace(~r(<br */?>), "\n")
 266     |> Pleroma.HTML.strip_tags()
 267     |> HtmlEntities.decode()
 268   end
 269
 270   defp prepare_user_bio(_), do: ""
 271
 272   defp username_from_nickname(string) when is_binary(string) do
 273     hd(String.split(string, "@"))
 274   end
 275
 276   defp username_from_nickname(_), do: nil
 277
 278   defp maybe_put_follow_requests_count(
 279          data,
 280          %User{id: user_id} = user,
 281          %User{id: user_id}
 282        ) do
 283     count =
 284       User.get_follow_requests(user)
 285       |> length()
 286
 287     data
 288     |> Kernel.put_in([:follow_requests_count], count)
 289   end
 290
 291   defp maybe_put_follow_requests_count(data, _, _), do: data
 292
 293   defp maybe_put_settings(
 294          data,
 295          %User{id: user_id} = user,
 296          %User{id: user_id},
 297          _opts
 298        ) do
 299     data
 300     |> Kernel.put_in([:source, :privacy], user.default_scope)
 301     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 302     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 303   end
 304
 305   defp maybe_put_settings(data, _, _, _), do: data
 306
 307   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 308          with_pleroma_settings: true
 309        }) do
 310     data
 311     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 312   end
 313
 314   defp maybe_put_settings_store(data, _, _, _), do: data
 315
 316   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 317          with_chat_token: token
 318        }) do
 319     data
 320     |> Kernel.put_in([:pleroma, :chat_token], token)
 321   end
 322
 323   defp maybe_put_chat_token(data, _, _, _), do: data
 324
 325   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 326     data
 327     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 328     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 329   end
 330
 331   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 332     data
 333     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 334     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 335   end
 336
 337   defp maybe_put_role(data, _, _), do: data
 338
 339   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 340     Kernel.put_in(
 341       data,
 342       [:pleroma, :notification_settings],
 343       Map.from_struct(user.notification_settings)
 344     )
 345   end
 346
 347   defp maybe_put_notification_settings(data, _, _), do: data
 348
 349   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 350     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 351   end
 352
 353   defp maybe_put_allow_following_move(data, _, _), do: data
 354
 355   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 356     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 357   end
 358
 359   defp maybe_put_activation_status(data, _, _), do: data
 360
 361   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 362     data
 363     |> Kernel.put_in(
 364       [:pleroma, :unread_conversation_count],
 365       user.unread_conversation_count
 366     )
 367   end
 368
 369   defp maybe_put_unread_conversation_count(data, _, _), do: data
 370
 371   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 372     Kernel.put_in(
 373       data,
 374       [:pleroma, :unread_notifications_count],
 375       Pleroma.Notification.unread_notifications_count(user)
 376     )
 377   end
 378
 379   defp maybe_put_unread_notification_count(data, _, _), do: data
 380
 381   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 382   defp image_url(_), do: nil
 383 end