git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_socket.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonSocket do
   2   use Phoenix.Socket
   3
   4   alias Pleroma.Web.OAuth.Token
   5   alias Pleroma.{User, Repo}
   6
   7   transport(
   8     :websocket,
   9     Phoenix.Transports.WebSocket.Raw,
  10     # We never receive data.
  11     timeout: :infinity
  12   )
  13
  14   @spec connect(params :: map(), Phoenix.Socket.t()) :: {:ok, Phoenix.Socket.t()} | :error
  15   def connect(%{"access_token" => token} = params, socket) do
  16     with %Token{user_id: user_id} <- Repo.get_by(Token, token: token),
  17          %User{} = user <- Repo.get(User, user_id),
  18          stream
  19          when stream in [
  20                 "public",
  21                 "public:local",
  22                 "public:media",
  23                 "public:local:media",
  24                 "user",
  25                 "direct",
  26                 "list",
  27                 "hashtag"
  28               ] <- params["stream"] do
  29       topic =
  30         case stream do
  31           "hashtag" -> "hashtag:#{params["tag"]}"
  32           "list" -> "list:#{params["list"]}"
  33           _ -> stream
  34         end
  35
  36       socket =
  37         socket
  38         |> assign(:topic, topic)
  39         |> assign(:user, user)
  40
  41       Pleroma.Web.Streamer.add_socket(topic, socket)
  42       {:ok, socket}
  43     else
  44       _e -> :error
  45     end
  46   end
  47
  48   def connect(%{"stream" => stream} = params, socket)
  49       when stream in ["public", "public:local", "hashtag"] do
  50     topic =
  51       case stream do
  52         "hashtag" -> "hashtag:#{params["tag"]}"
  53         _ -> stream
  54       end
  55
  56     socket =
  57       socket
  58       |> assign(:topic, topic)
  59
  60     Pleroma.Web.Streamer.add_socket(topic, socket)
  61     {:ok, socket}
  62   end
  63
  64   def connect(_params, _socket), do: :error
  65
  66   def id(_), do: nil
  67
  68   def handle(:text, message, _state) do
  69     # | :ok
  70     # | state
  71     # | {:text, message}
  72     # | {:text, message, state}
  73     # | {:close, "Goodbye!"}
  74     {:text, message}
  75   end
  76
  77   def handle(:closed, _, %{socket: socket}) do
  78     topic = socket.assigns[:topic]
  79     Pleroma.Web.Streamer.remove_socket(topic, socket)
  80   end
  81 end