git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 defmodule Pleroma.Web.MastodonAPI.AccountView do
   2   use Pleroma.Web, :view
   3   alias Pleroma.User
   4   alias Pleroma.Web.MastodonAPI.AccountView
   5   alias Pleroma.Web.CommonAPI.Utils
   6   alias Pleroma.Web.MediaProxy
   7   alias Pleroma.HTML
   8
   9   def render("accounts.json", %{users: users} = opts) do
  10     render_many(users, AccountView, "account.json", opts)
  11   end
  12
  13   def render("account.json", %{user: user} = opts) do
  14     image = User.avatar_url(user) |> MediaProxy.url()
  15     header = User.banner_url(user) |> MediaProxy.url()
  16     user_info = User.user_info(user)
  17     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  18
  19     emojis =
  20       (user.info.source_data["tag"] || [])
  21       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  22       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  23         %{
  24           "shortcode" => String.trim(name, ":"),
  25           "url" => MediaProxy.url(url),
  26           "static_url" => MediaProxy.url(url),
  27           "visible_in_picker" => false
  28         }
  29       end)
  30
  31     fields =
  32       (user.info.source_data["attachment"] || [])
  33       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  34       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  35
  36     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
  37
  38     %{
  39       id: to_string(user.id),
  40       username: username_from_nickname(user.nickname),
  41       acct: user.nickname,
  42       display_name: user.name || user.nickname,
  43       locked: user_info.locked,
  44       created_at: Utils.to_masto_date(user.inserted_at),
  45       followers_count: user_info.follower_count,
  46       following_count: user_info.following_count,
  47       statuses_count: user_info.note_count,
  48       note: bio || "",
  49       url: user.ap_id,
  50       avatar: image,
  51       avatar_static: image,
  52       header: header,
  53       header_static: header,
  54       emojis: emojis,
  55       fields: fields,
  56       bot: bot,
  57       source: %{
  58         note: "",
  59         privacy: user_info.default_scope,
  60         sensitive: false
  61       },
  62
  63       # Pleroma extension
  64       pleroma: %{
  65         confirmation_pending: user_info.confirmation_pending,
  66         tags: user.tags
  67       }
  68     }
  69   end
  70
  71   def render("mention.json", %{user: user}) do
  72     %{
  73       id: to_string(user.id),
  74       acct: user.nickname,
  75       username: username_from_nickname(user.nickname),
  76       url: user.ap_id
  77     }
  78   end
  79
  80   def render("relationship.json", %{user: user, target: target}) do
  81     follow_activity = Pleroma.Web.ActivityPub.Utils.fetch_latest_follow(user, target)
  82
  83     requested =
  84       if follow_activity do
  85         follow_activity.data["state"] == "pending"
  86       else
  87         false
  88       end
  89
  90     %{
  91       id: to_string(target.id),
  92       following: User.following?(user, target),
  93       followed_by: User.following?(target, user),
  94       blocking: User.blocks?(user, target),
  95       muting: false,
  96       muting_notifications: false,
  97       requested: requested,
  98       domain_blocking: false,
  99       showing_reblogs: false,
 100       endorsed: false
 101     }
 102   end
 103
 104   def render("relationships.json", %{user: user, targets: targets}) do
 105     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
 106   end
 107
 108   defp username_from_nickname(string) when is_binary(string) do
 109     hd(String.split(string, "@"))
 110   end
 111
 112   defp username_from_nickname(_), do: nil
 113 end