git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.HTML
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MastodonAPI.AccountView
  12   alias Pleroma.Web.MediaProxy
  13
  14   def render("accounts.json", %{users: users} = opts) do
  15     users
  16     |> render_many(AccountView, "account.json", opts)
  17     |> Enum.filter(&Enum.any?/1)
  18   end
  19
  20   def render("account.json", %{user: user} = opts) do
  21     if User.visible_for?(user, opts[:for]),
  22       do: do_render("account.json", opts),
  23       else: %{}
  24   end
  25
  26   def render("mention.json", %{user: user}) do
  27     %{
  28       id: to_string(user.id),
  29       acct: user.nickname,
  30       username: username_from_nickname(user.nickname),
  31       url: user.ap_id
  32     }
  33   end
  34
  35   def render("relationship.json", %{user: nil, target: _target}) do
  36     %{}
  37   end
  38
  39   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  40     follow_activity = Pleroma.Web.ActivityPub.Utils.fetch_latest_follow(user, target)
  41
  42     requested =
  43       if follow_activity && !User.following?(target, user) do
  44         follow_activity.data["state"] == "pending"
  45       else
  46         false
  47       end
  48
  49     %{
  50       id: to_string(target.id),
  51       following: User.following?(user, target),
  52       followed_by: User.following?(target, user),
  53       blocking: User.blocks?(user, target),
  54       muting: User.mutes?(user, target),
  55       muting_notifications: false,
  56       subscribing: User.subscribed_to?(user, target),
  57       requested: requested,
  58       domain_blocking: false,
  59       showing_reblogs: User.showing_reblogs?(user, target),
  60       endorsed: false
  61     }
  62   end
  63
  64   def render("relationships.json", %{user: user, targets: targets}) do
  65     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  66   end
  67
  68   defp do_render("account.json", %{user: user} = opts) do
  69     image = User.avatar_url(user) |> MediaProxy.url()
  70     header = User.banner_url(user) |> MediaProxy.url()
  71     user_info = User.get_cached_user_info(user)
  72     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  73
  74     emojis =
  75       (user.info.source_data["tag"] || [])
  76       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  77       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  78         %{
  79           "shortcode" => String.trim(name, ":"),
  80           "url" => MediaProxy.url(url),
  81           "static_url" => MediaProxy.url(url),
  82           "visible_in_picker" => false
  83         }
  84       end)
  85
  86     fields =
  87       (user.info.source_data["attachment"] || [])
  88       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  89       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  90
  91     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
  92
  93     relationship = render("relationship.json", %{user: opts[:for], target: user})
  94
  95     %{
  96       id: to_string(user.id),
  97       username: username_from_nickname(user.nickname),
  98       acct: user.nickname,
  99       display_name: user.name || user.nickname,
 100       locked: user_info.locked,
 101       created_at: Utils.to_masto_date(user.inserted_at),
 102       followers_count: user_info.follower_count,
 103       following_count: user_info.following_count,
 104       statuses_count: user_info.note_count,
 105       note: bio || "",
 106       url: user.ap_id,
 107       avatar: image,
 108       avatar_static: image,
 109       header: header,
 110       header_static: header,
 111       emojis: emojis,
 112       fields: fields,
 113       bot: bot,
 114       source: %{
 115         note: HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
 116         sensitive: false,
 117         pleroma: %{}
 118       },
 119
 120       # Pleroma extension
 121       pleroma: %{
 122         confirmation_pending: user_info.confirmation_pending,
 123         tags: user.tags,
 124         hide_followers: user.info.hide_followers,
 125         hide_follows: user.info.hide_follows,
 126         hide_favorites: user.info.hide_favorites,
 127         relationship: relationship
 128       }
 129     }
 130     |> maybe_put_role(user, opts[:for])
 131     |> maybe_put_settings(user, opts[:for], user_info)
 132     |> maybe_put_notification_settings(user, opts[:for])
 133   end
 134
 135   defp username_from_nickname(string) when is_binary(string) do
 136     hd(String.split(string, "@"))
 137   end
 138
 139   defp username_from_nickname(_), do: nil
 140
 141   defp maybe_put_settings(
 142          data,
 143          %User{id: user_id} = user,
 144          %User{id: user_id},
 145          user_info
 146        ) do
 147     data
 148     |> Kernel.put_in([:source, :privacy], user_info.default_scope)
 149     |> Kernel.put_in([:source, :pleroma, :show_role], user.info.show_role)
 150     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.info.no_rich_text)
 151   end
 152
 153   defp maybe_put_settings(data, _, _, _), do: data
 154
 155   defp maybe_put_role(data, %User{info: %{show_role: true}} = user, _) do
 156     data
 157     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 158     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 159   end
 160
 161   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 162     data
 163     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 164     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 165   end
 166
 167   defp maybe_put_role(data, _, _), do: data
 168
 169   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 170     Kernel.put_in(data, [:pleroma, :notification_settings], user.info.notification_settings)
 171   end
 172
 173   defp maybe_put_notification_settings(data, _, _), do: data
 174 end