git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.HTML
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MastodonAPI.AccountView
  12   alias Pleroma.Web.MediaProxy
  13
  14   def render("index.json", %{users: users} = opts) do
  15     users
  16     |> render_many(AccountView, "show.json", opts)
  17     |> Enum.filter(&Enum.any?/1)
  18   end
  19
  20   def render("show.json", %{user: user} = opts) do
  21     if User.visible_for?(user, opts[:for]),
  22       do: do_render("show.json", opts),
  23       else: %{}
  24   end
  25
  26   def render("mention.json", %{user: user}) do
  27     %{
  28       id: to_string(user.id),
  29       acct: user.nickname,
  30       username: username_from_nickname(user.nickname),
  31       url: User.profile_url(user)
  32     }
  33   end
  34
  35   def render("relationship.json", %{user: nil, target: _target}) do
  36     %{}
  37   end
  38
  39   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  40     follow_state = User.get_cached_follow_state(user, target)
  41
  42     requested =
  43       if follow_state && !User.following?(user, target) do
  44         follow_state == "pending"
  45       else
  46         false
  47       end
  48
  49     %{
  50       id: to_string(target.id),
  51       following: User.following?(user, target),
  52       followed_by: User.following?(target, user),
  53       blocking: User.blocks_ap_id?(user, target),
  54       blocked_by: User.blocks_ap_id?(target, user),
  55       muting: User.mutes?(user, target),
  56       muting_notifications: User.muted_notifications?(user, target),
  57       subscribing: User.subscribed_to?(user, target),
  58       requested: requested,
  59       domain_blocking: User.blocks_domain?(user, target),
  60       showing_reblogs: User.showing_reblogs?(user, target),
  61       endorsed: false
  62     }
  63   end
  64
  65   def render("relationships.json", %{user: user, targets: targets}) do
  66     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  67   end
  68
  69   defp do_render("show.json", %{user: user} = opts) do
  70     display_name = HTML.strip_tags(user.name || user.nickname)
  71
  72     image = User.avatar_url(user) |> MediaProxy.url()
  73     header = User.banner_url(user) |> MediaProxy.url()
  74     user_info = User.get_cached_user_info(user)
  75
  76     following_count =
  77       if !user.info.hide_follows_count or !user.info.hide_follows or opts[:for] == user do
  78         user_info.following_count
  79       else
  80         0
  81       end
  82
  83     followers_count =
  84       if !user.info.hide_followers_count or !user.info.hide_followers or opts[:for] == user do
  85         user_info.follower_count
  86       else
  87         0
  88       end
  89
  90     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  91
  92     emojis =
  93       (user.info.source_data["tag"] || [])
  94       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  95       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  96         %{
  97           "shortcode" => String.trim(name, ":"),
  98           "url" => MediaProxy.url(url),
  99           "static_url" => MediaProxy.url(url),
 100           "visible_in_picker" => false
 101         }
 102       end)
 103
 104     fields =
 105       user.info
 106       |> User.Info.fields()
 107       |> Enum.map(fn %{"name" => name, "value" => value} ->
 108         %{
 109           "name" => Pleroma.HTML.strip_tags(name),
 110           "value" => Pleroma.HTML.filter_tags(value, Pleroma.HTML.Scrubber.LinksOnly)
 111         }
 112       end)
 113
 114     raw_fields = Map.get(user.info, :raw_fields, [])
 115
 116     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
 117     relationship = render("relationship.json", %{user: opts[:for], target: user})
 118
 119     discoverable = user.info.discoverable
 120
 121     %{
 122       id: to_string(user.id),
 123       username: username_from_nickname(user.nickname),
 124       acct: user.nickname,
 125       display_name: display_name,
 126       locked: user_info.locked,
 127       created_at: Utils.to_masto_date(user.inserted_at),
 128       followers_count: followers_count,
 129       following_count: following_count,
 130       statuses_count: user_info.note_count,
 131       note: bio || "",
 132       url: User.profile_url(user),
 133       avatar: image,
 134       avatar_static: image,
 135       header: header,
 136       header_static: header,
 137       emojis: emojis,
 138       fields: fields,
 139       bot: bot,
 140       source: %{
 141         note: HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
 142         sensitive: false,
 143         fields: raw_fields,
 144         pleroma: %{
 145           discoverable: discoverable
 146         }
 147       },
 148
 149       # Pleroma extension
 150       pleroma: %{
 151         confirmation_pending: user_info.confirmation_pending,
 152         tags: user.tags,
 153         hide_followers_count: user.info.hide_followers_count,
 154         hide_follows_count: user.info.hide_follows_count,
 155         hide_followers: user.info.hide_followers,
 156         hide_follows: user.info.hide_follows,
 157         hide_favorites: user.info.hide_favorites,
 158         relationship: relationship,
 159         skip_thread_containment: user.info.skip_thread_containment,
 160         background_image: image_url(user.info.background) |> MediaProxy.url()
 161       }
 162     }
 163     |> maybe_put_role(user, opts[:for])
 164     |> maybe_put_settings(user, opts[:for], user_info)
 165     |> maybe_put_notification_settings(user, opts[:for])
 166     |> maybe_put_settings_store(user, opts[:for], opts)
 167     |> maybe_put_chat_token(user, opts[:for], opts)
 168     |> maybe_put_activation_status(user, opts[:for])
 169     |> maybe_put_follow_requests_count(user, opts[:for])
 170     |> maybe_put_unread_conversation_count(user, opts[:for])
 171   end
 172
 173   defp username_from_nickname(string) when is_binary(string) do
 174     hd(String.split(string, "@"))
 175   end
 176
 177   defp username_from_nickname(_), do: nil
 178
 179   defp maybe_put_follow_requests_count(
 180          data,
 181          %User{id: user_id} = user,
 182          %User{id: user_id}
 183        ) do
 184     count =
 185       User.get_follow_requests(user)
 186       |> length()
 187
 188     data
 189     |> Kernel.put_in([:follow_requests_count], count)
 190   end
 191
 192   defp maybe_put_follow_requests_count(data, _, _), do: data
 193
 194   defp maybe_put_settings(
 195          data,
 196          %User{id: user_id} = user,
 197          %User{id: user_id},
 198          user_info
 199        ) do
 200     data
 201     |> Kernel.put_in([:source, :privacy], user_info.default_scope)
 202     |> Kernel.put_in([:source, :pleroma, :show_role], user.info.show_role)
 203     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.info.no_rich_text)
 204   end
 205
 206   defp maybe_put_settings(data, _, _, _), do: data
 207
 208   defp maybe_put_settings_store(data, %User{info: info, id: id}, %User{id: id}, %{
 209          with_pleroma_settings: true
 210        }) do
 211     data
 212     |> Kernel.put_in([:pleroma, :settings_store], info.pleroma_settings_store)
 213   end
 214
 215   defp maybe_put_settings_store(data, _, _, _), do: data
 216
 217   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 218          with_chat_token: token
 219        }) do
 220     data
 221     |> Kernel.put_in([:pleroma, :chat_token], token)
 222   end
 223
 224   defp maybe_put_chat_token(data, _, _, _), do: data
 225
 226   defp maybe_put_role(data, %User{info: %{show_role: true}} = user, _) do
 227     data
 228     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 229     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 230   end
 231
 232   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 233     data
 234     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 235     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 236   end
 237
 238   defp maybe_put_role(data, _, _), do: data
 239
 240   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 241     Kernel.put_in(data, [:pleroma, :notification_settings], user.info.notification_settings)
 242   end
 243
 244   defp maybe_put_notification_settings(data, _, _), do: data
 245
 246   defp maybe_put_activation_status(data, user, %User{info: %{is_admin: true}}) do
 247     Kernel.put_in(data, [:pleroma, :deactivated], user.info.deactivated)
 248   end
 249
 250   defp maybe_put_activation_status(data, _, _), do: data
 251
 252   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 253     data
 254     |> Kernel.put_in(
 255       [:pleroma, :unread_conversation_count],
 256       user.info.unread_conversation_count
 257     )
 258   end
 259
 260   defp maybe_put_unread_conversation_count(data, _, _), do: data
 261
 262   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 263   defp image_url(_), do: nil
 264 end