git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 defmodule Pleroma.Web.MastodonAPI.AccountView do
   2   use Pleroma.Web, :view
   3   alias Pleroma.User
   4   alias Pleroma.Web.MastodonAPI.AccountView
   5   alias Pleroma.Web.CommonAPI.Utils
   6   alias Pleroma.Web.MediaProxy
   7
   8   def render("accounts.json", %{users: users} = opts) do
   9     render_many(users, AccountView, "account.json", opts)
  10   end
  11
  12   def render("account.json", %{user: user}) do
  13     image = User.avatar_url(user) |> MediaProxy.url()
  14     header = User.banner_url(user) |> MediaProxy.url()
  15     user_info = User.user_info(user)
  16     bot = (user.info["source_data"]["type"] || "Person") in ["Application", "Service"]
  17
  18     emojis =
  19       (user.info["source_data"]["tag"] || [])
  20       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  21       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  22         %{
  23           "shortcode" => String.trim(name, ":"),
  24           "url" => MediaProxy.url(url),
  25           "static_url" => MediaProxy.url(url),
  26           "visible_in_picker" => false
  27         }
  28       end)
  29
  30     %{
  31       id: to_string(user.id),
  32       username: hd(String.split(user.nickname, "@")),
  33       acct: user.nickname,
  34       display_name: user.name || user.nickname,
  35       locked: user_info.locked,
  36       created_at: Utils.to_masto_date(user.inserted_at),
  37       followers_count: user_info.follower_count,
  38       following_count: user_info.following_count,
  39       statuses_count: user_info.note_count,
  40       note: HtmlSanitizeEx.basic_html(user.bio) || "",
  41       url: user.ap_id,
  42       avatar: image,
  43       avatar_static: image,
  44       header: header,
  45       header_static: header,
  46       emojis: emojis,
  47       fields: [],
  48       bot: bot,
  49       source: %{
  50         note: "",
  51         privacy: "public",
  52         sensitive: "false"
  53       }
  54     }
  55   end
  56
  57   def render("mention.json", %{user: user}) do
  58     %{
  59       id: to_string(user.id),
  60       acct: user.nickname,
  61       username: hd(String.split(user.nickname, "@")),
  62       url: user.ap_id
  63     }
  64   end
  65
  66   def render("relationship.json", %{user: user, target: target}) do
  67     %{
  68       id: to_string(target.id),
  69       following: User.following?(user, target),
  70       followed_by: User.following?(target, user),
  71       blocking: User.blocks?(user, target),
  72       muting: false,
  73       requested: false,
  74       domain_blocking: false
  75     }
  76   end
  77
  78   def render("relationships.json", %{user: user, targets: targets}) do
  79     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  80   end
  81 end