git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification}
   4   alias Pleroma.Web.OAuth.App
   5   alias Pleroma.Web
   6   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView}
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Pleroma.Web.TwitterAPI.TwitterAPI
   9   alias Pleroma.Web.{CommonAPI, OStatus}
  10   import Ecto.Query
  11   import Logger
  12
  13   def create_app(conn, params) do
  14     with cs <- App.register_changeset(%App{}, params) |> IO.inspect,
  15          {:ok, app} <- Repo.insert(cs) |> IO.inspect do
  16       res = %{
  17         id: app.id,
  18         client_id: app.client_id,
  19         client_secret: app.client_secret
  20       }
  21
  22       json(conn, res)
  23     end
  24   end
  25
  26   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  27     params = if bio = params["note"] do
  28       Map.put(params, "bio", bio)
  29     else
  30       params
  31     end
  32
  33     params = if name = params["display_name"] do
  34       Map.put(params, "name", name)
  35     else
  36       params
  37     end
  38
  39     user = if avatar = params["avatar"] do
  40       with %Plug.Upload{} <- avatar,
  41            {:ok, object} <- ActivityPub.upload(avatar),
  42            change = Ecto.Changeset.change(user, %{avatar: object.data}),
  43            {:ok, user} = Repo.update(change) do
  44         user
  45       else
  46         _e -> user
  47       end
  48     else
  49       user
  50     end
  51
  52     user = if banner = params["header"] do
  53       with %Plug.Upload{} <- banner,
  54            {:ok, object} <- ActivityPub.upload(banner),
  55            new_info <- Map.put(user.info, "banner", object.data),
  56            change <- User.info_changeset(user, %{info: new_info}),
  57            {:ok, user} <- Repo.update(change) do
  58         user
  59       else
  60         _e -> user
  61       end
  62     else
  63       user
  64     end
  65
  66     with changeset <- User.update_changeset(user, params),
  67          {:ok, user} <- Repo.update(changeset) do
  68       json conn, AccountView.render("account.json", %{user: user})
  69     else
  70       _e ->
  71         conn
  72         |> put_status(403)
  73         |> json(%{error: "Invalid request"})
  74     end
  75   end
  76
  77   def verify_credentials(%{assigns: %{user: user}} = conn, params) do
  78     account = AccountView.render("account.json", %{user: user})
  79     json(conn, account)
  80   end
  81
  82   def user(conn, %{"id" => id}) do
  83     with %User{} = user <- Repo.get(User, id) do
  84       account = AccountView.render("account.json", %{user: user})
  85       json(conn, account)
  86     else
  87       _e -> conn
  88       |> put_status(404)
  89       |> json(%{error: "Can't find user"})
  90     end
  91   end
  92
  93   @instance Application.get_env(:pleroma, :instance)
  94
  95   def masto_instance(conn, _params) do
  96     response = %{
  97       uri: Web.base_url,
  98       title: Keyword.get(@instance, :name),
  99       description: "A Pleroma instance, an alternative fediverse server",
 100       version: Keyword.get(@instance, :version),
 101       email: Keyword.get(@instance, :email),
 102       urls: %{
 103         streaming_api: String.replace(Web.base_url, ["http","https"], "wss")
 104       },
 105       stats: %{
 106         user_count: 1,
 107         status_count: 2,
 108         domain_count: 3
 109       }
 110     }
 111
 112     json(conn, response)
 113   end
 114
 115   def custom_emojis(conn, _params) do
 116     mastodon_emoji = Pleroma.Formatter.get_custom_emoji()
 117     |> Enum.map(fn {shortcode, relative_url} ->
 118       url = to_string URI.merge(Web.base_url(), relative_url)
 119       %{
 120         "shortcode" => shortcode,
 121         "static_url" => url,
 122         "url" => url
 123       }
 124     end)
 125     json conn, mastodon_emoji
 126   end
 127
 128   defp add_link_headers(conn, method, activities) do
 129     last = List.last(activities)
 130     first = List.first(activities)
 131     if last do
 132       min = last.id
 133       max = first.id
 134       next_url = mastodon_api_url(Pleroma.Web.Endpoint, method, max_id: min)
 135       prev_url = mastodon_api_url(Pleroma.Web.Endpoint, method, since_id: max)
 136       conn
 137       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 138     else
 139       conn
 140     end
 141   end
 142
 143   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 144     params = params
 145     |> Map.put("type", ["Create", "Announce"])
 146     |> Map.put("blocking_user", user)
 147
 148     activities = ActivityPub.fetch_activities([user.ap_id | user.following], params)
 149     |> Enum.reverse
 150
 151     conn
 152     |> add_link_headers(:home_timeline, activities)
 153     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 154   end
 155
 156   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 157     params = params
 158     |> Map.put("type", ["Create", "Announce"])
 159     |> Map.put("local_only", !!params["local"])
 160     |> Map.put("blocking_user", user)
 161
 162     activities = ActivityPub.fetch_public_activities(params)
 163     |> Enum.reverse
 164
 165     conn
 166     |> add_link_headers(:public_timeline, activities)
 167     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 168   end
 169
 170   # TODO: Link headers
 171   def user_statuses(%{assigns: %{user: user}} = conn, params) do
 172     with %User{ap_id: ap_id} <- Repo.get(User, params["id"]) do
 173       params = params
 174       |> Map.put("type", ["Create", "Announce"])
 175       |> Map.put("actor_id", ap_id)
 176       |> Map.put("whole_db", true)
 177
 178       activities = ActivityPub.fetch_activities([], params)
 179       |> Enum.reverse
 180
 181       render conn, StatusView, "index.json", %{activities: activities, for: user, as: :activity}
 182     end
 183   end
 184
 185   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 186     with %Activity{} = activity <- Repo.get(Activity, id) do
 187       render conn, StatusView, "status.json", %{activity: activity, for: user}
 188     end
 189   end
 190
 191   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 192     with %Activity{} = activity <- Repo.get(Activity, id),
 193          activities <- ActivityPub.fetch_activities_for_context(activity.data["object"]["context"], %{"blocking_user" => user}),
 194          activities <- activities |> Enum.filter(fn (%{id: aid}) -> to_string(aid) != to_string(id) end),
 195          grouped_activities <- Enum.group_by(activities, fn (%{id: id}) -> id < activity.id end) do
 196       result = %{
 197         ancestors: StatusView.render("index.json", for: user, activities: grouped_activities[true] || [], as: :activity) |> Enum.reverse,
 198         descendants: StatusView.render("index.json", for: user, activities: grouped_activities[false] || [], as: :activity) |> Enum.reverse,
 199       }
 200
 201       json(conn, result)
 202     end
 203   end
 204
 205   def post_status(%{assigns: %{user: user}} = conn, %{"status" => status} = params) do
 206     params = params
 207     |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 208
 209     {:ok, activity} = CommonAPI.post(user, params)
 210     render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 211   end
 212
 213   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 214     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 215       json(conn, %{})
 216     else
 217       _e ->
 218         conn
 219         |> put_status(403)
 220         |> json(%{error: "Can't delete this post"})
 221     end
 222   end
 223
 224   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 225     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(ap_id_or_id, user),
 226          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 227       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 228     end
 229   end
 230
 231   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 232     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 233          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 234       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 235     end
 236   end
 237
 238   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 239     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 240          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 241       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 242     end
 243   end
 244
 245   def notifications(%{assigns: %{user: user}} = conn, params) do
 246     notifications = Notification.for_user(user, params)
 247     result = Enum.map(notifications, fn (%{id: id, activity: activity, inserted_at: created_at}) ->
 248       actor = User.get_cached_by_ap_id(activity.data["actor"])
 249       created_at = NaiveDateTime.to_iso8601(created_at)
 250       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 251       case activity.data["type"] do
 252         "Create" ->
 253           %{id: id, type: "mention", created_at: created_at, account: AccountView.render("account.json", %{user: actor}), status: StatusView.render("status.json", %{activity: activity, for: user})}
 254         "Like" ->
 255           liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 256           %{id: id, type: "favourite", created_at: created_at, account: AccountView.render("account.json", %{user: actor}), status: StatusView.render("status.json", %{activity: liked_activity, for: user})}
 257         "Announce" ->
 258           announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 259           %{id: id, type: "reblog", created_at: created_at, account: AccountView.render("account.json", %{user: actor}), status: StatusView.render("status.json", %{activity: announced_activity, for: user})}
 260         "Follow" ->
 261           %{id: id, type: "follow", created_at: created_at, account: AccountView.render("account.json", %{user: actor})}
 262         _ -> nil
 263       end
 264     end)
 265     |> Enum.filter(&(&1))
 266
 267     conn
 268     |> add_link_headers(:notifications, notifications)
 269     |> json(result)
 270   end
 271
 272   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 273     id = List.wrap(id)
 274     q = from u in User,
 275       where: u.id in ^id
 276     targets = Repo.all(q)
 277     render conn, AccountView, "relationships.json", %{user: user, targets: targets}
 278   end
 279
 280   def upload(%{assigns: %{user: user}} = conn, %{"file" => file}) do
 281     with {:ok, object} <- ActivityPub.upload(file) do
 282       data = object.data
 283       |> Map.put("id", object.id)
 284
 285       render conn, StatusView, "attachment.json", %{attachment: data}
 286     end
 287   end
 288
 289   def favourited_by(conn, %{"id" => id}) do
 290     with %Activity{data: %{"object" => %{"likes" => likes} = data}} <- Repo.get(Activity, id) do
 291       q = from u in User,
 292         where: u.ap_id in ^likes
 293       users = Repo.all(q)
 294       render conn, AccountView, "accounts.json", %{users: users, as: :user}
 295     else
 296       _ -> json(conn, [])
 297     end
 298   end
 299
 300   def reblogged_by(conn, %{"id" => id}) do
 301     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 302       q = from u in User,
 303         where: u.ap_id in ^announces
 304       users = Repo.all(q)
 305       render conn, AccountView, "accounts.json", %{users: users, as: :user}
 306     else
 307       _ -> json(conn, [])
 308     end
 309   end
 310
 311   # TODO: Link headers
 312   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 313     params = params
 314     |> Map.put("type", "Create")
 315     |> Map.put("local_only", !!params["local"])
 316     |> Map.put("blocking_user", user)
 317
 318     activities = ActivityPub.fetch_public_activities(params)
 319     |> Enum.reverse
 320
 321     conn
 322     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 323   end
 324
 325   # TODO: Pagination
 326   def followers(conn, %{"id" => id}) do
 327     with %User{} = user <- Repo.get(User, id),
 328          {:ok, followers} <- User.get_followers(user) do
 329       render conn, AccountView, "accounts.json", %{users: followers, as: :user}
 330     end
 331   end
 332
 333   def following(conn, %{"id" => id}) do
 334     with %User{} = user <- Repo.get(User, id),
 335          {:ok, followers} <- User.get_friends(user) do
 336       render conn, AccountView, "accounts.json", %{users: followers, as: :user}
 337     end
 338   end
 339
 340   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 341     with %User{} = followed <- Repo.get(User, id),
 342          {:ok, follower} <- User.follow(follower, followed),
 343          {:ok, activity} <- ActivityPub.follow(follower, followed) do
 344       render conn, AccountView, "relationship.json", %{user: follower, target: followed}
 345     else
 346       {:error, message} = err ->
 347         conn
 348         |> put_resp_content_type("application/json")
 349         |> send_resp(403, Poison.encode!(%{"error" => message}))
 350     end
 351   end
 352
 353   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 354     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 355          {:ok, follower} <- User.follow(follower, followed),
 356          {:ok, activity} <- ActivityPub.follow(follower, followed) do
 357       render conn, AccountView, "account.json", %{user: followed}
 358     else
 359       {:error, message} = err ->
 360         conn
 361         |> put_resp_content_type("application/json")
 362         |> send_resp(403, Poison.encode!(%{"error" => message}))
 363     end
 364   end
 365
 366   # TODO: Clean up and unify
 367   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 368     with %User{} = followed <- Repo.get(User, id),
 369          { :ok, follower, follow_activity } <- User.unfollow(follower, followed),
 370          { :ok, _activity } <- ActivityPub.insert(%{
 371            "type" => "Undo",
 372            "actor" => follower.ap_id,
 373            "object" => follow_activity.data["id"] # get latest Follow for these users
 374          }) do
 375       render conn, AccountView, "relationship.json", %{user: follower, target: followed}
 376     end
 377   end
 378
 379   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 380     with %User{} = blocked <- Repo.get(User, id),
 381          {:ok, blocker} <- User.block(blocker, blocked) do
 382       render conn, AccountView, "relationship.json", %{user: blocker, target: blocked}
 383     else
 384       {:error, message} = err ->
 385         conn
 386         |> put_resp_content_type("application/json")
 387         |> send_resp(403, Poison.encode!(%{"error" => message}))
 388     end
 389   end
 390
 391   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 392     with %User{} = blocked <- Repo.get(User, id),
 393          {:ok, blocker} <- User.unblock(blocker, blocked) do
 394       render conn, AccountView, "relationship.json", %{user: blocker, target: blocked}
 395     else
 396       {:error, message} = err ->
 397         conn
 398         |> put_resp_content_type("application/json")
 399         |> send_resp(403, Poison.encode!(%{"error" => message}))
 400     end
 401   end
 402
 403   # TODO: Use proper query
 404   def blocks(%{assigns: %{user: user}} = conn, _) do
 405     with blocked_users <- user.info["blocks"] || [],
 406          accounts <- Enum.map(blocked_users, fn (ap_id) -> User.get_cached_by_ap_id(ap_id) end) do
 407       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 408       json(conn, res)
 409     end
 410   end
 411
 412   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 413     accounts = User.search(query, params["resolve"] == "true")
 414
 415     fetched = if Regex.match?(~r/https?:/, query) do
 416       with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 417         activities
 418       else
 419         _e -> []
 420       end
 421     end || []
 422
 423     q = from a in Activity,
 424       where: fragment("?->>'type' = 'Create'", a.data),
 425       where: fragment("to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)", a.data, ^query),
 426       limit: 20
 427     statuses = Repo.all(q) ++ fetched
 428
 429     res = %{
 430       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 431       "statuses" => StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 432       "hashtags" => []
 433     }
 434
 435     json(conn, res)
 436   end
 437
 438   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 439     accounts = User.search(query, params["resolve"] == "true")
 440
 441     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 442
 443     json(conn, res)
 444   end
 445
 446   def favourites(%{assigns: %{user: user}} = conn, params) do
 447     params = conn
 448     |> Map.put("type", "Create")
 449     |> Map.put("favorited_by", user.ap_id)
 450     |> Map.put("blocking_user", user)
 451
 452     activities = ActivityPub.fetch_activities([], params)
 453     |> Enum.reverse
 454
 455     conn
 456     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 457   end
 458
 459   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 460     Logger.debug("Unimplemented, returning unmodified relationship")
 461     with %User{} = target <- Repo.get(User, id) do
 462       render conn, AccountView, "relationship.json", %{user: user, target: target}
 463     end
 464   end
 465
 466   def empty_array(conn, _) do
 467     Logger.debug("Unimplemented, returning an empty array")
 468     json(conn, [])
 469   end
 470 end