git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.CommonAPI.Utils
  10   alias Pleroma.Web.MastodonAPI.AccountView
  11   alias Pleroma.Web.MediaProxy
  12
  13   def render("index.json", %{users: users} = opts) do
  14     users
  15     |> render_many(AccountView, "show.json", opts)
  16     |> Enum.filter(&Enum.any?/1)
  17   end
  18
  19   def render("show.json", %{user: user} = opts) do
  20     if User.visible_for?(user, opts[:for]),
  21       do: do_render("show.json", opts),
  22       else: %{}
  23   end
  24
  25   def render("mention.json", %{user: user}) do
  26     %{
  27       id: to_string(user.id),
  28       acct: user.nickname,
  29       username: username_from_nickname(user.nickname),
  30       url: User.profile_url(user)
  31     }
  32   end
  33
  34   def render("relationship.json", %{user: nil, target: _target}) do
  35     %{}
  36   end
  37
  38   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  39     follow_state = User.get_cached_follow_state(user, target)
  40
  41     requested =
  42       if follow_state && !User.following?(user, target) do
  43         follow_state == "pending"
  44       else
  45         false
  46       end
  47
  48     %{
  49       id: to_string(target.id),
  50       following: User.following?(user, target),
  51       followed_by: User.following?(target, user),
  52       blocking: User.blocks_user?(user, target),
  53       blocked_by: User.blocks_user?(target, user),
  54       muting: User.mutes?(user, target),
  55       muting_notifications: User.muted_notifications?(user, target),
  56       subscribing: User.subscribed_to?(user, target),
  57       requested: requested,
  58       domain_blocking: User.blocks_domain?(user, target),
  59       showing_reblogs: User.showing_reblogs?(user, target),
  60       endorsed: false
  61     }
  62   end
  63
  64   def render("relationships.json", %{user: user, targets: targets}) do
  65     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  66   end
  67
  68   defp do_render("show.json", %{user: user} = opts) do
  69     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
  70     display_name = user.name || user.nickname
  71
  72     image = User.avatar_url(user) |> MediaProxy.url()
  73     header = User.banner_url(user) |> MediaProxy.url()
  74
  75     following_count =
  76       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
  77         user.following_count || 0
  78       else
  79         0
  80       end
  81
  82     followers_count =
  83       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
  84         user.follower_count || 0
  85       else
  86         0
  87       end
  88
  89     bot = user.actor_type in ["Application", "Service"]
  90
  91     emojis =
  92       (user.source_data["tag"] || [])
  93       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  94       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  95         %{
  96           "shortcode" => String.trim(name, ":"),
  97           "url" => MediaProxy.url(url),
  98           "static_url" => MediaProxy.url(url),
  99           "visible_in_picker" => false
 100         }
 101       end)
 102
 103     relationship = render("relationship.json", %{user: opts[:for], target: user})
 104
 105     %{
 106       id: to_string(user.id),
 107       username: username_from_nickname(user.nickname),
 108       acct: user.nickname,
 109       display_name: display_name,
 110       locked: user.locked,
 111       created_at: Utils.to_masto_date(user.inserted_at),
 112       followers_count: followers_count,
 113       following_count: following_count,
 114       statuses_count: user.note_count,
 115       note: user.bio || "",
 116       url: User.profile_url(user),
 117       avatar: image,
 118       avatar_static: image,
 119       header: header,
 120       header_static: header,
 121       emojis: emojis,
 122       fields: user.fields,
 123       bot: bot,
 124       source: %{
 125         note: Pleroma.HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
 126         sensitive: false,
 127         fields: user.raw_fields,
 128         pleroma: %{
 129           discoverable: user.discoverable,
 130           actor_type: user.actor_type
 131         }
 132       },
 133
 134       # Pleroma extension
 135       pleroma: %{
 136         confirmation_pending: user.confirmation_pending,
 137         tags: user.tags,
 138         hide_followers_count: user.hide_followers_count,
 139         hide_follows_count: user.hide_follows_count,
 140         hide_followers: user.hide_followers,
 141         hide_follows: user.hide_follows,
 142         hide_favorites: user.hide_favorites,
 143         relationship: relationship,
 144         skip_thread_containment: user.skip_thread_containment,
 145         background_image: image_url(user.background) |> MediaProxy.url()
 146       }
 147     }
 148     |> maybe_put_role(user, opts[:for])
 149     |> maybe_put_settings(user, opts[:for], opts)
 150     |> maybe_put_notification_settings(user, opts[:for])
 151     |> maybe_put_settings_store(user, opts[:for], opts)
 152     |> maybe_put_chat_token(user, opts[:for], opts)
 153     |> maybe_put_activation_status(user, opts[:for])
 154     |> maybe_put_follow_requests_count(user, opts[:for])
 155     |> maybe_put_allow_following_move(user, opts[:for])
 156     |> maybe_put_unread_conversation_count(user, opts[:for])
 157   end
 158
 159   defp username_from_nickname(string) when is_binary(string) do
 160     hd(String.split(string, "@"))
 161   end
 162
 163   defp username_from_nickname(_), do: nil
 164
 165   defp maybe_put_follow_requests_count(
 166          data,
 167          %User{id: user_id} = user,
 168          %User{id: user_id}
 169        ) do
 170     count =
 171       User.get_follow_requests(user)
 172       |> length()
 173
 174     data
 175     |> Kernel.put_in([:follow_requests_count], count)
 176   end
 177
 178   defp maybe_put_follow_requests_count(data, _, _), do: data
 179
 180   defp maybe_put_settings(
 181          data,
 182          %User{id: user_id} = user,
 183          %User{id: user_id},
 184          _opts
 185        ) do
 186     data
 187     |> Kernel.put_in([:source, :privacy], user.default_scope)
 188     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 189     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 190   end
 191
 192   defp maybe_put_settings(data, _, _, _), do: data
 193
 194   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 195          with_pleroma_settings: true
 196        }) do
 197     data
 198     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 199   end
 200
 201   defp maybe_put_settings_store(data, _, _, _), do: data
 202
 203   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 204          with_chat_token: token
 205        }) do
 206     data
 207     |> Kernel.put_in([:pleroma, :chat_token], token)
 208   end
 209
 210   defp maybe_put_chat_token(data, _, _, _), do: data
 211
 212   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 213     data
 214     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 215     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 216   end
 217
 218   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 219     data
 220     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 221     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 222   end
 223
 224   defp maybe_put_role(data, _, _), do: data
 225
 226   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 227     Kernel.put_in(data, [:pleroma, :notification_settings], user.notification_settings)
 228   end
 229
 230   defp maybe_put_notification_settings(data, _, _), do: data
 231
 232   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 233     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 234   end
 235
 236   defp maybe_put_allow_following_move(data, _, _), do: data
 237
 238   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 239     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 240   end
 241
 242   defp maybe_put_activation_status(data, _, _), do: data
 243
 244   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 245     data
 246     |> Kernel.put_in(
 247       [:pleroma, :unread_conversation_count],
 248       user.unread_conversation_count
 249     )
 250   end
 251
 252   defp maybe_put_unread_conversation_count(data, _, _), do: data
 253
 254   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 255   defp image_url(_), do: nil
 256 end