git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.CommonAPI.Utils
  10   alias Pleroma.Web.MastodonAPI.AccountView
  11   alias Pleroma.Web.MediaProxy
  12
  13   def render("index.json", %{users: users} = opts) do
  14     users
  15     |> render_many(AccountView, "show.json", opts)
  16     |> Enum.filter(&Enum.any?/1)
  17   end
  18
  19   def render("show.json", %{user: user} = opts) do
  20     if User.visible_for?(user, opts[:for]),
  21       do: do_render("show.json", opts),
  22       else: %{}
  23   end
  24
  25   def render("mention.json", %{user: user}) do
  26     %{
  27       id: to_string(user.id),
  28       acct: user.nickname,
  29       username: username_from_nickname(user.nickname),
  30       url: User.profile_url(user)
  31     }
  32   end
  33
  34   def render("relationship.json", %{user: nil, target: _target}) do
  35     %{}
  36   end
  37
  38   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  39     follow_state = User.get_follow_state(user, target)
  40
  41     %{
  42       id: to_string(target.id),
  43       following: follow_state == "accept",
  44       followed_by: User.following?(target, user),
  45       blocking: User.blocks_user?(user, target),
  46       blocked_by: User.blocks_user?(target, user),
  47       muting: User.mutes?(user, target),
  48       muting_notifications: User.muted_notifications?(user, target),
  49       subscribing: User.subscribed_to?(user, target),
  50       requested: follow_state == "pending",
  51       domain_blocking: User.blocks_domain?(user, target),
  52       showing_reblogs: User.showing_reblogs?(user, target),
  53       endorsed: false
  54     }
  55   end
  56
  57   def render("relationships.json", %{user: user, targets: targets}) do
  58     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  59   end
  60
  61   defp do_render("show.json", %{user: user} = opts) do
  62     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
  63     display_name = user.name || user.nickname
  64
  65     image = User.avatar_url(user) |> MediaProxy.url()
  66     header = User.banner_url(user) |> MediaProxy.url()
  67
  68     following_count =
  69       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
  70         user.following_count || 0
  71       else
  72         0
  73       end
  74
  75     followers_count =
  76       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
  77         user.follower_count || 0
  78       else
  79         0
  80       end
  81
  82     bot = user.actor_type in ["Application", "Service"]
  83
  84     emojis =
  85       (user.source_data["tag"] || [])
  86       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  87       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  88         %{
  89           "shortcode" => String.trim(name, ":"),
  90           "url" => MediaProxy.url(url),
  91           "static_url" => MediaProxy.url(url),
  92           "visible_in_picker" => false
  93         }
  94       end)
  95
  96     relationship = render("relationship.json", %{user: opts[:for], target: user})
  97
  98     %{
  99       id: to_string(user.id),
 100       username: username_from_nickname(user.nickname),
 101       acct: user.nickname,
 102       display_name: display_name,
 103       locked: user.locked,
 104       created_at: Utils.to_masto_date(user.inserted_at),
 105       followers_count: followers_count,
 106       following_count: following_count,
 107       statuses_count: user.note_count,
 108       note: user.bio || "",
 109       url: User.profile_url(user),
 110       avatar: image,
 111       avatar_static: image,
 112       header: header,
 113       header_static: header,
 114       emojis: emojis,
 115       fields: user.fields,
 116       bot: bot,
 117       source: %{
 118         note: Pleroma.HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
 119         sensitive: false,
 120         fields: user.raw_fields,
 121         pleroma: %{
 122           discoverable: user.discoverable,
 123           actor_type: user.actor_type
 124         }
 125       },
 126
 127       # Pleroma extension
 128       pleroma: %{
 129         confirmation_pending: user.confirmation_pending,
 130         tags: user.tags,
 131         hide_followers_count: user.hide_followers_count,
 132         hide_follows_count: user.hide_follows_count,
 133         hide_followers: user.hide_followers,
 134         hide_follows: user.hide_follows,
 135         hide_favorites: user.hide_favorites,
 136         relationship: relationship,
 137         skip_thread_containment: user.skip_thread_containment,
 138         background_image: image_url(user.background) |> MediaProxy.url()
 139       }
 140     }
 141     |> maybe_put_role(user, opts[:for])
 142     |> maybe_put_settings(user, opts[:for], opts)
 143     |> maybe_put_notification_settings(user, opts[:for])
 144     |> maybe_put_settings_store(user, opts[:for], opts)
 145     |> maybe_put_chat_token(user, opts[:for], opts)
 146     |> maybe_put_activation_status(user, opts[:for])
 147     |> maybe_put_follow_requests_count(user, opts[:for])
 148     |> maybe_put_allow_following_move(user, opts[:for])
 149     |> maybe_put_unread_conversation_count(user, opts[:for])
 150   end
 151
 152   defp username_from_nickname(string) when is_binary(string) do
 153     hd(String.split(string, "@"))
 154   end
 155
 156   defp username_from_nickname(_), do: nil
 157
 158   defp maybe_put_follow_requests_count(
 159          data,
 160          %User{id: user_id} = user,
 161          %User{id: user_id}
 162        ) do
 163     count =
 164       User.get_follow_requests(user)
 165       |> length()
 166
 167     data
 168     |> Kernel.put_in([:follow_requests_count], count)
 169   end
 170
 171   defp maybe_put_follow_requests_count(data, _, _), do: data
 172
 173   defp maybe_put_settings(
 174          data,
 175          %User{id: user_id} = user,
 176          %User{id: user_id},
 177          _opts
 178        ) do
 179     data
 180     |> Kernel.put_in([:source, :privacy], user.default_scope)
 181     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 182     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 183   end
 184
 185   defp maybe_put_settings(data, _, _, _), do: data
 186
 187   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 188          with_pleroma_settings: true
 189        }) do
 190     data
 191     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 192   end
 193
 194   defp maybe_put_settings_store(data, _, _, _), do: data
 195
 196   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 197          with_chat_token: token
 198        }) do
 199     data
 200     |> Kernel.put_in([:pleroma, :chat_token], token)
 201   end
 202
 203   defp maybe_put_chat_token(data, _, _, _), do: data
 204
 205   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 206     data
 207     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 208     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 209   end
 210
 211   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 212     data
 213     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 214     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 215   end
 216
 217   defp maybe_put_role(data, _, _), do: data
 218
 219   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 220     Kernel.put_in(data, [:pleroma, :notification_settings], user.notification_settings)
 221   end
 222
 223   defp maybe_put_notification_settings(data, _, _), do: data
 224
 225   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 226     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 227   end
 228
 229   defp maybe_put_allow_following_move(data, _, _), do: data
 230
 231   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 232     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 233   end
 234
 235   defp maybe_put_activation_status(data, _, _), do: data
 236
 237   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 238     data
 239     |> Kernel.put_in(
 240       [:pleroma, :unread_conversation_count],
 241       user.unread_conversation_count
 242     )
 243   end
 244
 245   defp maybe_put_unread_conversation_count(data, _, _), do: data
 246
 247   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 248   defp image_url(_), do: nil
 249 end