git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification, Stats}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView, ListView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.{CommonAPI, OStatus}
   8   alias Pleroma.Web.OAuth.{Authorization, Token, App}
   9   alias Comeonin.Pbkdf2
  10   import Ecto.Query
  11   require Logger
  12
  13   def create_app(conn, params) do
  14     with cs <- App.register_changeset(%App{}, params) |> IO.inspect(),
  15          {:ok, app} <- Repo.insert(cs) |> IO.inspect() do
  16       res = %{
  17         id: app.id,
  18         client_id: app.client_id,
  19         client_secret: app.client_secret
  20       }
  21
  22       json(conn, res)
  23     end
  24   end
  25
  26   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  27     original_user = user
  28
  29     params =
  30       if bio = params["note"] do
  31         Map.put(params, "bio", bio)
  32       else
  33         params
  34       end
  35
  36     params =
  37       if name = params["display_name"] do
  38         Map.put(params, "name", name)
  39       else
  40         params
  41       end
  42
  43     user =
  44       if avatar = params["avatar"] do
  45         with %Plug.Upload{} <- avatar,
  46              {:ok, object} <- ActivityPub.upload(avatar),
  47              change = Ecto.Changeset.change(user, %{avatar: object.data}),
  48              {:ok, user} = User.update_and_set_cache(change) do
  49           user
  50         else
  51           _e -> user
  52         end
  53       else
  54         user
  55       end
  56
  57     user =
  58       if banner = params["header"] do
  59         with %Plug.Upload{} <- banner,
  60              {:ok, object} <- ActivityPub.upload(banner),
  61              new_info <- Map.put(user.info, "banner", object.data),
  62              change <- User.info_changeset(user, %{info: new_info}),
  63              {:ok, user} <- User.update_and_set_cache(change) do
  64           user
  65         else
  66           _e -> user
  67         end
  68       else
  69         user
  70       end
  71
  72     with changeset <- User.update_changeset(user, params),
  73          {:ok, user} <- User.update_and_set_cache(changeset) do
  74       if original_user != user do
  75         CommonAPI.update(user)
  76       end
  77
  78       json(conn, AccountView.render("account.json", %{user: user}))
  79     else
  80       _e ->
  81         conn
  82         |> put_status(403)
  83         |> json(%{error: "Invalid request"})
  84     end
  85   end
  86
  87   def verify_credentials(%{assigns: %{user: user}} = conn, _) do
  88     account = AccountView.render("account.json", %{user: user})
  89     json(conn, account)
  90   end
  91
  92   def user(conn, %{"id" => id}) do
  93     with %User{} = user <- Repo.get(User, id) do
  94       account = AccountView.render("account.json", %{user: user})
  95       json(conn, account)
  96     else
  97       _e ->
  98         conn
  99         |> put_status(404)
 100         |> json(%{error: "Can't find user"})
 101     end
 102   end
 103
 104   @instance Application.get_env(:pleroma, :instance)
 105   @mastodon_api_level "2.3.3"
 106
 107   def masto_instance(conn, _params) do
 108     response = %{
 109       uri: Web.base_url(),
 110       title: Keyword.get(@instance, :name),
 111       description: "A Pleroma instance, an alternative fediverse server",
 112       version: "#{@mastodon_api_level} (compatible; #{Keyword.get(@instance, :version)})",
 113       email: Keyword.get(@instance, :email),
 114       urls: %{
 115         streaming_api: String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws")
 116       },
 117       stats: Stats.get_stats(),
 118       thumbnail: Web.base_url() <> "/instance/thumbnail.jpeg",
 119       max_toot_chars: Keyword.get(@instance, :limit)
 120     }
 121
 122     json(conn, response)
 123   end
 124
 125   def peers(conn, _params) do
 126     json(conn, Stats.get_peers())
 127   end
 128
 129   defp mastodonized_emoji do
 130     Pleroma.Formatter.get_custom_emoji()
 131     |> Enum.map(fn {shortcode, relative_url} ->
 132       url = to_string(URI.merge(Web.base_url(), relative_url))
 133
 134       %{
 135         "shortcode" => shortcode,
 136         "static_url" => url,
 137         "url" => url
 138       }
 139     end)
 140   end
 141
 142   def custom_emojis(conn, _params) do
 143     mastodon_emoji = mastodonized_emoji()
 144     json(conn, mastodon_emoji)
 145   end
 146
 147   defp add_link_headers(conn, method, activities, param \\ nil, params \\ %{}) do
 148     last = List.last(activities)
 149     first = List.first(activities)
 150
 151     if last do
 152       min = last.id
 153       max = first.id
 154
 155       {next_url, prev_url} =
 156         if param do
 157           {
 158             mastodon_api_url(
 159               Pleroma.Web.Endpoint,
 160               method,
 161               param,
 162               Map.merge(params, %{max_id: min})
 163             ),
 164             mastodon_api_url(
 165               Pleroma.Web.Endpoint,
 166               method,
 167               param,
 168               Map.merge(params, %{since_id: max})
 169             )
 170           }
 171         else
 172           {
 173             mastodon_api_url(
 174               Pleroma.Web.Endpoint,
 175               method,
 176               Map.merge(params, %{max_id: min})
 177             ),
 178             mastodon_api_url(
 179               Pleroma.Web.Endpoint,
 180               method,
 181               Map.merge(params, %{since_id: max})
 182             )
 183           }
 184         end
 185
 186       conn
 187       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 188     else
 189       conn
 190     end
 191   end
 192
 193   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 194     params =
 195       params
 196       |> Map.put("type", ["Create", "Announce"])
 197       |> Map.put("blocking_user", user)
 198       |> Map.put("user", user)
 199
 200     activities =
 201       ActivityPub.fetch_activities([user.ap_id | user.following], params)
 202       |> Enum.reverse()
 203
 204     conn
 205     |> add_link_headers(:home_timeline, activities)
 206     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 207   end
 208
 209   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 210     local_only = params["local"] in [true, "True", "true", "1"]
 211
 212     params =
 213       params
 214       |> Map.put("type", ["Create", "Announce"])
 215       |> Map.put("local_only", local_only)
 216       |> Map.put("blocking_user", user)
 217
 218     activities =
 219       ActivityPub.fetch_public_activities(params)
 220       |> Enum.reverse()
 221
 222     conn
 223     |> add_link_headers(:public_timeline, activities, false, %{"local" => local_only})
 224     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 225   end
 226
 227   def user_statuses(%{assigns: %{user: reading_user}} = conn, params) do
 228     with %User{} = user <- Repo.get(User, params["id"]) do
 229       # Since Pleroma has no "pinned" posts feature, we'll just set an empty list here
 230       activities =
 231         if params["pinned"] == "true" do
 232           []
 233         else
 234           ActivityPub.fetch_user_activities(user, reading_user, params)
 235         end
 236
 237       conn
 238       |> add_link_headers(:user_statuses, activities, params["id"])
 239       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 240     end
 241   end
 242
 243   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 244     query = ActivityPub.fetch_activities_query([user.ap_id], %{visibility: "direct"})
 245     activities = Repo.all(query)
 246
 247     conn
 248     |> add_link_headers(:dm_timeline, activities)
 249     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 250   end
 251
 252   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 253     with %Activity{} = activity <- Repo.get(Activity, id),
 254          true <- ActivityPub.visible_for_user?(activity, user) do
 255       render(conn, StatusView, "status.json", %{activity: activity, for: user})
 256     end
 257   end
 258
 259   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 260     with %Activity{} = activity <- Repo.get(Activity, id),
 261          activities <-
 262            ActivityPub.fetch_activities_for_context(activity.data["context"], %{
 263              "blocking_user" => user,
 264              "user" => user
 265            }),
 266          activities <-
 267            activities |> Enum.filter(fn %{id: aid} -> to_string(aid) != to_string(id) end),
 268          activities <-
 269            activities |> Enum.filter(fn %{data: %{"type" => type}} -> type == "Create" end),
 270          grouped_activities <- Enum.group_by(activities, fn %{id: id} -> id < activity.id end) do
 271       result = %{
 272         ancestors:
 273           StatusView.render(
 274             "index.json",
 275             for: user,
 276             activities: grouped_activities[true] || [],
 277             as: :activity
 278           )
 279           |> Enum.reverse(),
 280         descendants:
 281           StatusView.render(
 282             "index.json",
 283             for: user,
 284             activities: grouped_activities[false] || [],
 285             as: :activity
 286           )
 287           |> Enum.reverse()
 288       }
 289
 290       json(conn, result)
 291     end
 292   end
 293
 294   def post_status(%{assigns: %{user: user}} = conn, %{"status" => _} = params) do
 295     params =
 296       params
 297       |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 298       |> Map.put("no_attachment_links", true)
 299
 300     idempotency_key =
 301       case get_req_header(conn, "idempotency-key") do
 302         [key] -> key
 303         _ -> Ecto.UUID.generate()
 304       end
 305
 306     {:ok, activity} =
 307       Cachex.fetch!(:idempotency_cache, idempotency_key, fn _ -> CommonAPI.post(user, params) end)
 308
 309     render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 310   end
 311
 312   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 313     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 314       json(conn, %{})
 315     else
 316       _e ->
 317         conn
 318         |> put_status(403)
 319         |> json(%{error: "Can't delete this post"})
 320     end
 321   end
 322
 323   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 324     with {:ok, announce, _activity} = CommonAPI.repeat(ap_id_or_id, user) do
 325       render(conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity})
 326     end
 327   end
 328
 329   def unreblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 330     with {:ok, _, _, %{data: %{"id" => id}}} = CommonAPI.unrepeat(ap_id_or_id, user),
 331          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 332       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 333     end
 334   end
 335
 336   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 337     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 338          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 339       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 340     end
 341   end
 342
 343   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 344     with {:ok, _, _, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 345          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 346       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 347     end
 348   end
 349
 350   def notifications(%{assigns: %{user: user}} = conn, params) do
 351     notifications = Notification.for_user(user, params)
 352
 353     result =
 354       Enum.map(notifications, fn x ->
 355         render_notification(user, x)
 356       end)
 357       |> Enum.filter(& &1)
 358
 359     conn
 360     |> add_link_headers(:notifications, notifications)
 361     |> json(result)
 362   end
 363
 364   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 365     with {:ok, notification} <- Notification.get(user, id) do
 366       json(conn, render_notification(user, notification))
 367     else
 368       {:error, reason} ->
 369         conn
 370         |> put_resp_content_type("application/json")
 371         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 372     end
 373   end
 374
 375   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 376     Notification.clear(user)
 377     json(conn, %{})
 378   end
 379
 380   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 381     with {:ok, _notif} <- Notification.dismiss(user, id) do
 382       json(conn, %{})
 383     else
 384       {:error, reason} ->
 385         conn
 386         |> put_resp_content_type("application/json")
 387         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 388     end
 389   end
 390
 391   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 392     id = List.wrap(id)
 393     q = from(u in User, where: u.id in ^id)
 394     targets = Repo.all(q)
 395     render(conn, AccountView, "relationships.json", %{user: user, targets: targets})
 396   end
 397
 398   def upload(%{assigns: %{user: _}} = conn, %{"file" => file}) do
 399     with {:ok, object} <- ActivityPub.upload(file) do
 400       data =
 401         object.data
 402         |> Map.put("id", object.id)
 403
 404       render(conn, StatusView, "attachment.json", %{attachment: data})
 405     end
 406   end
 407
 408   def favourited_by(conn, %{"id" => id}) do
 409     with %Activity{data: %{"object" => %{"likes" => likes}}} <- Repo.get(Activity, id) do
 410       q = from(u in User, where: u.ap_id in ^likes)
 411       users = Repo.all(q)
 412       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 413     else
 414       _ -> json(conn, [])
 415     end
 416   end
 417
 418   def reblogged_by(conn, %{"id" => id}) do
 419     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 420       q = from(u in User, where: u.ap_id in ^announces)
 421       users = Repo.all(q)
 422       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 423     else
 424       _ -> json(conn, [])
 425     end
 426   end
 427
 428   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 429     local_only = params["local"] in [true, "True", "true", "1"]
 430
 431     params =
 432       params
 433       |> Map.put("type", "Create")
 434       |> Map.put("local_only", local_only)
 435       |> Map.put("blocking_user", user)
 436
 437     activities =
 438       ActivityPub.fetch_public_activities(params)
 439       |> Enum.reverse()
 440
 441     conn
 442     |> add_link_headers(:hashtag_timeline, activities, params["tag"], %{"local" => local_only})
 443     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 444   end
 445
 446   # TODO: Pagination
 447   def followers(conn, %{"id" => id}) do
 448     with %User{} = user <- Repo.get(User, id),
 449          {:ok, followers} <- User.get_followers(user) do
 450       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 451     end
 452   end
 453
 454   def following(conn, %{"id" => id}) do
 455     with %User{} = user <- Repo.get(User, id),
 456          {:ok, followers} <- User.get_friends(user) do
 457       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 458     end
 459   end
 460
 461   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 462     with %User{} = followed <- Repo.get(User, id),
 463          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 464          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 465       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 466     else
 467       {:error, message} ->
 468         conn
 469         |> put_resp_content_type("application/json")
 470         |> send_resp(403, Jason.encode!(%{"error" => message}))
 471     end
 472   end
 473
 474   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 475     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 476          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 477          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 478       render(conn, AccountView, "account.json", %{user: followed})
 479     else
 480       {:error, message} ->
 481         conn
 482         |> put_resp_content_type("application/json")
 483         |> send_resp(403, Jason.encode!(%{"error" => message}))
 484     end
 485   end
 486
 487   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 488     with %User{} = followed <- Repo.get(User, id),
 489          {:ok, _activity} <- ActivityPub.unfollow(follower, followed),
 490          {:ok, follower, _} <- User.unfollow(follower, followed) do
 491       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 492     end
 493   end
 494
 495   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 496     with %User{} = blocked <- Repo.get(User, id),
 497          {:ok, blocker} <- User.block(blocker, blocked),
 498          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
 499       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 500     else
 501       {:error, message} ->
 502         conn
 503         |> put_resp_content_type("application/json")
 504         |> send_resp(403, Jason.encode!(%{"error" => message}))
 505     end
 506   end
 507
 508   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 509     with %User{} = blocked <- Repo.get(User, id),
 510          {:ok, blocker} <- User.unblock(blocker, blocked),
 511          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
 512       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 513     else
 514       {:error, message} ->
 515         conn
 516         |> put_resp_content_type("application/json")
 517         |> send_resp(403, Jason.encode!(%{"error" => message}))
 518     end
 519   end
 520
 521   # TODO: Use proper query
 522   def blocks(%{assigns: %{user: user}} = conn, _) do
 523     with blocked_users <- user.info["blocks"] || [],
 524          accounts <- Enum.map(blocked_users, fn ap_id -> User.get_cached_by_ap_id(ap_id) end) do
 525       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 526       json(conn, res)
 527     end
 528   end
 529
 530   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 531     accounts = User.search(query, params["resolve"] == "true")
 532
 533     fetched =
 534       if Regex.match?(~r/https?:/, query) do
 535         with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 536           activities
 537           |> Enum.filter(fn
 538             %{data: %{"type" => "Create"}} -> true
 539             _ -> false
 540           end)
 541         else
 542           _e -> []
 543         end
 544       end || []
 545
 546     q =
 547       from(
 548         a in Activity,
 549         where: fragment("?->>'type' = 'Create'", a.data),
 550         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 551         where:
 552           fragment(
 553             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 554             a.data,
 555             ^query
 556           ),
 557         limit: 20,
 558         order_by: [desc: :id]
 559       )
 560
 561     statuses = Repo.all(q) ++ fetched
 562
 563     tags =
 564       String.split(query)
 565       |> Enum.uniq()
 566       |> Enum.filter(fn tag -> String.starts_with?(tag, "#") end)
 567       |> Enum.map(fn tag -> String.slice(tag, 1..-1) end)
 568
 569     res = %{
 570       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 571       "statuses" =>
 572         StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 573       "hashtags" => tags
 574     }
 575
 576     json(conn, res)
 577   end
 578
 579   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 580     accounts = User.search(query, params["resolve"] == "true")
 581
 582     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 583
 584     json(conn, res)
 585   end
 586
 587   def favourites(%{assigns: %{user: user}} = conn, _) do
 588     params =
 589       %{}
 590       |> Map.put("type", "Create")
 591       |> Map.put("favorited_by", user.ap_id)
 592       |> Map.put("blocking_user", user)
 593
 594     activities =
 595       ActivityPub.fetch_public_activities(params)
 596       |> Enum.reverse()
 597
 598     conn
 599     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 600   end
 601
 602   def get_lists(%{assigns: %{user: user}} = conn, opts) do
 603     lists = Pleroma.List.for_user(user, opts)
 604     res = ListView.render("lists.json", lists: lists)
 605     json(conn, res)
 606   end
 607
 608   def get_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 609     with %Pleroma.List{} = list <- Pleroma.List.get(id, user) do
 610       res = ListView.render("list.json", list: list)
 611       json(conn, res)
 612     else
 613       _e -> json(conn, "error")
 614     end
 615   end
 616
 617   def delete_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 618     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 619          {:ok, _list} <- Pleroma.List.delete(list) do
 620       json(conn, %{})
 621     else
 622       _e ->
 623         json(conn, "error")
 624     end
 625   end
 626
 627   def create_list(%{assigns: %{user: user}} = conn, %{"title" => title}) do
 628     with {:ok, %Pleroma.List{} = list} <- Pleroma.List.create(title, user) do
 629       res = ListView.render("list.json", list: list)
 630       json(conn, res)
 631     end
 632   end
 633
 634   def add_to_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 635     accounts
 636     |> Enum.each(fn account_id ->
 637       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 638            %User{} = followed <- Repo.get(User, account_id) do
 639         Pleroma.List.follow(list, followed)
 640       end
 641     end)
 642
 643     json(conn, %{})
 644   end
 645
 646   def remove_from_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 647     accounts
 648     |> Enum.each(fn account_id ->
 649       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 650            %User{} = followed <- Repo.get(Pleroma.User, account_id) do
 651         Pleroma.List.unfollow(list, followed)
 652       end
 653     end)
 654
 655     json(conn, %{})
 656   end
 657
 658   def list_accounts(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 659     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 660          {:ok, users} = Pleroma.List.get_following(list) do
 661       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 662     end
 663   end
 664
 665   def rename_list(%{assigns: %{user: user}} = conn, %{"id" => id, "title" => title}) do
 666     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 667          {:ok, list} <- Pleroma.List.rename(list, title) do
 668       res = ListView.render("list.json", list: list)
 669       json(conn, res)
 670     else
 671       _e ->
 672         json(conn, "error")
 673     end
 674   end
 675
 676   def list_timeline(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 677     with %Pleroma.List{title: title, following: following} <- Pleroma.List.get(id, user) do
 678       params =
 679         params
 680         |> Map.put("type", "Create")
 681         |> Map.put("blocking_user", user)
 682
 683       # adding title is a hack to not make empty lists function like a public timeline
 684       activities =
 685         ActivityPub.fetch_activities([title | following], params)
 686         |> Enum.reverse()
 687
 688       conn
 689       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 690     else
 691       _e ->
 692         conn
 693         |> put_status(403)
 694         |> json(%{error: "Error."})
 695     end
 696   end
 697
 698   def index(%{assigns: %{user: user}} = conn, _params) do
 699     token =
 700       conn
 701       |> get_session(:oauth_token)
 702
 703     if user && token do
 704       mastodon_emoji = mastodonized_emoji()
 705       accounts = Map.put(%{}, user.id, AccountView.render("account.json", %{user: user}))
 706
 707       initial_state =
 708         %{
 709           meta: %{
 710             streaming_api_base_url:
 711               String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 712             access_token: token,
 713             locale: "en",
 714             domain: Pleroma.Web.Endpoint.host(),
 715             admin: "1",
 716             me: "#{user.id}",
 717             unfollow_modal: false,
 718             boost_modal: false,
 719             delete_modal: true,
 720             auto_play_gif: false,
 721             reduce_motion: false
 722           },
 723           compose: %{
 724             me: "#{user.id}",
 725             default_privacy: "public",
 726             default_sensitive: false
 727           },
 728           media_attachments: %{
 729             accept_content_types: [
 730               ".jpg",
 731               ".jpeg",
 732               ".png",
 733               ".gif",
 734               ".webm",
 735               ".mp4",
 736               ".m4v",
 737               "image\/jpeg",
 738               "image\/png",
 739               "image\/gif",
 740               "video\/webm",
 741               "video\/mp4"
 742             ]
 743           },
 744           settings:
 745             Map.get(user.info, "settings") ||
 746               %{
 747                 onboarded: true,
 748                 home: %{
 749                   shows: %{
 750                     reblog: true,
 751                     reply: true
 752                   }
 753                 },
 754                 notifications: %{
 755                   alerts: %{
 756                     follow: true,
 757                     favourite: true,
 758                     reblog: true,
 759                     mention: true
 760                   },
 761                   shows: %{
 762                     follow: true,
 763                     favourite: true,
 764                     reblog: true,
 765                     mention: true
 766                   },
 767                   sounds: %{
 768                     follow: true,
 769                     favourite: true,
 770                     reblog: true,
 771                     mention: true
 772                   }
 773                 }
 774               },
 775           push_subscription: nil,
 776           accounts: accounts,
 777           custom_emojis: mastodon_emoji,
 778           char_limit: Keyword.get(@instance, :limit)
 779         }
 780         |> Jason.encode!()
 781
 782       conn
 783       |> put_layout(false)
 784       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 785     else
 786       conn
 787       |> redirect(to: "/web/login")
 788     end
 789   end
 790
 791   def put_settings(%{assigns: %{user: user}} = conn, %{"data" => settings} = _params) do
 792     with new_info <- Map.put(user.info, "settings", settings),
 793          change <- User.info_changeset(user, %{info: new_info}),
 794          {:ok, _user} <- User.update_and_set_cache(change) do
 795       conn
 796       |> json(%{})
 797     else
 798       e ->
 799         conn
 800         |> json(%{error: inspect(e)})
 801     end
 802   end
 803
 804   def login(conn, _) do
 805     conn
 806     |> render(MastodonView, "login.html", %{error: false})
 807   end
 808
 809   defp get_or_make_app() do
 810     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 811       {:ok, app}
 812     else
 813       _e ->
 814         cs =
 815           App.register_changeset(%App{}, %{
 816             client_name: "Mastodon-Local",
 817             redirect_uris: ".",
 818             scopes: "read,write,follow"
 819           })
 820
 821         Repo.insert(cs)
 822     end
 823   end
 824
 825   def login_post(conn, %{"authorization" => %{"name" => name, "password" => password}}) do
 826     with %User{} = user <- User.get_by_nickname_or_email(name),
 827          true <- Pbkdf2.checkpw(password, user.password_hash),
 828          {:ok, app} <- get_or_make_app(),
 829          {:ok, auth} <- Authorization.create_authorization(app, user),
 830          {:ok, token} <- Token.exchange_token(app, auth) do
 831       conn
 832       |> put_session(:oauth_token, token.token)
 833       |> redirect(to: "/web/getting-started")
 834     else
 835       _e ->
 836         conn
 837         |> render(MastodonView, "login.html", %{error: "Wrong username or password"})
 838     end
 839   end
 840
 841   def logout(conn, _) do
 842     conn
 843     |> clear_session
 844     |> redirect(to: "/")
 845   end
 846
 847   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 848     Logger.debug("Unimplemented, returning unmodified relationship")
 849
 850     with %User{} = target <- Repo.get(User, id) do
 851       render(conn, AccountView, "relationship.json", %{user: user, target: target})
 852     end
 853   end
 854
 855   def empty_array(conn, _) do
 856     Logger.debug("Unimplemented, returning an empty array")
 857     json(conn, [])
 858   end
 859
 860   def empty_object(conn, _) do
 861     Logger.debug("Unimplemented, returning an empty object")
 862     json(conn, %{})
 863   end
 864
 865   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
 866     actor = User.get_cached_by_ap_id(activity.data["actor"])
 867
 868     created_at =
 869       NaiveDateTime.to_iso8601(created_at)
 870       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 871
 872     case activity.data["type"] do
 873       "Create" ->
 874         %{
 875           id: id,
 876           type: "mention",
 877           created_at: created_at,
 878           account: AccountView.render("account.json", %{user: actor}),
 879           status: StatusView.render("status.json", %{activity: activity, for: user})
 880         }
 881
 882       "Like" ->
 883         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 884
 885         %{
 886           id: id,
 887           type: "favourite",
 888           created_at: created_at,
 889           account: AccountView.render("account.json", %{user: actor}),
 890           status: StatusView.render("status.json", %{activity: liked_activity, for: user})
 891         }
 892
 893       "Announce" ->
 894         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 895
 896         %{
 897           id: id,
 898           type: "reblog",
 899           created_at: created_at,
 900           account: AccountView.render("account.json", %{user: actor}),
 901           status: StatusView.render("status.json", %{activity: announced_activity, for: user})
 902         }
 903
 904       "Follow" ->
 905         %{
 906           id: id,
 907           type: "follow",
 908           created_at: created_at,
 909           account: AccountView.render("account.json", %{user: actor})
 910         }
 911
 912       _ ->
 913         nil
 914     end
 915   end
 916 end