git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     reading_user = opts[:for]
  17
  18     relationships_opt =
  19       cond do
  20         Map.has_key?(opts, :relationships) ->
  21           opts[:relationships]
  22
  23         is_nil(reading_user) ->
  24           UserRelationship.view_relationships_option(nil, [])
  25
  26         true ->
  27           UserRelationship.view_relationships_option(reading_user, users)
  28       end
  29
  30     opts = Map.put(opts, :relationships, relationships_opt)
  31
  32     users
  33     |> render_many(AccountView, "show.json", opts)
  34     |> Enum.filter(&Enum.any?/1)
  35   end
  36
  37   def render("show.json", %{user: user} = opts) do
  38     if User.visible_for?(user, opts[:for]),
  39       do: do_render("show.json", opts),
  40       else: %{}
  41   end
  42
  43   def render("mention.json", %{user: user}) do
  44     %{
  45       id: to_string(user.id),
  46       acct: user.nickname,
  47       username: username_from_nickname(user.nickname),
  48       url: user.uri || user.ap_id
  49     }
  50   end
  51
  52   def render("relationship.json", %{user: nil, target: _target}) do
  53     %{}
  54   end
  55
  56   def render(
  57         "relationship.json",
  58         %{user: %User{} = reading_user, target: %User{} = target} = opts
  59       ) do
  60     user_relationships = get_in(opts, [:relationships, :user_relationships])
  61     following_relationships = get_in(opts, [:relationships, :following_relationships])
  62
  63     follow_state =
  64       if following_relationships do
  65         user_to_target_following_relation =
  66           FollowingRelationship.find(following_relationships, reading_user, target)
  67
  68         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  69       else
  70         User.get_follow_state(reading_user, target)
  71       end
  72
  73     followed_by =
  74       if following_relationships do
  75         case FollowingRelationship.find(following_relationships, target, reading_user) do
  76           %{state: :follow_accept} -> true
  77           _ -> false
  78         end
  79       else
  80         User.following?(target, reading_user)
  81       end
  82
  83     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
  84     %{
  85       id: to_string(target.id),
  86       following: follow_state == :follow_accept,
  87       followed_by: followed_by,
  88       blocking:
  89         UserRelationship.exists?(
  90           user_relationships,
  91           :block,
  92           reading_user,
  93           target,
  94           &User.blocks_user?(&1, &2)
  95         ),
  96       blocked_by:
  97         UserRelationship.exists?(
  98           user_relationships,
  99           :block,
 100           target,
 101           reading_user,
 102           &User.blocks_user?(&1, &2)
 103         ),
 104       muting:
 105         UserRelationship.exists?(
 106           user_relationships,
 107           :mute,
 108           reading_user,
 109           target,
 110           &User.mutes?(&1, &2)
 111         ),
 112       muting_notifications:
 113         UserRelationship.exists?(
 114           user_relationships,
 115           :notification_mute,
 116           reading_user,
 117           target,
 118           &User.muted_notifications?(&1, &2)
 119         ),
 120       subscribing:
 121         UserRelationship.exists?(
 122           user_relationships,
 123           :inverse_subscription,
 124           target,
 125           reading_user,
 126           &User.subscribed_to?(&2, &1)
 127         ),
 128       requested: follow_state == :follow_pending,
 129       domain_blocking: User.blocks_domain?(reading_user, target),
 130       showing_reblogs:
 131         not UserRelationship.exists?(
 132           user_relationships,
 133           :reblog_mute,
 134           reading_user,
 135           target,
 136           &User.muting_reblogs?(&1, &2)
 137         ),
 138       endorsed: false
 139     }
 140   end
 141
 142   def render("relationships.json", %{user: user, targets: targets} = opts) do
 143     relationships_opt =
 144       cond do
 145         Map.has_key?(opts, :relationships) ->
 146           opts[:relationships]
 147
 148         is_nil(user) ->
 149           UserRelationship.view_relationships_option(nil, [])
 150
 151         true ->
 152           UserRelationship.view_relationships_option(user, targets)
 153       end
 154
 155     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 156     render_many(targets, AccountView, "relationship.json", render_opts)
 157   end
 158
 159   defp do_render("show.json", %{user: user} = opts) do
 160     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 161     display_name = user.name || user.nickname
 162
 163     image = User.avatar_url(user) |> MediaProxy.url()
 164     header = User.banner_url(user) |> MediaProxy.url()
 165
 166     following_count =
 167       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 168         user.following_count || 0
 169       else
 170         0
 171       end
 172
 173     followers_count =
 174       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 175         user.follower_count || 0
 176       else
 177         0
 178       end
 179
 180     bot = user.actor_type in ["Application", "Service"]
 181
 182     emojis =
 183       (user.source_data["tag"] || [])
 184       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 185       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 186         %{
 187           "shortcode" => String.trim(name, ":"),
 188           "url" => MediaProxy.url(url),
 189           "static_url" => MediaProxy.url(url),
 190           "visible_in_picker" => false
 191         }
 192       end)
 193
 194     relationship =
 195       render("relationship.json", %{
 196         user: opts[:for],
 197         target: user,
 198         relationships: opts[:relationships]
 199       })
 200
 201     %{
 202       id: to_string(user.id),
 203       username: username_from_nickname(user.nickname),
 204       acct: user.nickname,
 205       display_name: display_name,
 206       locked: user.locked,
 207       created_at: Utils.to_masto_date(user.inserted_at),
 208       followers_count: followers_count,
 209       following_count: following_count,
 210       statuses_count: user.note_count,
 211       note: user.bio || "",
 212       url: user.uri || user.ap_id,
 213       avatar: image,
 214       avatar_static: image,
 215       header: header,
 216       header_static: header,
 217       emojis: emojis,
 218       fields: user.fields,
 219       bot: bot,
 220       source: %{
 221         note: (user.bio || "") |> String.replace(~r(<br */?>), "\n") |> Pleroma.HTML.strip_tags(),
 222         sensitive: false,
 223         fields: user.raw_fields,
 224         pleroma: %{
 225           discoverable: user.discoverable,
 226           actor_type: user.actor_type
 227         }
 228       },
 229
 230       # Pleroma extension
 231       pleroma: %{
 232         confirmation_pending: user.confirmation_pending,
 233         tags: user.tags,
 234         hide_followers_count: user.hide_followers_count,
 235         hide_follows_count: user.hide_follows_count,
 236         hide_followers: user.hide_followers,
 237         hide_follows: user.hide_follows,
 238         hide_favorites: user.hide_favorites,
 239         relationship: relationship,
 240         skip_thread_containment: user.skip_thread_containment,
 241         background_image: image_url(user.background) |> MediaProxy.url()
 242       }
 243     }
 244     |> maybe_put_role(user, opts[:for])
 245     |> maybe_put_settings(user, opts[:for], opts)
 246     |> maybe_put_notification_settings(user, opts[:for])
 247     |> maybe_put_settings_store(user, opts[:for], opts)
 248     |> maybe_put_chat_token(user, opts[:for], opts)
 249     |> maybe_put_activation_status(user, opts[:for])
 250     |> maybe_put_follow_requests_count(user, opts[:for])
 251     |> maybe_put_allow_following_move(user, opts[:for])
 252     |> maybe_put_unread_conversation_count(user, opts[:for])
 253   end
 254
 255   defp username_from_nickname(string) when is_binary(string) do
 256     hd(String.split(string, "@"))
 257   end
 258
 259   defp username_from_nickname(_), do: nil
 260
 261   defp maybe_put_follow_requests_count(
 262          data,
 263          %User{id: user_id} = user,
 264          %User{id: user_id}
 265        ) do
 266     count =
 267       User.get_follow_requests(user)
 268       |> length()
 269
 270     data
 271     |> Kernel.put_in([:follow_requests_count], count)
 272   end
 273
 274   defp maybe_put_follow_requests_count(data, _, _), do: data
 275
 276   defp maybe_put_settings(
 277          data,
 278          %User{id: user_id} = user,
 279          %User{id: user_id},
 280          _opts
 281        ) do
 282     data
 283     |> Kernel.put_in([:source, :privacy], user.default_scope)
 284     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 285     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 286   end
 287
 288   defp maybe_put_settings(data, _, _, _), do: data
 289
 290   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 291          with_pleroma_settings: true
 292        }) do
 293     data
 294     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 295   end
 296
 297   defp maybe_put_settings_store(data, _, _, _), do: data
 298
 299   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 300          with_chat_token: token
 301        }) do
 302     data
 303     |> Kernel.put_in([:pleroma, :chat_token], token)
 304   end
 305
 306   defp maybe_put_chat_token(data, _, _, _), do: data
 307
 308   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 309     data
 310     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 311     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 312   end
 313
 314   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 315     data
 316     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 317     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 318   end
 319
 320   defp maybe_put_role(data, _, _), do: data
 321
 322   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 323     Kernel.put_in(data, [:pleroma, :notification_settings], user.notification_settings)
 324   end
 325
 326   defp maybe_put_notification_settings(data, _, _), do: data
 327
 328   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 329     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 330   end
 331
 332   defp maybe_put_allow_following_move(data, _, _), do: data
 333
 334   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 335     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 336   end
 337
 338   defp maybe_put_activation_status(data, _, _), do: data
 339
 340   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 341     data
 342     |> Kernel.put_in(
 343       [:pleroma, :unread_conversation_count],
 344       user.unread_conversation_count
 345     )
 346   end
 347
 348   defp maybe_put_unread_conversation_count(data, _, _), do: data
 349
 350   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 351   defp image_url(_), do: nil
 352 end