git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     reading_user = opts[:for]
  17
  18     relationships_opt =
  19       cond do
  20         Map.has_key?(opts, :relationships) ->
  21           opts[:relationships]
  22
  23         is_nil(reading_user) || !opts[:embed_relationships] ->
  24           UserRelationship.view_relationships_option(nil, [])
  25
  26         true ->
  27           UserRelationship.view_relationships_option(reading_user, users)
  28       end
  29
  30     opts = Map.put(opts, :relationships, relationships_opt)
  31
  32     users
  33     |> render_many(AccountView, "show.json", opts)
  34     |> Enum.filter(&Enum.any?/1)
  35   end
  36
  37   def render("show.json", %{user: user} = opts) do
  38     if User.visible_for?(user, opts[:for]) do
  39       do_render("show.json", opts)
  40     else
  41       %{}
  42     end
  43   end
  44
  45   def render("mention.json", %{user: user}) do
  46     %{
  47       id: to_string(user.id),
  48       acct: user.nickname,
  49       username: username_from_nickname(user.nickname),
  50       url: user.uri || user.ap_id
  51     }
  52   end
  53
  54   def render("relationship.json", %{user: nil, target: _target}) do
  55     %{}
  56   end
  57
  58   def render(
  59         "relationship.json",
  60         %{user: %User{} = reading_user, target: %User{} = target} = opts
  61       ) do
  62     user_relationships = get_in(opts, [:relationships, :user_relationships])
  63     following_relationships = get_in(opts, [:relationships, :following_relationships])
  64
  65     follow_state =
  66       if following_relationships do
  67         user_to_target_following_relation =
  68           FollowingRelationship.find(following_relationships, reading_user, target)
  69
  70         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  71       else
  72         User.get_follow_state(reading_user, target)
  73       end
  74
  75     followed_by =
  76       if following_relationships do
  77         case FollowingRelationship.find(following_relationships, target, reading_user) do
  78           %{state: :follow_accept} -> true
  79           _ -> false
  80         end
  81       else
  82         User.following?(target, reading_user)
  83       end
  84
  85     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
  86     %{
  87       id: to_string(target.id),
  88       following: follow_state == :follow_accept,
  89       followed_by: followed_by,
  90       blocking:
  91         UserRelationship.exists?(
  92           user_relationships,
  93           :block,
  94           reading_user,
  95           target,
  96           &User.blocks_user?(&1, &2)
  97         ),
  98       blocked_by:
  99         UserRelationship.exists?(
 100           user_relationships,
 101           :block,
 102           target,
 103           reading_user,
 104           &User.blocks_user?(&1, &2)
 105         ),
 106       muting:
 107         UserRelationship.exists?(
 108           user_relationships,
 109           :mute,
 110           reading_user,
 111           target,
 112           &User.mutes?(&1, &2)
 113         ),
 114       muting_notifications:
 115         UserRelationship.exists?(
 116           user_relationships,
 117           :notification_mute,
 118           reading_user,
 119           target,
 120           &User.muted_notifications?(&1, &2)
 121         ),
 122       subscribing:
 123         UserRelationship.exists?(
 124           user_relationships,
 125           :inverse_subscription,
 126           target,
 127           reading_user,
 128           &User.subscribed_to?(&2, &1)
 129         ),
 130       requested: follow_state == :follow_pending,
 131       domain_blocking: User.blocks_domain?(reading_user, target),
 132       showing_reblogs:
 133         not UserRelationship.exists?(
 134           user_relationships,
 135           :reblog_mute,
 136           reading_user,
 137           target,
 138           &User.muting_reblogs?(&1, &2)
 139         ),
 140       endorsed: false
 141     }
 142   end
 143
 144   def render("relationships.json", %{user: user, targets: targets} = opts) do
 145     relationships_opt =
 146       cond do
 147         Map.has_key?(opts, :relationships) ->
 148           opts[:relationships]
 149
 150         is_nil(user) ->
 151           UserRelationship.view_relationships_option(nil, [])
 152
 153         true ->
 154           UserRelationship.view_relationships_option(user, targets)
 155       end
 156
 157     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 158     render_many(targets, AccountView, "relationship.json", render_opts)
 159   end
 160
 161   defp do_render("show.json", %{user: user} = opts) do
 162     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 163     display_name = user.name || user.nickname
 164
 165     image = User.avatar_url(user) |> MediaProxy.url()
 166     header = User.banner_url(user) |> MediaProxy.url()
 167
 168     following_count =
 169       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 170         user.following_count || 0
 171       else
 172         0
 173       end
 174
 175     followers_count =
 176       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 177         user.follower_count || 0
 178       else
 179         0
 180       end
 181
 182     bot = user.actor_type in ["Application", "Service"]
 183
 184     emojis =
 185       Enum.map(user.emoji, fn {shortcode, raw_url} ->
 186         url = MediaProxy.url(raw_url)
 187
 188         %{
 189           shortcode: shortcode,
 190           url: url,
 191           static_url: url,
 192           visible_in_picker: false
 193         }
 194       end)
 195
 196     relationship =
 197       if opts[:embed_relationships] do
 198         render("relationship.json", %{
 199           user: opts[:for],
 200           target: user,
 201           relationships: opts[:relationships]
 202         })
 203       else
 204         %{}
 205       end
 206
 207     %{
 208       id: to_string(user.id),
 209       username: username_from_nickname(user.nickname),
 210       acct: user.nickname,
 211       display_name: display_name,
 212       locked: user.locked,
 213       created_at: Utils.to_masto_date(user.inserted_at),
 214       followers_count: followers_count,
 215       following_count: following_count,
 216       statuses_count: user.note_count,
 217       note: user.bio || "",
 218       url: user.uri || user.ap_id,
 219       avatar: image,
 220       avatar_static: image,
 221       header: header,
 222       header_static: header,
 223       emojis: emojis,
 224       fields: user.fields,
 225       bot: bot,
 226       source: %{
 227         note: user.raw_bio || "",
 228         sensitive: false,
 229         fields: user.raw_fields,
 230         pleroma: %{
 231           discoverable: user.discoverable,
 232           actor_type: user.actor_type
 233         }
 234       },
 235
 236       # Pleroma extension
 237       pleroma: %{
 238         ap_id: user.ap_id,
 239         confirmation_pending: user.confirmation_pending,
 240         tags: user.tags,
 241         hide_followers_count: user.hide_followers_count,
 242         hide_follows_count: user.hide_follows_count,
 243         hide_followers: user.hide_followers,
 244         hide_follows: user.hide_follows,
 245         hide_favorites: user.hide_favorites,
 246         relationship: relationship,
 247         skip_thread_containment: user.skip_thread_containment,
 248         background_image: image_url(user.background) |> MediaProxy.url()
 249       }
 250     }
 251     |> maybe_put_role(user, opts[:for])
 252     |> maybe_put_settings(user, opts[:for], opts)
 253     |> maybe_put_notification_settings(user, opts[:for])
 254     |> maybe_put_settings_store(user, opts[:for], opts)
 255     |> maybe_put_chat_token(user, opts[:for], opts)
 256     |> maybe_put_activation_status(user, opts[:for])
 257     |> maybe_put_follow_requests_count(user, opts[:for])
 258     |> maybe_put_allow_following_move(user, opts[:for])
 259     |> maybe_put_unread_conversation_count(user, opts[:for])
 260     |> maybe_put_unread_notification_count(user, opts[:for])
 261   end
 262
 263   defp username_from_nickname(string) when is_binary(string) do
 264     hd(String.split(string, "@"))
 265   end
 266
 267   defp username_from_nickname(_), do: nil
 268
 269   defp maybe_put_follow_requests_count(
 270          data,
 271          %User{id: user_id} = user,
 272          %User{id: user_id}
 273        ) do
 274     count =
 275       User.get_follow_requests(user)
 276       |> length()
 277
 278     data
 279     |> Kernel.put_in([:follow_requests_count], count)
 280   end
 281
 282   defp maybe_put_follow_requests_count(data, _, _), do: data
 283
 284   defp maybe_put_settings(
 285          data,
 286          %User{id: user_id} = user,
 287          %User{id: user_id},
 288          _opts
 289        ) do
 290     data
 291     |> Kernel.put_in([:source, :privacy], user.default_scope)
 292     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 293     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 294   end
 295
 296   defp maybe_put_settings(data, _, _, _), do: data
 297
 298   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 299          with_pleroma_settings: true
 300        }) do
 301     data
 302     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 303   end
 304
 305   defp maybe_put_settings_store(data, _, _, _), do: data
 306
 307   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 308          with_chat_token: token
 309        }) do
 310     data
 311     |> Kernel.put_in([:pleroma, :chat_token], token)
 312   end
 313
 314   defp maybe_put_chat_token(data, _, _, _), do: data
 315
 316   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 317     data
 318     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 319     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 320   end
 321
 322   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 323     data
 324     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 325     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 326   end
 327
 328   defp maybe_put_role(data, _, _), do: data
 329
 330   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 331     Kernel.put_in(
 332       data,
 333       [:pleroma, :notification_settings],
 334       Map.from_struct(user.notification_settings)
 335     )
 336   end
 337
 338   defp maybe_put_notification_settings(data, _, _), do: data
 339
 340   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 341     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 342   end
 343
 344   defp maybe_put_allow_following_move(data, _, _), do: data
 345
 346   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 347     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 348   end
 349
 350   defp maybe_put_activation_status(data, _, _), do: data
 351
 352   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 353     data
 354     |> Kernel.put_in(
 355       [:pleroma, :unread_conversation_count],
 356       user.unread_conversation_count
 357     )
 358   end
 359
 360   defp maybe_put_unread_conversation_count(data, _, _), do: data
 361
 362   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 363     Kernel.put_in(
 364       data,
 365       [:pleroma, :unread_notifications_count],
 366       Pleroma.Notification.unread_notifications_count(user)
 367     )
 368   end
 369
 370   defp maybe_put_unread_notification_count(data, _, _), do: data
 371
 372   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 373   defp image_url(_), do: nil
 374 end