git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification, Stats}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.{CommonAPI, OStatus}
   8   alias Pleroma.Web.OAuth.{Authorization, Token, App}
   9   alias Comeonin.Pbkdf2
  10   import Ecto.Query
  11   require Logger
  12
  13   def create_app(conn, params) do
  14     with cs <- App.register_changeset(%App{}, params) |> IO.inspect,
  15          {:ok, app} <- Repo.insert(cs) |> IO.inspect do
  16       res = %{
  17         id: app.id,
  18         client_id: app.client_id,
  19         client_secret: app.client_secret
  20       }
  21
  22       json(conn, res)
  23     end
  24   end
  25
  26   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  27     params = if bio = params["note"] do
  28       Map.put(params, "bio", bio)
  29     else
  30       params
  31     end
  32
  33     params = if name = params["display_name"] do
  34       Map.put(params, "name", name)
  35     else
  36       params
  37     end
  38
  39     user = if avatar = params["avatar"] do
  40       with %Plug.Upload{} <- avatar,
  41            {:ok, object} <- ActivityPub.upload(avatar),
  42            change = Ecto.Changeset.change(user, %{avatar: object.data}),
  43            {:ok, user} = Repo.update(change) do
  44         user
  45       else
  46         _e -> user
  47       end
  48     else
  49       user
  50     end
  51
  52     user = if banner = params["header"] do
  53       with %Plug.Upload{} <- banner,
  54            {:ok, object} <- ActivityPub.upload(banner),
  55            new_info <- Map.put(user.info, "banner", object.data),
  56            change <- User.info_changeset(user, %{info: new_info}),
  57            {:ok, user} <- Repo.update(change) do
  58         user
  59       else
  60         _e -> user
  61       end
  62     else
  63       user
  64     end
  65
  66     with changeset <- User.update_changeset(user, params),
  67          {:ok, user} <- Repo.update(changeset) do
  68       json conn, AccountView.render("account.json", %{user: user})
  69     else
  70       _e ->
  71         conn
  72         |> put_status(403)
  73         |> json(%{error: "Invalid request"})
  74     end
  75   end
  76
  77   def verify_credentials(%{assigns: %{user: user}} = conn, _) do
  78     account = AccountView.render("account.json", %{user: user})
  79     json(conn, account)
  80   end
  81
  82   def user(conn, %{"id" => id}) do
  83     with %User{} = user <- Repo.get(User, id) do
  84       account = AccountView.render("account.json", %{user: user})
  85       json(conn, account)
  86     else
  87       _e -> conn
  88       |> put_status(404)
  89       |> json(%{error: "Can't find user"})
  90     end
  91   end
  92
  93   @instance Application.get_env(:pleroma, :instance)
  94
  95   def masto_instance(conn, _params) do
  96     response = %{
  97       uri: Web.base_url,
  98       title: Keyword.get(@instance, :name),
  99       description: "A Pleroma instance, an alternative fediverse server",
 100       version: Keyword.get(@instance, :version),
 101       email: Keyword.get(@instance, :email),
 102       urls: %{
 103         streaming_api: String.replace(Web.base_url, ["http","https"], "wss")
 104       },
 105       stats: Stats.get_stats,
 106       thumbnail: Web.base_url <> "/instance/thumbnail.jpeg",
 107       max_toot_chars: Keyword.get(@instance, :limit)
 108     }
 109
 110     json(conn, response)
 111   end
 112
 113   def peers(conn, _params) do
 114     json(conn, Stats.get_peers)
 115   end
 116
 117   defp mastodonized_emoji do
 118     Pleroma.Formatter.get_custom_emoji()
 119     |> Enum.map(fn {shortcode, relative_url} ->
 120       url = to_string URI.merge(Web.base_url(), relative_url)
 121       %{
 122         "shortcode" => shortcode,
 123         "static_url" => url,
 124         "url" => url
 125       }
 126     end)
 127   end
 128
 129   def custom_emojis(conn, _params) do
 130     mastodon_emoji = mastodonized_emoji()
 131     json conn, mastodon_emoji
 132   end
 133
 134   defp add_link_headers(conn, method, activities) do
 135     last = List.last(activities)
 136     first = List.first(activities)
 137     if last do
 138       min = last.id
 139       max = first.id
 140       next_url = mastodon_api_url(Pleroma.Web.Endpoint, method, max_id: min)
 141       prev_url = mastodon_api_url(Pleroma.Web.Endpoint, method, since_id: max)
 142       conn
 143       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 144     else
 145       conn
 146     end
 147   end
 148
 149   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 150     params = params
 151     |> Map.put("type", ["Create", "Announce"])
 152     |> Map.put("blocking_user", user)
 153     |> Map.put("user", user)
 154
 155     activities = ActivityPub.fetch_activities([user.ap_id | user.following], params)
 156     |> Enum.reverse
 157
 158     conn
 159     |> add_link_headers(:home_timeline, activities)
 160     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 161   end
 162
 163   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 164     params = params
 165     |> Map.put("type", ["Create", "Announce"])
 166     |> Map.put("local_only", params["local"] in [true, "True", "true", "1"])
 167     |> Map.put("blocking_user", user)
 168
 169     activities = ActivityPub.fetch_public_activities(params)
 170     |> Enum.reverse
 171
 172     conn
 173     |> add_link_headers(:public_timeline, activities)
 174     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 175   end
 176
 177   # TODO: Link headers
 178   def user_statuses(%{assigns: %{user: user}} = conn, params) do
 179     with %User{ap_id: ap_id} <- Repo.get(User, params["id"]) do
 180       params = params
 181       |> Map.put("type", ["Create", "Announce"])
 182       |> Map.put("actor_id", ap_id)
 183       |> Map.put("whole_db", true)
 184
 185       activities = ActivityPub.fetch_activities([], params)
 186       |> Enum.reverse
 187
 188       render conn, StatusView, "index.json", %{activities: activities, for: user, as: :activity}
 189     end
 190   end
 191
 192   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 193     with %Activity{} = activity <- Repo.get(Activity, id) do
 194       render conn, StatusView, "status.json", %{activity: activity, for: user}
 195     end
 196   end
 197
 198   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 199     with %Activity{} = activity <- Repo.get(Activity, id),
 200          activities <- ActivityPub.fetch_activities_for_context(activity.data["object"]["context"], %{"blocking_user" => user}),
 201          activities <- activities |> Enum.filter(fn (%{id: aid}) -> to_string(aid) != to_string(id) end),
 202          activities <- activities |> Enum.filter(fn (%{data: %{"type" => type}}) -> type == "Create" end),
 203          grouped_activities <- Enum.group_by(activities, fn (%{id: id}) -> id < activity.id end) do
 204       result = %{
 205         ancestors: StatusView.render("index.json", for: user, activities: grouped_activities[true] || [], as: :activity) |> Enum.reverse,
 206         descendants: StatusView.render("index.json", for: user, activities: grouped_activities[false] || [], as: :activity) |> Enum.reverse,
 207       }
 208
 209       json(conn, result)
 210     end
 211   end
 212
 213   def post_status(%{assigns: %{user: user}} = conn, %{"status" => _} = params) do
 214     params = params
 215     |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 216     |> Map.put("no_attachment_links", true)
 217
 218     {:ok, activity} = CommonAPI.post(user, params)
 219     render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 220   end
 221
 222   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 223     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 224       json(conn, %{})
 225     else
 226       _e ->
 227         conn
 228         |> put_status(403)
 229         |> json(%{error: "Can't delete this post"})
 230     end
 231   end
 232
 233   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 234     with {:ok, announce, _activity} = CommonAPI.repeat(ap_id_or_id, user) do
 235       render conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity}
 236     end
 237   end
 238
 239   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 240     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 241          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 242       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 243     end
 244   end
 245
 246   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 247     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 248          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 249       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 250     end
 251   end
 252
 253   def notifications(%{assigns: %{user: user}} = conn, params) do
 254     notifications = Notification.for_user(user, params)
 255     result = Enum.map(notifications, fn x ->
 256       render_notification(user, x)
 257     end)
 258     |> Enum.filter(&(&1))
 259
 260     conn
 261     |> add_link_headers(:notifications, notifications)
 262     |> json(result)
 263   end
 264
 265   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 266     with {:ok, notification} <- Notification.get(user, id) do
 267       json(conn, render_notification(user, notification))
 268     else
 269       {:error, reason} ->
 270         conn
 271         |> put_resp_content_type("application/json")
 272         |> send_resp(403, Poison.encode!(%{"error" => reason}))
 273     end
 274   end
 275
 276   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 277     Notification.clear(user)
 278     json(conn, %{})
 279   end
 280
 281   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 282     with {:ok, _notif} <- Notification.dismiss(user, id) do
 283       json(conn, %{})
 284     else
 285       {:error, reason} ->
 286         conn
 287         |> put_resp_content_type("application/json")
 288         |> send_resp(403, Poison.encode!(%{"error" => reason}))
 289     end
 290   end
 291
 292   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 293     id = List.wrap(id)
 294     q = from u in User,
 295       where: u.id in ^id
 296     targets = Repo.all(q)
 297     render conn, AccountView, "relationships.json", %{user: user, targets: targets}
 298   end
 299
 300   def upload(%{assigns: %{user: _}} = conn, %{"file" => file}) do
 301     with {:ok, object} <- ActivityPub.upload(file) do
 302       data = object.data
 303       |> Map.put("id", object.id)
 304
 305       render conn, StatusView, "attachment.json", %{attachment: data}
 306     end
 307   end
 308
 309   def favourited_by(conn, %{"id" => id}) do
 310     with %Activity{data: %{"object" => %{"likes" => likes}}} <- Repo.get(Activity, id) do
 311       q = from u in User,
 312         where: u.ap_id in ^likes
 313       users = Repo.all(q)
 314       render conn, AccountView, "accounts.json", %{users: users, as: :user}
 315     else
 316       _ -> json(conn, [])
 317     end
 318   end
 319
 320   def reblogged_by(conn, %{"id" => id}) do
 321     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 322       q = from u in User,
 323         where: u.ap_id in ^announces
 324       users = Repo.all(q)
 325       render conn, AccountView, "accounts.json", %{users: users, as: :user}
 326     else
 327       _ -> json(conn, [])
 328     end
 329   end
 330
 331   # TODO: Link headers
 332   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 333     params = params
 334     |> Map.put("type", "Create")
 335     |> Map.put("local_only", !!params["local"])
 336     |> Map.put("blocking_user", user)
 337
 338     activities = ActivityPub.fetch_public_activities(params)
 339     |> Enum.reverse
 340
 341     conn
 342     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 343   end
 344
 345   # TODO: Pagination
 346   def followers(conn, %{"id" => id}) do
 347     with %User{} = user <- Repo.get(User, id),
 348          {:ok, followers} <- User.get_followers(user) do
 349       render conn, AccountView, "accounts.json", %{users: followers, as: :user}
 350     end
 351   end
 352
 353   def following(conn, %{"id" => id}) do
 354     with %User{} = user <- Repo.get(User, id),
 355          {:ok, followers} <- User.get_friends(user) do
 356       render conn, AccountView, "accounts.json", %{users: followers, as: :user}
 357     end
 358   end
 359
 360   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 361     with %User{} = followed <- Repo.get(User, id),
 362          {:ok, follower} <- User.follow(follower, followed),
 363          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 364       render conn, AccountView, "relationship.json", %{user: follower, target: followed}
 365     else
 366       {:error, message} ->
 367         conn
 368         |> put_resp_content_type("application/json")
 369         |> send_resp(403, Poison.encode!(%{"error" => message}))
 370     end
 371   end
 372
 373   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 374     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 375          {:ok, follower} <- User.follow(follower, followed),
 376          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 377       render conn, AccountView, "account.json", %{user: followed}
 378     else
 379       {:error, message} ->
 380         conn
 381         |> put_resp_content_type("application/json")
 382         |> send_resp(403, Poison.encode!(%{"error" => message}))
 383     end
 384   end
 385
 386   # TODO: Clean up and unify
 387   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 388     with %User{} = followed <- Repo.get(User, id),
 389          { :ok, follower, follow_activity } <- User.unfollow(follower, followed),
 390          { :ok, _activity } <- ActivityPub.insert(%{
 391            "type" => "Undo",
 392            "actor" => follower.ap_id,
 393            "object" => follow_activity.data["id"] # get latest Follow for these users
 394          }) do
 395       render conn, AccountView, "relationship.json", %{user: follower, target: followed}
 396     end
 397   end
 398
 399   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 400     with %User{} = blocked <- Repo.get(User, id),
 401          {:ok, blocker} <- User.block(blocker, blocked) do
 402       render conn, AccountView, "relationship.json", %{user: blocker, target: blocked}
 403     else
 404       {:error, message} ->
 405         conn
 406         |> put_resp_content_type("application/json")
 407         |> send_resp(403, Poison.encode!(%{"error" => message}))
 408     end
 409   end
 410
 411   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 412     with %User{} = blocked <- Repo.get(User, id),
 413          {:ok, blocker} <- User.unblock(blocker, blocked) do
 414       render conn, AccountView, "relationship.json", %{user: blocker, target: blocked}
 415     else
 416       {:error, message} ->
 417         conn
 418         |> put_resp_content_type("application/json")
 419         |> send_resp(403, Poison.encode!(%{"error" => message}))
 420     end
 421   end
 422
 423   # TODO: Use proper query
 424   def blocks(%{assigns: %{user: user}} = conn, _) do
 425     with blocked_users <- user.info["blocks"] || [],
 426          accounts <- Enum.map(blocked_users, fn (ap_id) -> User.get_cached_by_ap_id(ap_id) end) do
 427       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 428       json(conn, res)
 429     end
 430   end
 431
 432   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 433     accounts = User.search(query, params["resolve"] == "true")
 434
 435     fetched = if Regex.match?(~r/https?:/, query) do
 436       with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 437         activities
 438       else
 439         _e -> []
 440       end
 441     end || []
 442
 443     q = from a in Activity,
 444       where: fragment("?->>'type' = 'Create'", a.data),
 445       where: fragment("to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)", a.data, ^query),
 446       limit: 20
 447     statuses = Repo.all(q) ++ fetched
 448
 449     res = %{
 450       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 451       "statuses" => StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 452       "hashtags" => []
 453     }
 454
 455     json(conn, res)
 456   end
 457
 458   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 459     accounts = User.search(query, params["resolve"] == "true")
 460
 461     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 462
 463     json(conn, res)
 464   end
 465
 466   def favourites(%{assigns: %{user: user}} = conn, _) do
 467     params = conn
 468     |> Map.put("type", "Create")
 469     |> Map.put("favorited_by", user.ap_id)
 470     |> Map.put("blocking_user", user)
 471
 472     activities = ActivityPub.fetch_activities([], params)
 473     |> Enum.reverse
 474
 475     conn
 476     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 477   end
 478
 479   def index(%{assigns: %{user: user}} = conn, _params) do
 480     token = conn
 481     |> get_session(:oauth_token)
 482
 483     if user && token do
 484       mastodon_emoji = mastodonized_emoji()
 485       accounts = Map.put(%{}, user.id, AccountView.render("account.json", %{user: user}))
 486       initial_state = %{
 487         meta: %{
 488           streaming_api_base_url: String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 489           access_token: token,
 490           locale: "en",
 491           domain: Pleroma.Web.Endpoint.host(),
 492           admin: "1",
 493           me: "#{user.id}",
 494           unfollow_modal: false,
 495           boost_modal: false,
 496           delete_modal: true,
 497           auto_play_gif: false,
 498           reduce_motion: false
 499         },
 500         compose: %{
 501           me: "#{user.id}",
 502           default_privacy: "public",
 503           default_sensitive: false
 504         },
 505         media_attachments: %{
 506           accept_content_types: [
 507             ".jpg",
 508             ".jpeg",
 509             ".png",
 510             ".gif",
 511             ".webm",
 512             ".mp4",
 513             ".m4v",
 514             "image\/jpeg",
 515             "image\/png",
 516             "image\/gif",
 517             "video\/webm",
 518             "video\/mp4"
 519           ]
 520         },
 521         settings: %{
 522           onboarded: true,
 523           home: %{
 524             shows: %{
 525               reblog: true,
 526               reply: true
 527             }
 528           },
 529           notifications: %{
 530             alerts: %{
 531               follow: true,
 532               favourite: true,
 533               reblog: true,
 534               mention: true
 535             },
 536             shows: %{
 537               follow: true,
 538               favourite: true,
 539               reblog: true,
 540               mention: true
 541             },
 542             sounds: %{
 543               follow: true,
 544               favourite: true,
 545               reblog: true,
 546               mention: true
 547             }
 548           }
 549         },
 550         push_subscription: nil,
 551         accounts: accounts,
 552         custom_emojis: mastodon_emoji
 553       } |> Poison.encode!
 554       conn
 555       |> put_layout(false)
 556       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 557     else
 558       conn
 559       |> redirect(to: "/web/login")
 560     end
 561   end
 562
 563   def login(conn, _) do
 564     conn
 565     |> render(MastodonView, "login.html", %{error: false})
 566   end
 567
 568   defp get_or_make_app() do
 569     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 570       {:ok, app}
 571     else
 572       _e ->
 573         cs = App.register_changeset(%App{}, %{client_name: "Mastodon-Local", redirect_uris: ".", scopes: "read,write,follow"})
 574         Repo.insert(cs)
 575     end
 576   end
 577
 578   def login_post(conn, %{"authorization" => %{ "name" => name, "password" => password}}) do
 579     with %User{} = user <- User.get_cached_by_nickname(name),
 580          true <- Pbkdf2.checkpw(password, user.password_hash),
 581          {:ok, app} <- get_or_make_app(),
 582          {:ok, auth} <- Authorization.create_authorization(app, user),
 583          {:ok, token} <- Token.exchange_token(app, auth) do
 584       conn
 585       |> put_session(:oauth_token, token.token)
 586       |> redirect(to: "/web/getting-started")
 587     else
 588       _e ->
 589         conn
 590         |> render(MastodonView, "login.html", %{error: "Wrong username or password"})
 591     end
 592   end
 593
 594   def logout(conn, _) do
 595     conn
 596     |> clear_session
 597     |> redirect(to: "/")
 598   end
 599
 600   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 601     Logger.debug("Unimplemented, returning unmodified relationship")
 602     with %User{} = target <- Repo.get(User, id) do
 603       render conn, AccountView, "relationship.json", %{user: user, target: target}
 604     end
 605   end
 606
 607   def empty_array(conn, _) do
 608     Logger.debug("Unimplemented, returning an empty array")
 609     json(conn, [])
 610   end
 611
 612   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
 613     actor = User.get_cached_by_ap_id(activity.data["actor"])
 614     created_at = NaiveDateTime.to_iso8601(created_at)
 615     |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 616     case activity.data["type"] do
 617       "Create" ->
 618         %{id: id, type: "mention", created_at: created_at, account: AccountView.render("account.json", %{user: actor}), status: StatusView.render("status.json", %{activity: activity, for: user})}
 619       "Like" ->
 620         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 621         %{id: id, type: "favourite", created_at: created_at, account: AccountView.render("account.json", %{user: actor}), status: StatusView.render("status.json", %{activity: liked_activity, for: user})}
 622       "Announce" ->
 623         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 624         %{id: id, type: "reblog", created_at: created_at, account: AccountView.render("account.json", %{user: actor}), status: StatusView.render("status.json", %{activity: announced_activity, for: user})}
 625       "Follow" ->
 626         %{id: id, type: "follow", created_at: created_at, account: AccountView.render("account.json", %{user: actor})}
 627       _ -> nil
 628     end
 629   end
 630 end