git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification, Stats}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.{CommonAPI, OStatus}
   8   alias Pleroma.Web.OAuth.{Authorization, Token, App}
   9   alias Comeonin.Pbkdf2
  10   import Ecto.Query
  11   require Logger
  12
  13   def create_app(conn, params) do
  14     with cs <- App.register_changeset(%App{}, params) |> IO.inspect(),
  15          {:ok, app} <- Repo.insert(cs) |> IO.inspect() do
  16       res = %{
  17         id: app.id,
  18         client_id: app.client_id,
  19         client_secret: app.client_secret
  20       }
  21
  22       json(conn, res)
  23     end
  24   end
  25
  26   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  27     original_user = user
  28
  29     params =
  30       if bio = params["note"] do
  31         Map.put(params, "bio", bio)
  32       else
  33         params
  34       end
  35
  36     params =
  37       if name = params["display_name"] do
  38         Map.put(params, "name", name)
  39       else
  40         params
  41       end
  42
  43     user =
  44       if avatar = params["avatar"] do
  45         with %Plug.Upload{} <- avatar,
  46              {:ok, object} <- ActivityPub.upload(avatar),
  47              change = Ecto.Changeset.change(user, %{avatar: object.data}),
  48              {:ok, user} = User.update_and_set_cache(change) do
  49           user
  50         else
  51           _e -> user
  52         end
  53       else
  54         user
  55       end
  56
  57     user =
  58       if banner = params["header"] do
  59         with %Plug.Upload{} <- banner,
  60              {:ok, object} <- ActivityPub.upload(banner),
  61              new_info <- Map.put(user.info, "banner", object.data),
  62              change <- User.info_changeset(user, %{info: new_info}),
  63              {:ok, user} <- User.update_and_set_cache(change) do
  64           user
  65         else
  66           _e -> user
  67         end
  68       else
  69         user
  70       end
  71
  72     with changeset <- User.update_changeset(user, params),
  73          {:ok, user} <- User.update_and_set_cache(changeset) do
  74       if original_user != user do
  75         CommonAPI.update(user)
  76       end
  77
  78       json(conn, AccountView.render("account.json", %{user: user}))
  79     else
  80       _e ->
  81         conn
  82         |> put_status(403)
  83         |> json(%{error: "Invalid request"})
  84     end
  85   end
  86
  87   def verify_credentials(%{assigns: %{user: user}} = conn, _) do
  88     account = AccountView.render("account.json", %{user: user})
  89     json(conn, account)
  90   end
  91
  92   def user(conn, %{"id" => id}) do
  93     with %User{} = user <- Repo.get(User, id) do
  94       account = AccountView.render("account.json", %{user: user})
  95       json(conn, account)
  96     else
  97       _e ->
  98         conn
  99         |> put_status(404)
 100         |> json(%{error: "Can't find user"})
 101     end
 102   end
 103
 104   @instance Application.get_env(:pleroma, :instance)
 105   @mastodon_api_level "2.3.3"
 106
 107   def masto_instance(conn, _params) do
 108     response = %{
 109       uri: Web.base_url(),
 110       title: Keyword.get(@instance, :name),
 111       description: "A Pleroma instance, an alternative fediverse server",
 112       version: "#{@mastodon_api_level} (compatible; #{Keyword.get(@instance, :version)})",
 113       email: Keyword.get(@instance, :email),
 114       urls: %{
 115         streaming_api: String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws")
 116       },
 117       stats: Stats.get_stats(),
 118       thumbnail: Web.base_url() <> "/instance/thumbnail.jpeg",
 119       max_toot_chars: Keyword.get(@instance, :limit)
 120     }
 121
 122     json(conn, response)
 123   end
 124
 125   def peers(conn, _params) do
 126     json(conn, Stats.get_peers())
 127   end
 128
 129   defp mastodonized_emoji do
 130     Pleroma.Formatter.get_custom_emoji()
 131     |> Enum.map(fn {shortcode, relative_url} ->
 132       url = to_string(URI.merge(Web.base_url(), relative_url))
 133
 134       %{
 135         "shortcode" => shortcode,
 136         "static_url" => url,
 137         "url" => url
 138       }
 139     end)
 140   end
 141
 142   def custom_emojis(conn, _params) do
 143     mastodon_emoji = mastodonized_emoji()
 144     json(conn, mastodon_emoji)
 145   end
 146
 147   defp add_link_headers(conn, method, activities, param \\ false) do
 148     last = List.last(activities)
 149     first = List.first(activities)
 150
 151     if last do
 152       min = last.id
 153       max = first.id
 154
 155       {next_url, prev_url} =
 156         if param do
 157           {
 158             mastodon_api_url(Pleroma.Web.Endpoint, method, param, max_id: min),
 159             mastodon_api_url(Pleroma.Web.Endpoint, method, param, since_id: max)
 160           }
 161         else
 162           {
 163             mastodon_api_url(Pleroma.Web.Endpoint, method, max_id: min),
 164             mastodon_api_url(Pleroma.Web.Endpoint, method, since_id: max)
 165           }
 166         end
 167
 168       conn
 169       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 170     else
 171       conn
 172     end
 173   end
 174
 175   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 176     params =
 177       params
 178       |> Map.put("type", ["Create", "Announce"])
 179       |> Map.put("blocking_user", user)
 180       |> Map.put("user", user)
 181
 182     activities =
 183       ActivityPub.fetch_activities([user.ap_id | user.following], params)
 184       |> Enum.reverse()
 185
 186     conn
 187     |> add_link_headers(:home_timeline, activities)
 188     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 189   end
 190
 191   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 192     params =
 193       params
 194       |> Map.put("type", ["Create", "Announce"])
 195       |> Map.put("local_only", params["local"] in [true, "True", "true", "1"])
 196       |> Map.put("blocking_user", user)
 197
 198     activities =
 199       ActivityPub.fetch_public_activities(params)
 200       |> Enum.reverse()
 201
 202     conn
 203     |> add_link_headers(:public_timeline, activities)
 204     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 205   end
 206
 207   def user_statuses(%{assigns: %{user: user}} = conn, params) do
 208     with %User{ap_id: ap_id} <- Repo.get(User, params["id"]) do
 209       params =
 210         params
 211         |> Map.put("type", ["Create", "Announce"])
 212         |> Map.put("actor_id", ap_id)
 213         |> Map.put("whole_db", true)
 214
 215       activities =
 216         if params["pinned"] == "true" do
 217           # Since Pleroma has no "pinned" posts feature, we'll just set an empty list here
 218           []
 219         else
 220           ActivityPub.fetch_public_activities(params)
 221           |> Enum.reverse()
 222         end
 223
 224       conn
 225       |> add_link_headers(:user_statuses, activities, params["id"])
 226       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 227     end
 228   end
 229
 230   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 231     with %Activity{} = activity <- Repo.get(Activity, id),
 232          true <- ActivityPub.visible_for_user?(activity, user) do
 233       render(conn, StatusView, "status.json", %{activity: activity, for: user})
 234     end
 235   end
 236
 237   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 238     with %Activity{} = activity <- Repo.get(Activity, id),
 239          activities <-
 240            ActivityPub.fetch_activities_for_context(activity.data["context"], %{
 241              "blocking_user" => user,
 242              "user" => user
 243            }),
 244          activities <-
 245            activities |> Enum.filter(fn %{id: aid} -> to_string(aid) != to_string(id) end),
 246          activities <-
 247            activities |> Enum.filter(fn %{data: %{"type" => type}} -> type == "Create" end),
 248          grouped_activities <- Enum.group_by(activities, fn %{id: id} -> id < activity.id end) do
 249       result = %{
 250         ancestors:
 251           StatusView.render(
 252             "index.json",
 253             for: user,
 254             activities: grouped_activities[true] || [],
 255             as: :activity
 256           )
 257           |> Enum.reverse(),
 258         descendants:
 259           StatusView.render(
 260             "index.json",
 261             for: user,
 262             activities: grouped_activities[false] || [],
 263             as: :activity
 264           )
 265           |> Enum.reverse()
 266       }
 267
 268       json(conn, result)
 269     end
 270   end
 271
 272   def post_status(%{assigns: %{user: user}} = conn, %{"status" => _} = params) do
 273     params =
 274       params
 275       |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 276       |> Map.put("no_attachment_links", true)
 277
 278     idempotency_key =
 279       case get_req_header(conn, "idempotency-key") do
 280         [key] -> key
 281         _ -> Ecto.UUID.generate()
 282       end
 283
 284     {:ok, activity} =
 285       Cachex.get!(
 286         :idempotency_cache,
 287         idempotency_key,
 288         fallback: fn _ -> CommonAPI.post(user, params) end
 289       )
 290
 291     render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 292   end
 293
 294   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 295     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 296       json(conn, %{})
 297     else
 298       _e ->
 299         conn
 300         |> put_status(403)
 301         |> json(%{error: "Can't delete this post"})
 302     end
 303   end
 304
 305   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 306     with {:ok, announce, _activity} = CommonAPI.repeat(ap_id_or_id, user) do
 307       render(conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity})
 308     end
 309   end
 310
 311   def unreblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 312     with {:ok, _, _, %{data: %{"id" => id}}} = CommonAPI.unrepeat(ap_id_or_id, user),
 313          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 314       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 315     end
 316   end
 317
 318   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 319     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 320          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 321       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 322     end
 323   end
 324
 325   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 326     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 327          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 328       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 329     end
 330   end
 331
 332   def notifications(%{assigns: %{user: user}} = conn, params) do
 333     notifications = Notification.for_user(user, params)
 334
 335     result =
 336       Enum.map(notifications, fn x ->
 337         render_notification(user, x)
 338       end)
 339       |> Enum.filter(& &1)
 340
 341     conn
 342     |> add_link_headers(:notifications, notifications)
 343     |> json(result)
 344   end
 345
 346   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 347     with {:ok, notification} <- Notification.get(user, id) do
 348       json(conn, render_notification(user, notification))
 349     else
 350       {:error, reason} ->
 351         conn
 352         |> put_resp_content_type("application/json")
 353         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 354     end
 355   end
 356
 357   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 358     Notification.clear(user)
 359     json(conn, %{})
 360   end
 361
 362   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 363     with {:ok, _notif} <- Notification.dismiss(user, id) do
 364       json(conn, %{})
 365     else
 366       {:error, reason} ->
 367         conn
 368         |> put_resp_content_type("application/json")
 369         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 370     end
 371   end
 372
 373   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 374     id = List.wrap(id)
 375     q = from(u in User, where: u.id in ^id)
 376     targets = Repo.all(q)
 377     render(conn, AccountView, "relationships.json", %{user: user, targets: targets})
 378   end
 379
 380   def upload(%{assigns: %{user: _}} = conn, %{"file" => file}) do
 381     with {:ok, object} <- ActivityPub.upload(file) do
 382       data =
 383         object.data
 384         |> Map.put("id", object.id)
 385
 386       render(conn, StatusView, "attachment.json", %{attachment: data})
 387     end
 388   end
 389
 390   def favourited_by(conn, %{"id" => id}) do
 391     with %Activity{data: %{"object" => %{"likes" => likes}}} <- Repo.get(Activity, id) do
 392       q = from(u in User, where: u.ap_id in ^likes)
 393       users = Repo.all(q)
 394       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 395     else
 396       _ -> json(conn, [])
 397     end
 398   end
 399
 400   def reblogged_by(conn, %{"id" => id}) do
 401     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 402       q = from(u in User, where: u.ap_id in ^announces)
 403       users = Repo.all(q)
 404       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 405     else
 406       _ -> json(conn, [])
 407     end
 408   end
 409
 410   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 411     params =
 412       params
 413       |> Map.put("type", "Create")
 414       |> Map.put("local_only", !!params["local"])
 415       |> Map.put("blocking_user", user)
 416
 417     activities =
 418       ActivityPub.fetch_public_activities(params)
 419       |> Enum.reverse()
 420
 421     conn
 422     |> add_link_headers(:hashtag_timeline, activities, params["tag"])
 423     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 424   end
 425
 426   # TODO: Pagination
 427   def followers(conn, %{"id" => id}) do
 428     with %User{} = user <- Repo.get(User, id),
 429          {:ok, followers} <- User.get_followers(user) do
 430       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 431     end
 432   end
 433
 434   def following(conn, %{"id" => id}) do
 435     with %User{} = user <- Repo.get(User, id),
 436          {:ok, followers} <- User.get_friends(user) do
 437       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 438     end
 439   end
 440
 441   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 442     with %User{} = followed <- Repo.get(User, id),
 443          {:ok, follower} <- User.follow(follower, followed),
 444          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 445       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 446     else
 447       {:error, message} ->
 448         conn
 449         |> put_resp_content_type("application/json")
 450         |> send_resp(403, Jason.encode!(%{"error" => message}))
 451     end
 452   end
 453
 454   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 455     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 456          {:ok, follower} <- User.follow(follower, followed),
 457          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 458       render(conn, AccountView, "account.json", %{user: followed})
 459     else
 460       {:error, message} ->
 461         conn
 462         |> put_resp_content_type("application/json")
 463         |> send_resp(403, Jason.encode!(%{"error" => message}))
 464     end
 465   end
 466
 467   # TODO: Clean up and unify
 468   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 469     with %User{} = followed <- Repo.get(User, id),
 470          {:ok, follower, follow_activity} <- User.unfollow(follower, followed),
 471          {:ok, _activity} <-
 472            ActivityPub.insert(%{
 473              "type" => "Undo",
 474              "actor" => follower.ap_id,
 475              # get latest Follow for these users
 476              "object" => follow_activity.data["id"]
 477            }) do
 478       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 479     end
 480   end
 481
 482   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 483     with %User{} = blocked <- Repo.get(User, id),
 484          {:ok, blocker} <- User.block(blocker, blocked) do
 485       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 486     else
 487       {:error, message} ->
 488         conn
 489         |> put_resp_content_type("application/json")
 490         |> send_resp(403, Jason.encode!(%{"error" => message}))
 491     end
 492   end
 493
 494   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 495     with %User{} = blocked <- Repo.get(User, id),
 496          {:ok, blocker} <- User.unblock(blocker, blocked) do
 497       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 498     else
 499       {:error, message} ->
 500         conn
 501         |> put_resp_content_type("application/json")
 502         |> send_resp(403, Jason.encode!(%{"error" => message}))
 503     end
 504   end
 505
 506   # TODO: Use proper query
 507   def blocks(%{assigns: %{user: user}} = conn, _) do
 508     with blocked_users <- user.info["blocks"] || [],
 509          accounts <- Enum.map(blocked_users, fn ap_id -> User.get_cached_by_ap_id(ap_id) end) do
 510       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 511       json(conn, res)
 512     end
 513   end
 514
 515   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 516     accounts = User.search(query, params["resolve"] == "true")
 517
 518     fetched =
 519       if Regex.match?(~r/https?:/, query) do
 520         with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 521           activities
 522           |> Enum.filter(fn
 523             %{data: %{"type" => "Create"}} -> true
 524             _ -> false
 525           end)
 526         else
 527           _e -> []
 528         end
 529       end || []
 530
 531     q =
 532       from(
 533         a in Activity,
 534         where: fragment("?->>'type' = 'Create'", a.data),
 535         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 536         where:
 537           fragment(
 538             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 539             a.data,
 540             ^query
 541           ),
 542         limit: 20,
 543         order_by: [desc: :id]
 544       )
 545
 546     statuses = Repo.all(q) ++ fetched
 547
 548     tags =
 549       String.split(query)
 550       |> Enum.uniq()
 551       |> Enum.filter(fn tag -> String.starts_with?(tag, "#") end)
 552       |> Enum.map(fn tag -> String.slice(tag, 1..-1) end)
 553
 554     res = %{
 555       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 556       "statuses" =>
 557         StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 558       "hashtags" => tags
 559     }
 560
 561     json(conn, res)
 562   end
 563
 564   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 565     accounts = User.search(query, params["resolve"] == "true")
 566
 567     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 568
 569     json(conn, res)
 570   end
 571
 572   def favourites(%{assigns: %{user: user}} = conn, _) do
 573     params =
 574       %{}
 575       |> Map.put("type", "Create")
 576       |> Map.put("favorited_by", user.ap_id)
 577       |> Map.put("blocking_user", user)
 578
 579     activities =
 580       ActivityPub.fetch_public_activities(params)
 581       |> Enum.reverse()
 582
 583     conn
 584     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 585   end
 586
 587   def index(%{assigns: %{user: user}} = conn, _params) do
 588     token =
 589       conn
 590       |> get_session(:oauth_token)
 591
 592     if user && token do
 593       mastodon_emoji = mastodonized_emoji()
 594       accounts = Map.put(%{}, user.id, AccountView.render("account.json", %{user: user}))
 595
 596       initial_state =
 597         %{
 598           meta: %{
 599             streaming_api_base_url:
 600               String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 601             access_token: token,
 602             locale: "en",
 603             domain: Pleroma.Web.Endpoint.host(),
 604             admin: "1",
 605             me: "#{user.id}",
 606             unfollow_modal: false,
 607             boost_modal: false,
 608             delete_modal: true,
 609             auto_play_gif: false,
 610             reduce_motion: false
 611           },
 612           compose: %{
 613             me: "#{user.id}",
 614             default_privacy: "public",
 615             default_sensitive: false
 616           },
 617           media_attachments: %{
 618             accept_content_types: [
 619               ".jpg",
 620               ".jpeg",
 621               ".png",
 622               ".gif",
 623               ".webm",
 624               ".mp4",
 625               ".m4v",
 626               "image\/jpeg",
 627               "image\/png",
 628               "image\/gif",
 629               "video\/webm",
 630               "video\/mp4"
 631             ]
 632           },
 633           settings:
 634             Map.get(user.info, "settings") ||
 635               %{
 636                 onboarded: true,
 637                 home: %{
 638                   shows: %{
 639                     reblog: true,
 640                     reply: true
 641                   }
 642                 },
 643                 notifications: %{
 644                   alerts: %{
 645                     follow: true,
 646                     favourite: true,
 647                     reblog: true,
 648                     mention: true
 649                   },
 650                   shows: %{
 651                     follow: true,
 652                     favourite: true,
 653                     reblog: true,
 654                     mention: true
 655                   },
 656                   sounds: %{
 657                     follow: true,
 658                     favourite: true,
 659                     reblog: true,
 660                     mention: true
 661                   }
 662                 }
 663               },
 664           push_subscription: nil,
 665           accounts: accounts,
 666           custom_emojis: mastodon_emoji,
 667           char_limit: Keyword.get(@instance, :limit)
 668         }
 669         |> Jason.encode!()
 670
 671       conn
 672       |> put_layout(false)
 673       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 674     else
 675       conn
 676       |> redirect(to: "/web/login")
 677     end
 678   end
 679
 680   def put_settings(%{assigns: %{user: user}} = conn, %{"data" => settings} = _params) do
 681     with new_info <- Map.put(user.info, "settings", settings),
 682          change <- User.info_changeset(user, %{info: new_info}),
 683          {:ok, _user} <- User.update_and_set_cache(change) do
 684       conn
 685       |> json(%{})
 686     else
 687       e ->
 688         conn
 689         |> json(%{error: inspect(e)})
 690     end
 691   end
 692
 693   def login(conn, _) do
 694     conn
 695     |> render(MastodonView, "login.html", %{error: false})
 696   end
 697
 698   defp get_or_make_app() do
 699     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 700       {:ok, app}
 701     else
 702       _e ->
 703         cs =
 704           App.register_changeset(%App{}, %{
 705             client_name: "Mastodon-Local",
 706             redirect_uris: ".",
 707             scopes: "read,write,follow"
 708           })
 709
 710         Repo.insert(cs)
 711     end
 712   end
 713
 714   def login_post(conn, %{"authorization" => %{"name" => name, "password" => password}}) do
 715     with %User{} = user <- User.get_by_nickname_or_email(name),
 716          true <- Pbkdf2.checkpw(password, user.password_hash),
 717          {:ok, app} <- get_or_make_app(),
 718          {:ok, auth} <- Authorization.create_authorization(app, user),
 719          {:ok, token} <- Token.exchange_token(app, auth) do
 720       conn
 721       |> put_session(:oauth_token, token.token)
 722       |> redirect(to: "/web/getting-started")
 723     else
 724       _e ->
 725         conn
 726         |> render(MastodonView, "login.html", %{error: "Wrong username or password"})
 727     end
 728   end
 729
 730   def logout(conn, _) do
 731     conn
 732     |> clear_session
 733     |> redirect(to: "/")
 734   end
 735
 736   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 737     Logger.debug("Unimplemented, returning unmodified relationship")
 738
 739     with %User{} = target <- Repo.get(User, id) do
 740       render(conn, AccountView, "relationship.json", %{user: user, target: target})
 741     end
 742   end
 743
 744   def empty_array(conn, _) do
 745     Logger.debug("Unimplemented, returning an empty array")
 746     json(conn, [])
 747   end
 748
 749   def empty_object(conn, _) do
 750     Logger.debug("Unimplemented, returning an empty object")
 751     json(conn, %{})
 752   end
 753
 754   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
 755     actor = User.get_cached_by_ap_id(activity.data["actor"])
 756
 757     created_at =
 758       NaiveDateTime.to_iso8601(created_at)
 759       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 760
 761     case activity.data["type"] do
 762       "Create" ->
 763         %{
 764           id: id,
 765           type: "mention",
 766           created_at: created_at,
 767           account: AccountView.render("account.json", %{user: actor}),
 768           status: StatusView.render("status.json", %{activity: activity, for: user})
 769         }
 770
 771       "Like" ->
 772         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 773
 774         %{
 775           id: id,
 776           type: "favourite",
 777           created_at: created_at,
 778           account: AccountView.render("account.json", %{user: actor}),
 779           status: StatusView.render("status.json", %{activity: liked_activity, for: user})
 780         }
 781
 782       "Announce" ->
 783         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 784
 785         %{
 786           id: id,
 787           type: "reblog",
 788           created_at: created_at,
 789           account: AccountView.render("account.json", %{user: actor}),
 790           status: StatusView.render("status.json", %{activity: announced_activity, for: user})
 791         }
 792
 793       "Follow" ->
 794         %{
 795           id: id,
 796           type: "follow",
 797           created_at: created_at,
 798           account: AccountView.render("account.json", %{user: actor})
 799         }
 800
 801       _ ->
 802         nil
 803     end
 804   end
 805 end