git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     reading_user = opts[:for]
  17
  18     relationships_opt =
  19       cond do
  20         Map.has_key?(opts, :relationships) ->
  21           opts[:relationships]
  22
  23         is_nil(reading_user) || !opts[:embed_relationships] ->
  24           UserRelationship.view_relationships_option(nil, [])
  25
  26         true ->
  27           UserRelationship.view_relationships_option(reading_user, users)
  28       end
  29
  30     opts =
  31       opts
  32       |> Map.merge(%{relationships: relationships_opt, as: :user})
  33       |> Map.delete(:users)
  34
  35     users
  36     |> render_many(AccountView, "show.json", opts)
  37     |> Enum.filter(&Enum.any?/1)
  38   end
  39
  40   @doc """
  41   Renders specified user account.
  42     :skip_visibility_check option skips visibility check and renders any user (local or remote)
  43       regardless of [:pleroma, :restrict_unauthenticated] setting.
  44     :for option specifies the requester and can be a User record or nil.
  45       Only use `user: user, for: user` when `user` is the actual requester of own profile.
  46   """
  47   def render("show.json", %{user: _user, skip_visibility_check: true} = opts) do
  48     do_render("show.json", opts)
  49   end
  50
  51   def render("show.json", %{user: user, for: for_user_or_nil} = opts) do
  52     if User.visible_for(user, for_user_or_nil) == :visible do
  53       do_render("show.json", opts)
  54     else
  55       %{}
  56     end
  57   end
  58
  59   def render("show.json", _) do
  60     raise "In order to prevent account accessibility issues, " <>
  61             ":skip_visibility_check or :for option is required."
  62   end
  63
  64   def render("mention.json", %{user: user}) do
  65     %{
  66       id: to_string(user.id),
  67       acct: user.nickname,
  68       username: username_from_nickname(user.nickname),
  69       url: user.uri || user.ap_id
  70     }
  71   end
  72
  73   def render("relationship.json", %{user: nil, target: _target}) do
  74     %{}
  75   end
  76
  77   def render(
  78         "relationship.json",
  79         %{user: %User{} = reading_user, target: %User{} = target} = opts
  80       ) do
  81     user_relationships = get_in(opts, [:relationships, :user_relationships])
  82     following_relationships = get_in(opts, [:relationships, :following_relationships])
  83
  84     follow_state =
  85       if following_relationships do
  86         user_to_target_following_relation =
  87           FollowingRelationship.find(following_relationships, reading_user, target)
  88
  89         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  90       else
  91         User.get_follow_state(reading_user, target)
  92       end
  93
  94     followed_by =
  95       if following_relationships do
  96         case FollowingRelationship.find(following_relationships, target, reading_user) do
  97           %{state: :follow_accept} -> true
  98           _ -> false
  99         end
 100       else
 101         User.following?(target, reading_user)
 102       end
 103
 104     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
 105     %{
 106       id: to_string(target.id),
 107       following: follow_state == :follow_accept,
 108       followed_by: followed_by,
 109       blocking:
 110         UserRelationship.exists?(
 111           user_relationships,
 112           :block,
 113           reading_user,
 114           target,
 115           &User.blocks_user?(&1, &2)
 116         ),
 117       blocked_by:
 118         UserRelationship.exists?(
 119           user_relationships,
 120           :block,
 121           target,
 122           reading_user,
 123           &User.blocks_user?(&1, &2)
 124         ),
 125       muting:
 126         UserRelationship.exists?(
 127           user_relationships,
 128           :mute,
 129           reading_user,
 130           target,
 131           &User.mutes?(&1, &2)
 132         ),
 133       muting_notifications:
 134         UserRelationship.exists?(
 135           user_relationships,
 136           :notification_mute,
 137           reading_user,
 138           target,
 139           &User.muted_notifications?(&1, &2)
 140         ),
 141       subscribing:
 142         UserRelationship.exists?(
 143           user_relationships,
 144           :inverse_subscription,
 145           target,
 146           reading_user,
 147           &User.subscribed_to?(&2, &1)
 148         ),
 149       requested: follow_state == :follow_pending,
 150       domain_blocking: User.blocks_domain?(reading_user, target),
 151       showing_reblogs:
 152         not UserRelationship.exists?(
 153           user_relationships,
 154           :reblog_mute,
 155           reading_user,
 156           target,
 157           &User.muting_reblogs?(&1, &2)
 158         ),
 159       endorsed: false
 160     }
 161   end
 162
 163   def render("relationships.json", %{user: user, targets: targets} = opts) do
 164     relationships_opt =
 165       cond do
 166         Map.has_key?(opts, :relationships) ->
 167           opts[:relationships]
 168
 169         is_nil(user) ->
 170           UserRelationship.view_relationships_option(nil, [])
 171
 172         true ->
 173           UserRelationship.view_relationships_option(user, targets)
 174       end
 175
 176     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 177     render_many(targets, AccountView, "relationship.json", render_opts)
 178   end
 179
 180   defp do_render("show.json", %{user: user} = opts) do
 181     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 182     display_name = user.name || user.nickname
 183
 184     image = User.avatar_url(user) |> MediaProxy.url()
 185     header = User.banner_url(user) |> MediaProxy.url()
 186
 187     following_count =
 188       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 189         user.following_count || 0
 190       else
 191         0
 192       end
 193
 194     followers_count =
 195       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 196         user.follower_count || 0
 197       else
 198         0
 199       end
 200
 201     bot = user.actor_type == "Service"
 202
 203     emojis =
 204       Enum.map(user.emoji, fn {shortcode, raw_url} ->
 205         url = MediaProxy.url(raw_url)
 206
 207         %{
 208           shortcode: shortcode,
 209           url: url,
 210           static_url: url,
 211           visible_in_picker: false
 212         }
 213       end)
 214
 215     relationship =
 216       if opts[:embed_relationships] do
 217         render("relationship.json", %{
 218           user: opts[:for],
 219           target: user,
 220           relationships: opts[:relationships]
 221         })
 222       else
 223         %{}
 224       end
 225
 226     favicon =
 227       if Pleroma.Config.get([:instances_favicons, :enabled]) do
 228         user
 229         |> Map.get(:ap_id, "")
 230         |> URI.parse()
 231         |> URI.merge("/")
 232         |> Pleroma.Instances.Instance.get_or_update_favicon()
 233         |> MediaProxy.url()
 234       else
 235         nil
 236       end
 237
 238     %{
 239       id: to_string(user.id),
 240       username: username_from_nickname(user.nickname),
 241       acct: user.nickname,
 242       display_name: display_name,
 243       locked: user.locked,
 244       created_at: Utils.to_masto_date(user.inserted_at),
 245       followers_count: followers_count,
 246       following_count: following_count,
 247       statuses_count: user.note_count,
 248       note: user.bio || "",
 249       url: user.uri || user.ap_id,
 250       avatar: image,
 251       avatar_static: image,
 252       header: header,
 253       header_static: header,
 254       emojis: emojis,
 255       fields: user.fields,
 256       bot: bot,
 257       source: %{
 258         note: user.raw_bio || "",
 259         sensitive: false,
 260         fields: user.raw_fields,
 261         pleroma: %{
 262           discoverable: user.discoverable,
 263           actor_type: user.actor_type
 264         }
 265       },
 266
 267       # Pleroma extension
 268       pleroma: %{
 269         ap_id: user.ap_id,
 270         also_known_as: user.also_known_as,
 271         confirmation_pending: user.confirmation_pending,
 272         tags: user.tags,
 273         hide_followers_count: user.hide_followers_count,
 274         hide_follows_count: user.hide_follows_count,
 275         hide_followers: user.hide_followers,
 276         hide_follows: user.hide_follows,
 277         hide_favorites: user.hide_favorites,
 278         relationship: relationship,
 279         skip_thread_containment: user.skip_thread_containment,
 280         background_image: image_url(user.background) |> MediaProxy.url(),
 281         accepts_chat_messages: user.accepts_chat_messages,
 282         favicon: favicon
 283       }
 284     }
 285     |> maybe_put_role(user, opts[:for])
 286     |> maybe_put_settings(user, opts[:for], opts)
 287     |> maybe_put_notification_settings(user, opts[:for])
 288     |> maybe_put_settings_store(user, opts[:for], opts)
 289     |> maybe_put_chat_token(user, opts[:for], opts)
 290     |> maybe_put_activation_status(user, opts[:for])
 291     |> maybe_put_follow_requests_count(user, opts[:for])
 292     |> maybe_put_allow_following_move(user, opts[:for])
 293     |> maybe_put_unread_conversation_count(user, opts[:for])
 294     |> maybe_put_unread_notification_count(user, opts[:for])
 295   end
 296
 297   defp username_from_nickname(string) when is_binary(string) do
 298     hd(String.split(string, "@"))
 299   end
 300
 301   defp username_from_nickname(_), do: nil
 302
 303   defp maybe_put_follow_requests_count(
 304          data,
 305          %User{id: user_id} = user,
 306          %User{id: user_id}
 307        ) do
 308     count =
 309       User.get_follow_requests(user)
 310       |> length()
 311
 312     data
 313     |> Kernel.put_in([:follow_requests_count], count)
 314   end
 315
 316   defp maybe_put_follow_requests_count(data, _, _), do: data
 317
 318   defp maybe_put_settings(
 319          data,
 320          %User{id: user_id} = user,
 321          %User{id: user_id},
 322          _opts
 323        ) do
 324     data
 325     |> Kernel.put_in([:source, :privacy], user.default_scope)
 326     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 327     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 328   end
 329
 330   defp maybe_put_settings(data, _, _, _), do: data
 331
 332   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 333          with_pleroma_settings: true
 334        }) do
 335     data
 336     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 337   end
 338
 339   defp maybe_put_settings_store(data, _, _, _), do: data
 340
 341   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 342          with_chat_token: token
 343        }) do
 344     data
 345     |> Kernel.put_in([:pleroma, :chat_token], token)
 346   end
 347
 348   defp maybe_put_chat_token(data, _, _, _), do: data
 349
 350   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 351     data
 352     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 353     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 354   end
 355
 356   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 357     data
 358     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 359     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 360   end
 361
 362   defp maybe_put_role(data, _, _), do: data
 363
 364   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 365     Kernel.put_in(
 366       data,
 367       [:pleroma, :notification_settings],
 368       Map.from_struct(user.notification_settings)
 369     )
 370   end
 371
 372   defp maybe_put_notification_settings(data, _, _), do: data
 373
 374   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 375     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 376   end
 377
 378   defp maybe_put_allow_following_move(data, _, _), do: data
 379
 380   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 381     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 382   end
 383
 384   defp maybe_put_activation_status(data, _, _), do: data
 385
 386   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 387     data
 388     |> Kernel.put_in(
 389       [:pleroma, :unread_conversation_count],
 390       user.unread_conversation_count
 391     )
 392   end
 393
 394   defp maybe_put_unread_conversation_count(data, _, _), do: data
 395
 396   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 397     Kernel.put_in(
 398       data,
 399       [:pleroma, :unread_notifications_count],
 400       Pleroma.Notification.unread_notifications_count(user)
 401     )
 402   end
 403
 404   defp maybe_put_unread_notification_count(data, _, _), do: data
 405
 406   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 407   defp image_url(_), do: nil
 408 end