git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserNote
  11   alias Pleroma.UserRelationship
  12   alias Pleroma.Web.CommonAPI.Utils
  13   alias Pleroma.Web.MastodonAPI.AccountView
  14   alias Pleroma.Web.MediaProxy
  15
  16   def render("index.json", %{users: users} = opts) do
  17     reading_user = opts[:for]
  18
  19     relationships_opt =
  20       cond do
  21         Map.has_key?(opts, :relationships) ->
  22           opts[:relationships]
  23
  24         is_nil(reading_user) || !opts[:embed_relationships] ->
  25           UserRelationship.view_relationships_option(nil, [])
  26
  27         true ->
  28           UserRelationship.view_relationships_option(reading_user, users)
  29       end
  30
  31     opts =
  32       opts
  33       |> Map.merge(%{relationships: relationships_opt, as: :user})
  34       |> Map.delete(:users)
  35
  36     users
  37     |> render_many(AccountView, "show.json", opts)
  38     |> Enum.filter(&Enum.any?/1)
  39   end
  40
  41   @doc """
  42   Renders specified user account.
  43     :skip_visibility_check option skips visibility check and renders any user (local or remote)
  44       regardless of [:pleroma, :restrict_unauthenticated] setting.
  45     :for option specifies the requester and can be a User record or nil.
  46       Only use `user: user, for: user` when `user` is the actual requester of own profile.
  47   """
  48   def render("show.json", %{user: _user, skip_visibility_check: true} = opts) do
  49     do_render("show.json", opts)
  50   end
  51
  52   def render("show.json", %{user: user, for: for_user_or_nil} = opts) do
  53     if User.visible_for(user, for_user_or_nil) == :visible do
  54       do_render("show.json", opts)
  55     else
  56       %{}
  57     end
  58   end
  59
  60   def render("show.json", _) do
  61     raise "In order to prevent account accessibility issues, " <>
  62             ":skip_visibility_check or :for option is required."
  63   end
  64
  65   def render("mention.json", %{user: user}) do
  66     %{
  67       id: to_string(user.id),
  68       acct: user.nickname,
  69       username: username_from_nickname(user.nickname),
  70       url: user.uri || user.ap_id
  71     }
  72   end
  73
  74   def render("relationship.json", %{user: nil, target: _target}) do
  75     %{}
  76   end
  77
  78   def render(
  79         "relationship.json",
  80         %{user: %User{} = reading_user, target: %User{} = target} = opts
  81       ) do
  82     user_relationships = get_in(opts, [:relationships, :user_relationships])
  83     following_relationships = get_in(opts, [:relationships, :following_relationships])
  84
  85     follow_state =
  86       if following_relationships do
  87         user_to_target_following_relation =
  88           FollowingRelationship.find(following_relationships, reading_user, target)
  89
  90         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  91       else
  92         User.get_follow_state(reading_user, target)
  93       end
  94
  95     followed_by =
  96       if following_relationships do
  97         case FollowingRelationship.find(following_relationships, target, reading_user) do
  98           %{state: :follow_accept} -> true
  99           _ -> false
 100         end
 101       else
 102         User.following?(target, reading_user)
 103       end
 104
 105     subscribing =
 106       UserRelationship.exists?(
 107         user_relationships,
 108         :inverse_subscription,
 109         target,
 110         reading_user,
 111         &User.subscribed_to?(&2, &1)
 112       )
 113
 114     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
 115     %{
 116       id: to_string(target.id),
 117       following: follow_state == :follow_accept,
 118       followed_by: followed_by,
 119       blocking:
 120         UserRelationship.exists?(
 121           user_relationships,
 122           :block,
 123           reading_user,
 124           target,
 125           &User.blocks_user?(&1, &2)
 126         ),
 127       blocked_by:
 128         UserRelationship.exists?(
 129           user_relationships,
 130           :block,
 131           target,
 132           reading_user,
 133           &User.blocks_user?(&1, &2)
 134         ),
 135       muting:
 136         UserRelationship.exists?(
 137           user_relationships,
 138           :mute,
 139           reading_user,
 140           target,
 141           &User.mutes?(&1, &2)
 142         ),
 143       muting_notifications:
 144         UserRelationship.exists?(
 145           user_relationships,
 146           :notification_mute,
 147           reading_user,
 148           target,
 149           &User.muted_notifications?(&1, &2)
 150         ),
 151       subscribing: subscribing,
 152       notifying: subscribing,
 153       requested: follow_state == :follow_pending,
 154       domain_blocking: User.blocks_domain?(reading_user, target),
 155       showing_reblogs:
 156         not UserRelationship.exists?(
 157           user_relationships,
 158           :reblog_mute,
 159           reading_user,
 160           target,
 161           &User.muting_reblogs?(&1, &2)
 162         ),
 163       endorsed: false,
 164       note:
 165         UserNote.show(
 166           reading_user,
 167           target
 168         )
 169     }
 170   end
 171
 172   def render("relationships.json", %{user: user, targets: targets} = opts) do
 173     relationships_opt =
 174       cond do
 175         Map.has_key?(opts, :relationships) ->
 176           opts[:relationships]
 177
 178         is_nil(user) ->
 179           UserRelationship.view_relationships_option(nil, [])
 180
 181         true ->
 182           UserRelationship.view_relationships_option(user, targets)
 183       end
 184
 185     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 186     render_many(targets, AccountView, "relationship.json", render_opts)
 187   end
 188
 189   def render("instance.json", %{instance: %Pleroma.Instances.Instance{} = instance}) do
 190     %{
 191       name: instance.host,
 192       favicon: instance.favicon |> MediaProxy.url(),
 193       nodeinfo: instance.nodeinfo
 194     }
 195   end
 196
 197   def render("instance.json", _), do: nil
 198
 199   defp do_render("show.json", %{user: user} = opts) do
 200     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 201     display_name = user.name || user.nickname
 202
 203     avatar = User.avatar_url(user) |> MediaProxy.url()
 204     avatar_static = User.avatar_url(user) |> MediaProxy.preview_url(static: true)
 205     header = User.banner_url(user) |> MediaProxy.url()
 206     header_static = User.banner_url(user) |> MediaProxy.preview_url(static: true)
 207
 208     following_count =
 209       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user,
 210         do: user.following_count,
 211         else: 0
 212
 213     followers_count =
 214       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user,
 215         do: user.follower_count,
 216         else: 0
 217
 218     bot = user.actor_type == "Service"
 219
 220     emojis =
 221       Enum.map(user.emoji, fn {shortcode, raw_url} ->
 222         url = MediaProxy.url(raw_url)
 223
 224         %{
 225           shortcode: shortcode,
 226           url: url,
 227           static_url: url,
 228           visible_in_picker: false
 229         }
 230       end)
 231
 232     relationship =
 233       if opts[:embed_relationships] do
 234         render("relationship.json", %{
 235           user: opts[:for],
 236           target: user,
 237           relationships: opts[:relationships]
 238         })
 239       else
 240         %{}
 241       end
 242
 243     instance =
 244       with {:ok, instance} <- Pleroma.Instances.Instance.get_cached_by_url(user.ap_id) do
 245         instance
 246       else
 247         _ ->
 248           nil
 249       end
 250
 251     favicon =
 252       if is_nil(instance) do
 253         nil
 254       else
 255         instance.favicon
 256         |> MediaProxy.url()
 257       end
 258
 259     %{
 260       id: to_string(user.id),
 261       username: username_from_nickname(user.nickname),
 262       acct: user.nickname,
 263       display_name: display_name,
 264       locked: user.is_locked,
 265       created_at: Utils.to_masto_date(user.inserted_at),
 266       followers_count: followers_count,
 267       following_count: following_count,
 268       statuses_count: user.note_count,
 269       note: user.bio,
 270       url: user.uri || user.ap_id,
 271       avatar: avatar,
 272       avatar_static: avatar_static,
 273       header: header,
 274       header_static: header_static,
 275       emojis: emojis,
 276       fields: user.fields,
 277       bot: bot,
 278       source: %{
 279         note: user.raw_bio || "",
 280         sensitive: false,
 281         fields: user.raw_fields,
 282         pleroma: %{
 283           discoverable: user.is_discoverable,
 284           actor_type: user.actor_type
 285         }
 286       },
 287       last_status_at: user.last_status_at,
 288       akkoma: %{
 289         instance: render("instance.json", %{instance: instance})
 290       },
 291       # Pleroma extensions
 292       # Note: it's insecure to output :email but fully-qualified nickname may serve as safe stub
 293       fqn: User.full_nickname(user),
 294       pleroma: %{
 295         ap_id: user.ap_id,
 296         also_known_as: user.also_known_as,
 297         is_confirmed: user.is_confirmed,
 298         is_suggested: user.is_suggested,
 299         tags: user.tags,
 300         hide_followers_count: user.hide_followers_count,
 301         hide_follows_count: user.hide_follows_count,
 302         hide_followers: user.hide_followers,
 303         hide_follows: user.hide_follows,
 304         hide_favorites: user.hide_favorites,
 305         relationship: relationship,
 306         skip_thread_containment: user.skip_thread_containment,
 307         background_image: image_url(user.background) |> MediaProxy.url(),
 308         favicon: favicon
 309       }
 310     }
 311     |> maybe_put_role(user, opts[:for])
 312     |> maybe_put_settings(user, opts[:for], opts)
 313     |> maybe_put_notification_settings(user, opts[:for])
 314     |> maybe_put_settings_store(user, opts[:for], opts)
 315     |> maybe_put_activation_status(user, opts[:for])
 316     |> maybe_put_follow_requests_count(user, opts[:for])
 317     |> maybe_put_allow_following_move(user, opts[:for])
 318     |> maybe_put_unread_conversation_count(user, opts[:for])
 319     |> maybe_put_unread_notification_count(user, opts[:for])
 320     |> maybe_put_email_address(user, opts[:for])
 321   end
 322
 323   defp username_from_nickname(string) when is_binary(string) do
 324     hd(String.split(string, "@"))
 325   end
 326
 327   defp username_from_nickname(_), do: nil
 328
 329   defp maybe_put_follow_requests_count(
 330          data,
 331          %User{id: user_id} = user,
 332          %User{id: user_id}
 333        ) do
 334     count =
 335       User.get_follow_requests(user)
 336       |> length()
 337
 338     data
 339     |> Kernel.put_in([:follow_requests_count], count)
 340   end
 341
 342   defp maybe_put_follow_requests_count(data, _, _), do: data
 343
 344   defp maybe_put_settings(
 345          data,
 346          %User{id: user_id} = user,
 347          %User{id: user_id},
 348          _opts
 349        ) do
 350     data
 351     |> Kernel.put_in([:source, :privacy], user.default_scope)
 352     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 353     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 354   end
 355
 356   defp maybe_put_settings(data, _, _, _), do: data
 357
 358   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 359          with_pleroma_settings: true
 360        }) do
 361     data
 362     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 363   end
 364
 365   defp maybe_put_settings_store(data, _, _, _), do: data
 366
 367   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 368     data
 369     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 370     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 371   end
 372
 373   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 374     data
 375     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 376     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 377   end
 378
 379   defp maybe_put_role(data, _, _), do: data
 380
 381   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 382     Kernel.put_in(
 383       data,
 384       [:pleroma, :notification_settings],
 385       Map.from_struct(user.notification_settings)
 386     )
 387   end
 388
 389   defp maybe_put_notification_settings(data, _, _), do: data
 390
 391   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 392     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 393   end
 394
 395   defp maybe_put_allow_following_move(data, _, _), do: data
 396
 397   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 398     Kernel.put_in(data, [:pleroma, :deactivated], !user.is_active)
 399   end
 400
 401   defp maybe_put_activation_status(data, _, _), do: data
 402
 403   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 404     data
 405     |> Kernel.put_in(
 406       [:pleroma, :unread_conversation_count],
 407       Pleroma.Conversation.Participation.unread_count(user)
 408     )
 409   end
 410
 411   defp maybe_put_unread_conversation_count(data, _, _), do: data
 412
 413   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 414     Kernel.put_in(
 415       data,
 416       [:pleroma, :unread_notifications_count],
 417       Pleroma.Notification.unread_notifications_count(user)
 418     )
 419   end
 420
 421   defp maybe_put_unread_notification_count(data, _, _), do: data
 422
 423   defp maybe_put_email_address(data, %User{id: user_id}, %User{id: user_id} = user) do
 424     Kernel.put_in(
 425       data,
 426       [:pleroma, :email],
 427       user.email
 428     )
 429   end
 430
 431   defp maybe_put_email_address(data, _, _), do: data
 432
 433   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 434   defp image_url(_), do: nil
 435 end