git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.HTML
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MastodonAPI.AccountView
  12   alias Pleroma.Web.MediaProxy
  13
  14   def render("accounts.json", %{users: users} = opts) do
  15     users
  16     |> render_many(AccountView, "account.json", opts)
  17     |> Enum.filter(&Enum.any?/1)
  18   end
  19
  20   def render("account.json", %{user: user} = opts) do
  21     if User.visible_for?(user, opts[:for]),
  22       do: do_render("account.json", opts),
  23       else: %{}
  24   end
  25
  26   def render("mention.json", %{user: user}) do
  27     %{
  28       id: to_string(user.id),
  29       acct: user.nickname,
  30       username: username_from_nickname(user.nickname),
  31       url: user.ap_id
  32     }
  33   end
  34
  35   def render("relationship.json", %{user: nil, target: _target}) do
  36     %{}
  37   end
  38
  39   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  40     follow_activity = Pleroma.Web.ActivityPub.Utils.fetch_latest_follow(user, target)
  41
  42     requested =
  43       if follow_activity && !User.following?(target, user) do
  44         follow_activity.data["state"] == "pending"
  45       else
  46         false
  47       end
  48
  49     %{
  50       id: to_string(target.id),
  51       following: User.following?(user, target),
  52       followed_by: User.following?(target, user),
  53       blocking: User.blocks?(user, target),
  54       muting: User.mutes?(user, target),
  55       muting_notifications: false,
  56       subscribing: User.subscribed_to?(user, target),
  57       requested: requested,
  58       domain_blocking: false,
  59       showing_reblogs: User.showing_reblogs?(user, target),
  60       endorsed: false
  61     }
  62   end
  63
  64   def render("relationships.json", %{user: user, targets: targets}) do
  65     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  66   end
  67
  68   defp do_render("account.json", %{user: user} = opts) do
  69     display_name = HTML.strip_tags(user.name || user.nickname)
  70
  71     image = User.avatar_url(user) |> MediaProxy.url()
  72     header = User.banner_url(user) |> MediaProxy.url()
  73     user_info = User.get_cached_user_info(user)
  74     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  75
  76     emojis =
  77       (user.info.source_data["tag"] || [])
  78       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  79       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  80         %{
  81           "shortcode" => String.trim(name, ":"),
  82           "url" => MediaProxy.url(url),
  83           "static_url" => MediaProxy.url(url),
  84           "visible_in_picker" => false
  85         }
  86       end)
  87
  88     fields =
  89       (user.info.source_data["attachment"] || [])
  90       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  91       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  92
  93     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
  94
  95     relationship = render("relationship.json", %{user: opts[:for], target: user})
  96
  97     %{
  98       id: to_string(user.id),
  99       username: username_from_nickname(user.nickname),
 100       acct: user.nickname,
 101       display_name: display_name,
 102       locked: user_info.locked,
 103       created_at: Utils.to_masto_date(user.inserted_at),
 104       followers_count: user_info.follower_count,
 105       following_count: user_info.following_count,
 106       statuses_count: user_info.note_count,
 107       note: bio || "",
 108       url: user.ap_id,
 109       avatar: image,
 110       avatar_static: image,
 111       header: header,
 112       header_static: header,
 113       emojis: emojis,
 114       fields: fields,
 115       bot: bot,
 116       source: %{
 117         note: HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
 118         sensitive: false,
 119         pleroma: %{}
 120       },
 121
 122       # Pleroma extension
 123       pleroma: %{
 124         confirmation_pending: user_info.confirmation_pending,
 125         tags: user.tags,
 126         hide_followers: user.info.hide_followers,
 127         hide_follows: user.info.hide_follows,
 128         hide_favorites: user.info.hide_favorites,
 129         relationship: relationship,
 130         skip_thread_containment: user.info.skip_thread_containment,
 131         background_image: image_url(user.info.background) |> MediaProxy.url()
 132       }
 133     }
 134     |> maybe_put_role(user, opts[:for])
 135     |> maybe_put_settings(user, opts[:for], user_info)
 136     |> maybe_put_notification_settings(user, opts[:for])
 137     |> maybe_put_settings_store(user, opts[:for], opts)
 138     |> maybe_put_chat_token(user, opts[:for], opts)
 139   end
 140
 141   defp username_from_nickname(string) when is_binary(string) do
 142     hd(String.split(string, "@"))
 143   end
 144
 145   defp username_from_nickname(_), do: nil
 146
 147   defp maybe_put_settings(
 148          data,
 149          %User{id: user_id} = user,
 150          %User{id: user_id},
 151          user_info
 152        ) do
 153     data
 154     |> Kernel.put_in([:source, :privacy], user_info.default_scope)
 155     |> Kernel.put_in([:source, :pleroma, :show_role], user.info.show_role)
 156     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.info.no_rich_text)
 157   end
 158
 159   defp maybe_put_settings(data, _, _, _), do: data
 160
 161   defp maybe_put_settings_store(data, %User{info: info, id: id}, %User{id: id}, %{
 162          with_pleroma_settings: true
 163        }) do
 164     data
 165     |> Kernel.put_in([:pleroma, :settings_store], info.pleroma_settings_store)
 166   end
 167
 168   defp maybe_put_settings_store(data, _, _, _), do: data
 169
 170   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 171          with_chat_token: token
 172        }) do
 173     data
 174     |> Kernel.put_in([:pleroma, :chat_token], token)
 175   end
 176
 177   defp maybe_put_chat_token(data, _, _, _), do: data
 178
 179   defp maybe_put_role(data, %User{info: %{show_role: true}} = user, _) do
 180     data
 181     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 182     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 183   end
 184
 185   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 186     data
 187     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 188     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 189   end
 190
 191   defp maybe_put_role(data, _, _), do: data
 192
 193   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 194     Kernel.put_in(data, [:pleroma, :notification_settings], user.info.notification_settings)
 195   end
 196
 197   defp maybe_put_notification_settings(data, _, _), do: data
 198
 199   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 200   defp image_url(_), do: nil
 201 end