git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7   alias Pleroma.User
   8   alias Pleroma.Web.MastodonAPI.AccountView
   9   alias Pleroma.Web.CommonAPI.Utils
  10   alias Pleroma.Web.MediaProxy
  11   alias Pleroma.HTML
  12
  13   def render("accounts.json", %{users: users} = opts) do
  14     users
  15     |> render_many(AccountView, "account.json", opts)
  16     |> Enum.filter(&Enum.any?/1)
  17   end
  18
  19   def render("account.json", %{user: user} = opts) do
  20     if User.visible_for?(user, opts[:for]),
  21       do: do_render("account.json", opts),
  22       else: %{}
  23   end
  24
  25   def render("mention.json", %{user: user}) do
  26     %{
  27       id: to_string(user.id),
  28       acct: user.nickname,
  29       username: username_from_nickname(user.nickname),
  30       url: user.ap_id
  31     }
  32   end
  33
  34   def render("relationship.json", %{user: user, target: target}) do
  35     follow_activity = Pleroma.Web.ActivityPub.Utils.fetch_latest_follow(user, target)
  36
  37     requested =
  38       if follow_activity do
  39         follow_activity.data["state"] == "pending"
  40       else
  41         false
  42       end
  43
  44     %{
  45       id: to_string(target.id),
  46       following: User.following?(user, target),
  47       followed_by: User.following?(target, user),
  48       blocking: User.blocks?(user, target),
  49       muting: false,
  50       muting_notifications: false,
  51       requested: requested,
  52       domain_blocking: false,
  53       showing_reblogs: false,
  54       endorsed: false
  55     }
  56   end
  57
  58   def render("relationships.json", %{user: user, targets: targets}) do
  59     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  60   end
  61
  62   defp do_render("account.json", %{user: user} = opts) do
  63     image = User.avatar_url(user) |> MediaProxy.url()
  64     header = User.banner_url(user) |> MediaProxy.url()
  65     user_info = User.user_info(user)
  66     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  67
  68     emojis =
  69       (user.info.source_data["tag"] || [])
  70       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  71       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  72         %{
  73           "shortcode" => String.trim(name, ":"),
  74           "url" => MediaProxy.url(url),
  75           "static_url" => MediaProxy.url(url),
  76           "visible_in_picker" => false
  77         }
  78       end)
  79
  80     fields =
  81       (user.info.source_data["attachment"] || [])
  82       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  83       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  84
  85     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
  86
  87     %{
  88       id: to_string(user.id),
  89       username: username_from_nickname(user.nickname),
  90       acct: user.nickname,
  91       display_name: user.name || user.nickname,
  92       locked: user_info.locked,
  93       created_at: Utils.to_masto_date(user.inserted_at),
  94       followers_count: user_info.follower_count,
  95       following_count: user_info.following_count,
  96       statuses_count: user_info.note_count,
  97       note: bio || "",
  98       url: user.ap_id,
  99       avatar: image,
 100       avatar_static: image,
 101       header: header,
 102       header_static: header,
 103       emojis: emojis,
 104       fields: fields,
 105       bot: bot,
 106       source: %{
 107         note: "",
 108         privacy: user_info.default_scope,
 109         sensitive: false
 110       },
 111
 112       # Pleroma extension
 113       pleroma: %{
 114         confirmation_pending: user_info.confirmation_pending,
 115         tags: user.tags
 116       }
 117     }
 118   end
 119
 120   defp username_from_nickname(string) when is_binary(string) do
 121     hd(String.split(string, "@"))
 122   end
 123
 124   defp username_from_nickname(_), do: nil
 125 end