git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7   alias Pleroma.User
   8   alias Pleroma.Web.MastodonAPI.AccountView
   9   alias Pleroma.Web.CommonAPI.Utils
  10   alias Pleroma.Web.MediaProxy
  11   alias Pleroma.HTML
  12
  13   def render("accounts.json", %{users: users} = opts) do
  14     render_many(users, AccountView, "account.json", opts)
  15   end
  16
  17   def render("account.json", %{user: user} = opts) do
  18     image = User.avatar_url(user) |> MediaProxy.url()
  19     header = User.banner_url(user) |> MediaProxy.url()
  20     user_info = User.user_info(user)
  21     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  22
  23     emojis =
  24       (user.info.source_data["tag"] || [])
  25       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  26       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  27         %{
  28           "shortcode" => String.trim(name, ":"),
  29           "url" => MediaProxy.url(url),
  30           "static_url" => MediaProxy.url(url),
  31           "visible_in_picker" => false
  32         }
  33       end)
  34
  35     fields =
  36       (user.info.source_data["attachment"] || [])
  37       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  38       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  39
  40     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
  41
  42     %{
  43       id: to_string(user.id),
  44       username: username_from_nickname(user.nickname),
  45       acct: user.nickname,
  46       display_name: user.name || user.nickname,
  47       locked: user_info.locked,
  48       created_at: Utils.to_masto_date(user.inserted_at),
  49       followers_count: user_info.follower_count,
  50       following_count: user_info.following_count,
  51       statuses_count: user_info.note_count,
  52       note: bio || "",
  53       url: user.ap_id,
  54       avatar: image,
  55       avatar_static: image,
  56       header: header,
  57       header_static: header,
  58       emojis: emojis,
  59       fields: fields,
  60       bot: bot,
  61       source: %{
  62         note: "",
  63         privacy: user_info.default_scope,
  64         sensitive: false
  65       },
  66
  67       # Pleroma extension
  68       pleroma: %{
  69         confirmation_pending: user_info.confirmation_pending,
  70         tags: user.tags
  71       }
  72     }
  73   end
  74
  75   def render("mention.json", %{user: user}) do
  76     %{
  77       id: to_string(user.id),
  78       acct: user.nickname,
  79       username: username_from_nickname(user.nickname),
  80       url: user.ap_id
  81     }
  82   end
  83
  84   def render("relationship.json", %{user: user, target: target}) do
  85     follow_activity = Pleroma.Web.ActivityPub.Utils.fetch_latest_follow(user, target)
  86
  87     requested =
  88       if follow_activity do
  89         follow_activity.data["state"] == "pending"
  90       else
  91         false
  92       end
  93
  94     %{
  95       id: to_string(target.id),
  96       following: User.following?(user, target),
  97       followed_by: User.following?(target, user),
  98       blocking: User.blocks?(user, target),
  99       muting: false,
 100       muting_notifications: false,
 101       requested: requested,
 102       domain_blocking: false,
 103       showing_reblogs: false,
 104       endorsed: false
 105     }
 106   end
 107
 108   def render("relationships.json", %{user: user, targets: targets}) do
 109     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
 110   end
 111
 112   defp username_from_nickname(string) when is_binary(string) do
 113     hd(String.split(string, "@"))
 114   end
 115
 116   defp username_from_nickname(_), do: nil
 117 end