git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.HTML
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MastodonAPI.AccountView
  12   alias Pleroma.Web.MediaProxy
  13
  14   def render("index.json", %{users: users} = opts) do
  15     users
  16     |> render_many(AccountView, "show.json", opts)
  17     |> Enum.filter(&Enum.any?/1)
  18   end
  19
  20   def render("show.json", %{user: user} = opts) do
  21     if User.visible_for?(user, opts[:for]),
  22       do: do_render("show.json", opts),
  23       else: %{}
  24   end
  25
  26   def render("mention.json", %{user: user}) do
  27     %{
  28       id: to_string(user.id),
  29       acct: user.nickname,
  30       username: username_from_nickname(user.nickname),
  31       url: User.profile_url(user)
  32     }
  33   end
  34
  35   def render("relationship.json", %{user: nil, target: _target}) do
  36     %{}
  37   end
  38
  39   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  40     follow_state = User.get_cached_follow_state(user, target)
  41
  42     requested =
  43       if follow_state && !User.following?(user, target) do
  44         follow_state == "pending"
  45       else
  46         false
  47       end
  48
  49     %{
  50       id: to_string(target.id),
  51       following: User.following?(user, target),
  52       followed_by: User.following?(target, user),
  53       blocking: User.blocks_ap_id?(user, target),
  54       blocked_by: User.blocks_ap_id?(target, user),
  55       muting: User.mutes?(user, target),
  56       muting_notifications: User.muted_notifications?(user, target),
  57       subscribing: User.subscribed_to?(user, target),
  58       requested: requested,
  59       domain_blocking: User.blocks_domain?(user, target),
  60       showing_reblogs: User.showing_reblogs?(user, target),
  61       endorsed: false
  62     }
  63   end
  64
  65   def render("relationships.json", %{user: user, targets: targets}) do
  66     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  67   end
  68
  69   defp do_render("show.json", %{user: user} = opts) do
  70     display_name = HTML.strip_tags(user.name || user.nickname)
  71
  72     image = User.avatar_url(user) |> MediaProxy.url()
  73     header = User.banner_url(user) |> MediaProxy.url()
  74     user_info = User.get_cached_user_info(user)
  75
  76     following_count =
  77       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
  78         user_info.following_count
  79       else
  80         0
  81       end
  82
  83     followers_count =
  84       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
  85         user_info.follower_count
  86       else
  87         0
  88       end
  89
  90     bot = (user.source_data["type"] || "Person") in ["Application", "Service"]
  91
  92     emojis =
  93       (user.source_data["tag"] || [])
  94       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  95       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  96         %{
  97           "shortcode" => String.trim(name, ":"),
  98           "url" => MediaProxy.url(url),
  99           "static_url" => MediaProxy.url(url),
 100           "visible_in_picker" => false
 101         }
 102       end)
 103
 104     fields =
 105       user
 106       |> User.fields()
 107       |> Enum.map(fn %{"name" => name, "value" => value} ->
 108         %{
 109           "name" => Pleroma.HTML.strip_tags(name),
 110           "value" => Pleroma.HTML.filter_tags(value, Pleroma.HTML.Scrubber.LinksOnly)
 111         }
 112       end)
 113
 114     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
 115     relationship = render("relationship.json", %{user: opts[:for], target: user})
 116
 117     %{
 118       id: to_string(user.id),
 119       username: username_from_nickname(user.nickname),
 120       acct: user.nickname,
 121       display_name: display_name,
 122       locked: user.locked,
 123       created_at: Utils.to_masto_date(user.inserted_at),
 124       followers_count: followers_count,
 125       following_count: following_count,
 126       statuses_count: user.note_count,
 127       note: bio || "",
 128       url: User.profile_url(user),
 129       avatar: image,
 130       avatar_static: image,
 131       header: header,
 132       header_static: header,
 133       emojis: emojis,
 134       fields: fields,
 135       bot: bot,
 136       source: %{
 137         note: HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
 138         sensitive: false,
 139         fields: user.raw_fields,
 140         pleroma: %{
 141           discoverable: user.discoverable
 142         }
 143       },
 144
 145       # Pleroma extension
 146       pleroma: %{
 147         confirmation_pending: user_info.confirmation_pending,
 148         tags: user.tags,
 149         hide_followers_count: user.hide_followers_count,
 150         hide_follows_count: user.hide_follows_count,
 151         hide_followers: user.hide_followers,
 152         hide_follows: user.hide_follows,
 153         hide_favorites: user.hide_favorites,
 154         relationship: relationship,
 155         skip_thread_containment: user.skip_thread_containment,
 156         background_image: image_url(user.background) |> MediaProxy.url()
 157       }
 158     }
 159     |> maybe_put_role(user, opts[:for])
 160     |> maybe_put_settings(user, opts[:for], user_info)
 161     |> maybe_put_notification_settings(user, opts[:for])
 162     |> maybe_put_settings_store(user, opts[:for], opts)
 163     |> maybe_put_chat_token(user, opts[:for], opts)
 164     |> maybe_put_activation_status(user, opts[:for])
 165     |> maybe_put_follow_requests_count(user, opts[:for])
 166     |> maybe_put_unread_conversation_count(user, opts[:for])
 167   end
 168
 169   defp username_from_nickname(string) when is_binary(string) do
 170     hd(String.split(string, "@"))
 171   end
 172
 173   defp username_from_nickname(_), do: nil
 174
 175   defp maybe_put_follow_requests_count(
 176          data,
 177          %User{id: user_id} = user,
 178          %User{id: user_id}
 179        ) do
 180     count =
 181       User.get_follow_requests(user)
 182       |> length()
 183
 184     data
 185     |> Kernel.put_in([:follow_requests_count], count)
 186   end
 187
 188   defp maybe_put_follow_requests_count(data, _, _), do: data
 189
 190   defp maybe_put_settings(
 191          data,
 192          %User{id: user_id} = user,
 193          %User{id: user_id},
 194          _user_info
 195        ) do
 196     data
 197     |> Kernel.put_in([:source, :privacy], user.default_scope)
 198     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 199     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 200   end
 201
 202   defp maybe_put_settings(data, _, _, _), do: data
 203
 204   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 205          with_pleroma_settings: true
 206        }) do
 207     data
 208     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 209   end
 210
 211   defp maybe_put_settings_store(data, _, _, _), do: data
 212
 213   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 214          with_chat_token: token
 215        }) do
 216     data
 217     |> Kernel.put_in([:pleroma, :chat_token], token)
 218   end
 219
 220   defp maybe_put_chat_token(data, _, _, _), do: data
 221
 222   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 223     data
 224     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 225     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 226   end
 227
 228   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 229     data
 230     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 231     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 232   end
 233
 234   defp maybe_put_role(data, _, _), do: data
 235
 236   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 237     Kernel.put_in(data, [:pleroma, :notification_settings], user.notification_settings)
 238   end
 239
 240   defp maybe_put_notification_settings(data, _, _), do: data
 241
 242   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 243     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 244   end
 245
 246   defp maybe_put_activation_status(data, _, _), do: data
 247
 248   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 249     data
 250     |> Kernel.put_in(
 251       [:pleroma, :unread_conversation_count],
 252       user.unread_conversation_count
 253     )
 254   end
 255
 256   defp maybe_put_unread_conversation_count(data, _, _), do: data
 257
 258   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 259   defp image_url(_), do: nil
 260 end