git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification, Stats}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView, ListView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.ActivityPub.Utils
   8   alias Pleroma.Web.{CommonAPI, OStatus}
   9   alias Pleroma.Web.OAuth.{Authorization, Token, App}
  10   alias Comeonin.Pbkdf2
  11   import Ecto.Query
  12   require Logger
  13
  14   action_fallback(:errors)
  15
  16   def create_app(conn, params) do
  17     with cs <- App.register_changeset(%App{}, params) |> IO.inspect(),
  18          {:ok, app} <- Repo.insert(cs) |> IO.inspect() do
  19       res = %{
  20         id: app.id,
  21         client_id: app.client_id,
  22         client_secret: app.client_secret
  23       }
  24
  25       json(conn, res)
  26     end
  27   end
  28
  29   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  30     original_user = user
  31
  32     params =
  33       if bio = params["note"] do
  34         Map.put(params, "bio", bio)
  35       else
  36         params
  37       end
  38
  39     params =
  40       if name = params["display_name"] do
  41         Map.put(params, "name", name)
  42       else
  43         params
  44       end
  45
  46     user =
  47       if avatar = params["avatar"] do
  48         with %Plug.Upload{} <- avatar,
  49              {:ok, object} <- ActivityPub.upload(avatar),
  50              change = Ecto.Changeset.change(user, %{avatar: object.data}),
  51              {:ok, user} = User.update_and_set_cache(change) do
  52           user
  53         else
  54           _e -> user
  55         end
  56       else
  57         user
  58       end
  59
  60     user =
  61       if banner = params["header"] do
  62         with %Plug.Upload{} <- banner,
  63              {:ok, object} <- ActivityPub.upload(banner),
  64              new_info <- Map.put(user.info, "banner", object.data),
  65              change <- User.info_changeset(user, %{info: new_info}),
  66              {:ok, user} <- User.update_and_set_cache(change) do
  67           user
  68         else
  69           _e -> user
  70         end
  71       else
  72         user
  73       end
  74
  75     with changeset <- User.update_changeset(user, params),
  76          {:ok, user} <- User.update_and_set_cache(changeset) do
  77       if original_user != user do
  78         CommonAPI.update(user)
  79       end
  80
  81       json(conn, AccountView.render("account.json", %{user: user}))
  82     else
  83       _e ->
  84         conn
  85         |> put_status(403)
  86         |> json(%{error: "Invalid request"})
  87     end
  88   end
  89
  90   def verify_credentials(%{assigns: %{user: user}} = conn, _) do
  91     account = AccountView.render("account.json", %{user: user})
  92     json(conn, account)
  93   end
  94
  95   def user(conn, %{"id" => id}) do
  96     with %User{} = user <- Repo.get(User, id) do
  97       account = AccountView.render("account.json", %{user: user})
  98       json(conn, account)
  99     else
 100       _e ->
 101         conn
 102         |> put_status(404)
 103         |> json(%{error: "Can't find user"})
 104     end
 105   end
 106
 107   @instance Application.get_env(:pleroma, :instance)
 108   @mastodon_api_level "2.3.3"
 109
 110   def masto_instance(conn, _params) do
 111     response = %{
 112       uri: Web.base_url(),
 113       title: Keyword.get(@instance, :name),
 114       description: "A Pleroma instance, an alternative fediverse server",
 115       version: "#{@mastodon_api_level} (compatible; #{Keyword.get(@instance, :version)})",
 116       email: Keyword.get(@instance, :email),
 117       urls: %{
 118         streaming_api: String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws")
 119       },
 120       stats: Stats.get_stats(),
 121       thumbnail: Web.base_url() <> "/instance/thumbnail.jpeg",
 122       max_toot_chars: Keyword.get(@instance, :limit)
 123     }
 124
 125     json(conn, response)
 126   end
 127
 128   def peers(conn, _params) do
 129     json(conn, Stats.get_peers())
 130   end
 131
 132   defp mastodonized_emoji do
 133     Pleroma.Formatter.get_custom_emoji()
 134     |> Enum.map(fn {shortcode, relative_url} ->
 135       url = to_string(URI.merge(Web.base_url(), relative_url))
 136
 137       %{
 138         "shortcode" => shortcode,
 139         "static_url" => url,
 140         "visible_in_picker" => true,
 141         "url" => url
 142       }
 143     end)
 144   end
 145
 146   def custom_emojis(conn, _params) do
 147     mastodon_emoji = mastodonized_emoji()
 148     json(conn, mastodon_emoji)
 149   end
 150
 151   defp add_link_headers(conn, method, activities, param \\ nil, params \\ %{}) do
 152     last = List.last(activities)
 153     first = List.first(activities)
 154
 155     if last do
 156       min = last.id
 157       max = first.id
 158
 159       {next_url, prev_url} =
 160         if param do
 161           {
 162             mastodon_api_url(
 163               Pleroma.Web.Endpoint,
 164               method,
 165               param,
 166               Map.merge(params, %{max_id: min})
 167             ),
 168             mastodon_api_url(
 169               Pleroma.Web.Endpoint,
 170               method,
 171               param,
 172               Map.merge(params, %{since_id: max})
 173             )
 174           }
 175         else
 176           {
 177             mastodon_api_url(
 178               Pleroma.Web.Endpoint,
 179               method,
 180               Map.merge(params, %{max_id: min})
 181             ),
 182             mastodon_api_url(
 183               Pleroma.Web.Endpoint,
 184               method,
 185               Map.merge(params, %{since_id: max})
 186             )
 187           }
 188         end
 189
 190       conn
 191       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 192     else
 193       conn
 194     end
 195   end
 196
 197   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 198     params =
 199       params
 200       |> Map.put("type", ["Create", "Announce"])
 201       |> Map.put("blocking_user", user)
 202       |> Map.put("user", user)
 203
 204     activities =
 205       ActivityPub.fetch_activities([user.ap_id | user.following], params)
 206       |> Enum.reverse()
 207
 208     conn
 209     |> add_link_headers(:home_timeline, activities)
 210     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 211   end
 212
 213   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 214     local_only = params["local"] in [true, "True", "true", "1"]
 215
 216     params =
 217       params
 218       |> Map.put("type", ["Create", "Announce"])
 219       |> Map.put("local_only", local_only)
 220       |> Map.put("blocking_user", user)
 221
 222     activities =
 223       ActivityPub.fetch_public_activities(params)
 224       |> Enum.reverse()
 225
 226     conn
 227     |> add_link_headers(:public_timeline, activities, false, %{"local" => local_only})
 228     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 229   end
 230
 231   def user_statuses(%{assigns: %{user: reading_user}} = conn, params) do
 232     with %User{} = user <- Repo.get(User, params["id"]) do
 233       # Since Pleroma has no "pinned" posts feature, we'll just set an empty list here
 234       activities =
 235         if params["pinned"] == "true" do
 236           []
 237         else
 238           ActivityPub.fetch_user_activities(user, reading_user, params)
 239         end
 240
 241       conn
 242       |> add_link_headers(:user_statuses, activities, params["id"])
 243       |> render(StatusView, "index.json", %{
 244         activities: activities,
 245         for: reading_user,
 246         as: :activity
 247       })
 248     end
 249   end
 250
 251   def dm_timeline(%{assigns: %{user: user}} = conn, _params) do
 252     query =
 253       ActivityPub.fetch_activities_query([user.ap_id], %{"type" => "Create", visibility: "direct"})
 254
 255     activities = Repo.all(query)
 256
 257     conn
 258     |> add_link_headers(:dm_timeline, activities)
 259     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 260   end
 261
 262   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 263     with %Activity{} = activity <- Repo.get(Activity, id),
 264          true <- ActivityPub.visible_for_user?(activity, user) do
 265       render(conn, StatusView, "status.json", %{activity: activity, for: user})
 266     end
 267   end
 268
 269   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 270     with %Activity{} = activity <- Repo.get(Activity, id),
 271          activities <-
 272            ActivityPub.fetch_activities_for_context(activity.data["context"], %{
 273              "blocking_user" => user,
 274              "user" => user
 275            }),
 276          activities <-
 277            activities |> Enum.filter(fn %{id: aid} -> to_string(aid) != to_string(id) end),
 278          activities <-
 279            activities |> Enum.filter(fn %{data: %{"type" => type}} -> type == "Create" end),
 280          grouped_activities <- Enum.group_by(activities, fn %{id: id} -> id < activity.id end) do
 281       result = %{
 282         ancestors:
 283           StatusView.render(
 284             "index.json",
 285             for: user,
 286             activities: grouped_activities[true] || [],
 287             as: :activity
 288           )
 289           |> Enum.reverse(),
 290         descendants:
 291           StatusView.render(
 292             "index.json",
 293             for: user,
 294             activities: grouped_activities[false] || [],
 295             as: :activity
 296           )
 297           |> Enum.reverse()
 298       }
 299
 300       json(conn, result)
 301     end
 302   end
 303
 304   def post_status(conn, %{"status" => "", "media_ids" => media_ids} = params)
 305       when length(media_ids) > 0 do
 306     params =
 307       params
 308       |> Map.put("status", ".")
 309
 310     post_status(conn, params)
 311   end
 312
 313   def post_status(%{assigns: %{user: user}} = conn, %{"status" => _} = params) do
 314     params =
 315       params
 316       |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 317       |> Map.put("no_attachment_links", true)
 318
 319     idempotency_key =
 320       case get_req_header(conn, "idempotency-key") do
 321         [key] -> key
 322         _ -> Ecto.UUID.generate()
 323       end
 324
 325     {:ok, activity} =
 326       Cachex.fetch!(:idempotency_cache, idempotency_key, fn _ -> CommonAPI.post(user, params) end)
 327
 328     render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 329   end
 330
 331   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 332     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 333       json(conn, %{})
 334     else
 335       _e ->
 336         conn
 337         |> put_status(403)
 338         |> json(%{error: "Can't delete this post"})
 339     end
 340   end
 341
 342   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 343     with {:ok, announce, _activity} <- CommonAPI.repeat(ap_id_or_id, user) do
 344       render(conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity})
 345     end
 346   end
 347
 348   def unreblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 349     with {:ok, _, _, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
 350          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 351       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 352     end
 353   end
 354
 355   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 356     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
 357          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 358       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 359     end
 360   end
 361
 362   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 363     with {:ok, _, _, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
 364          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 365       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 366     end
 367   end
 368
 369   def notifications(%{assigns: %{user: user}} = conn, params) do
 370     notifications = Notification.for_user(user, params)
 371
 372     result =
 373       Enum.map(notifications, fn x ->
 374         render_notification(user, x)
 375       end)
 376       |> Enum.filter(& &1)
 377
 378     conn
 379     |> add_link_headers(:notifications, notifications)
 380     |> json(result)
 381   end
 382
 383   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 384     with {:ok, notification} <- Notification.get(user, id) do
 385       json(conn, render_notification(user, notification))
 386     else
 387       {:error, reason} ->
 388         conn
 389         |> put_resp_content_type("application/json")
 390         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 391     end
 392   end
 393
 394   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 395     Notification.clear(user)
 396     json(conn, %{})
 397   end
 398
 399   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 400     with {:ok, _notif} <- Notification.dismiss(user, id) do
 401       json(conn, %{})
 402     else
 403       {:error, reason} ->
 404         conn
 405         |> put_resp_content_type("application/json")
 406         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 407     end
 408   end
 409
 410   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 411     id = List.wrap(id)
 412     q = from(u in User, where: u.id in ^id)
 413     targets = Repo.all(q)
 414     render(conn, AccountView, "relationships.json", %{user: user, targets: targets})
 415   end
 416
 417   def upload(%{assigns: %{user: _}} = conn, %{"file" => file}) do
 418     with {:ok, object} <- ActivityPub.upload(file) do
 419       data =
 420         object.data
 421         |> Map.put("id", object.id)
 422
 423       render(conn, StatusView, "attachment.json", %{attachment: data})
 424     end
 425   end
 426
 427   def favourited_by(conn, %{"id" => id}) do
 428     with %Activity{data: %{"object" => %{"likes" => likes}}} <- Repo.get(Activity, id) do
 429       q = from(u in User, where: u.ap_id in ^likes)
 430       users = Repo.all(q)
 431       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 432     else
 433       _ -> json(conn, [])
 434     end
 435   end
 436
 437   def reblogged_by(conn, %{"id" => id}) do
 438     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 439       q = from(u in User, where: u.ap_id in ^announces)
 440       users = Repo.all(q)
 441       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 442     else
 443       _ -> json(conn, [])
 444     end
 445   end
 446
 447   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 448     local_only = params["local"] in [true, "True", "true", "1"]
 449
 450     params =
 451       params
 452       |> Map.put("type", "Create")
 453       |> Map.put("local_only", local_only)
 454       |> Map.put("blocking_user", user)
 455
 456     activities =
 457       ActivityPub.fetch_public_activities(params)
 458       |> Enum.reverse()
 459
 460     conn
 461     |> add_link_headers(:hashtag_timeline, activities, params["tag"], %{"local" => local_only})
 462     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 463   end
 464
 465   # TODO: Pagination
 466   def followers(conn, %{"id" => id}) do
 467     with %User{} = user <- Repo.get(User, id),
 468          {:ok, followers} <- User.get_followers(user) do
 469       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 470     end
 471   end
 472
 473   def following(conn, %{"id" => id}) do
 474     with %User{} = user <- Repo.get(User, id),
 475          {:ok, followers} <- User.get_friends(user) do
 476       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 477     end
 478   end
 479
 480   def follow_requests(%{assigns: %{user: followed}} = conn, _params) do
 481     with {:ok, follow_requests} <- User.get_follow_requests(followed) do
 482       render(conn, AccountView, "accounts.json", %{users: follow_requests, as: :user})
 483     end
 484   end
 485
 486   def authorize_follow_request(%{assigns: %{user: followed}} = conn, %{"id" => id}) do
 487     with %User{} = follower <- Repo.get(User, id),
 488          {:ok, follower} <- User.follow(follower, followed),
 489          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 490          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 491          {:ok, _activity} <-
 492            ActivityPub.accept(%{
 493              to: [follower.ap_id],
 494              actor: followed.ap_id,
 495              object: follow_activity.data["id"],
 496              type: "Accept"
 497            }) do
 498       render(conn, AccountView, "relationship.json", %{user: followed, target: follower})
 499     else
 500       {:error, message} ->
 501         conn
 502         |> put_resp_content_type("application/json")
 503         |> send_resp(403, Jason.encode!(%{"error" => message}))
 504     end
 505   end
 506
 507   def reject_follow_request(%{assigns: %{user: followed}} = conn, %{"id" => id}) do
 508     with %User{} = follower <- Repo.get(User, id),
 509          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 510          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 511          {:ok, _activity} <-
 512            ActivityPub.reject(%{
 513              to: [follower.ap_id],
 514              actor: followed.ap_id,
 515              object: follow_activity.data["id"],
 516              type: "Reject"
 517            }) do
 518       render(conn, AccountView, "relationship.json", %{user: followed, target: follower})
 519     else
 520       {:error, message} ->
 521         conn
 522         |> put_resp_content_type("application/json")
 523         |> send_resp(403, Jason.encode!(%{"error" => message}))
 524     end
 525   end
 526
 527   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 528     with %User{} = followed <- Repo.get(User, id),
 529          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 530          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 531       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 532     else
 533       {:error, message} ->
 534         conn
 535         |> put_resp_content_type("application/json")
 536         |> send_resp(403, Jason.encode!(%{"error" => message}))
 537     end
 538   end
 539
 540   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 541     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 542          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 543          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 544       render(conn, AccountView, "account.json", %{user: followed})
 545     else
 546       {:error, message} ->
 547         conn
 548         |> put_resp_content_type("application/json")
 549         |> send_resp(403, Jason.encode!(%{"error" => message}))
 550     end
 551   end
 552
 553   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 554     with %User{} = followed <- Repo.get(User, id),
 555          {:ok, _activity} <- ActivityPub.unfollow(follower, followed),
 556          {:ok, follower, _} <- User.unfollow(follower, followed) do
 557       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 558     end
 559   end
 560
 561   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 562     with %User{} = blocked <- Repo.get(User, id),
 563          {:ok, blocker} <- User.block(blocker, blocked),
 564          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
 565       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 566     else
 567       {:error, message} ->
 568         conn
 569         |> put_resp_content_type("application/json")
 570         |> send_resp(403, Jason.encode!(%{"error" => message}))
 571     end
 572   end
 573
 574   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 575     with %User{} = blocked <- Repo.get(User, id),
 576          {:ok, blocker} <- User.unblock(blocker, blocked),
 577          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
 578       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 579     else
 580       {:error, message} ->
 581         conn
 582         |> put_resp_content_type("application/json")
 583         |> send_resp(403, Jason.encode!(%{"error" => message}))
 584     end
 585   end
 586
 587   # TODO: Use proper query
 588   def blocks(%{assigns: %{user: user}} = conn, _) do
 589     with blocked_users <- user.info["blocks"] || [],
 590          accounts <- Enum.map(blocked_users, fn ap_id -> User.get_cached_by_ap_id(ap_id) end) do
 591       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 592       json(conn, res)
 593     end
 594   end
 595
 596   def domain_blocks(%{assigns: %{user: %{info: info}}} = conn, _) do
 597     json(conn, info["domain_blocks"] || [])
 598   end
 599
 600   def block_domain(%{assigns: %{user: blocker}} = conn, %{"domain" => domain}) do
 601     User.block_domain(blocker, domain)
 602     json(conn, %{})
 603   end
 604
 605   def unblock_domain(%{assigns: %{user: blocker}} = conn, %{"domain" => domain}) do
 606     User.unblock_domain(blocker, domain)
 607     json(conn, %{})
 608   end
 609
 610   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 611     accounts = User.search(query, params["resolve"] == "true")
 612
 613     fetched =
 614       if Regex.match?(~r/https?:/, query) do
 615         with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 616           activities
 617           |> Enum.filter(fn
 618             %{data: %{"type" => "Create"}} -> true
 619             _ -> false
 620           end)
 621         else
 622           _e -> []
 623         end
 624       end || []
 625
 626     q =
 627       from(
 628         a in Activity,
 629         where: fragment("?->>'type' = 'Create'", a.data),
 630         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 631         where:
 632           fragment(
 633             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 634             a.data,
 635             ^query
 636           ),
 637         limit: 20,
 638         order_by: [desc: :id]
 639       )
 640
 641     statuses = Repo.all(q) ++ fetched
 642
 643     tags =
 644       String.split(query)
 645       |> Enum.uniq()
 646       |> Enum.filter(fn tag -> String.starts_with?(tag, "#") end)
 647       |> Enum.map(fn tag -> String.slice(tag, 1..-1) end)
 648
 649     res = %{
 650       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 651       "statuses" =>
 652         StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 653       "hashtags" => tags
 654     }
 655
 656     json(conn, res)
 657   end
 658
 659   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 660     accounts = User.search(query, params["resolve"] == "true")
 661
 662     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 663
 664     json(conn, res)
 665   end
 666
 667   def favourites(%{assigns: %{user: user}} = conn, _) do
 668     params =
 669       %{}
 670       |> Map.put("type", "Create")
 671       |> Map.put("favorited_by", user.ap_id)
 672       |> Map.put("blocking_user", user)
 673
 674     activities =
 675       ActivityPub.fetch_public_activities(params)
 676       |> Enum.reverse()
 677
 678     conn
 679     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 680   end
 681
 682   def get_lists(%{assigns: %{user: user}} = conn, opts) do
 683     lists = Pleroma.List.for_user(user, opts)
 684     res = ListView.render("lists.json", lists: lists)
 685     json(conn, res)
 686   end
 687
 688   def get_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 689     with %Pleroma.List{} = list <- Pleroma.List.get(id, user) do
 690       res = ListView.render("list.json", list: list)
 691       json(conn, res)
 692     else
 693       _e -> json(conn, "error")
 694     end
 695   end
 696
 697   def delete_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 698     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 699          {:ok, _list} <- Pleroma.List.delete(list) do
 700       json(conn, %{})
 701     else
 702       _e ->
 703         json(conn, "error")
 704     end
 705   end
 706
 707   def create_list(%{assigns: %{user: user}} = conn, %{"title" => title}) do
 708     with {:ok, %Pleroma.List{} = list} <- Pleroma.List.create(title, user) do
 709       res = ListView.render("list.json", list: list)
 710       json(conn, res)
 711     end
 712   end
 713
 714   def add_to_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 715     accounts
 716     |> Enum.each(fn account_id ->
 717       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 718            %User{} = followed <- Repo.get(User, account_id) do
 719         Pleroma.List.follow(list, followed)
 720       end
 721     end)
 722
 723     json(conn, %{})
 724   end
 725
 726   def remove_from_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 727     accounts
 728     |> Enum.each(fn account_id ->
 729       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 730            %User{} = followed <- Repo.get(Pleroma.User, account_id) do
 731         Pleroma.List.unfollow(list, followed)
 732       end
 733     end)
 734
 735     json(conn, %{})
 736   end
 737
 738   def list_accounts(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 739     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 740          {:ok, users} = Pleroma.List.get_following(list) do
 741       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 742     end
 743   end
 744
 745   def rename_list(%{assigns: %{user: user}} = conn, %{"id" => id, "title" => title}) do
 746     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 747          {:ok, list} <- Pleroma.List.rename(list, title) do
 748       res = ListView.render("list.json", list: list)
 749       json(conn, res)
 750     else
 751       _e ->
 752         json(conn, "error")
 753     end
 754   end
 755
 756   def list_timeline(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 757     with %Pleroma.List{title: title, following: following} <- Pleroma.List.get(id, user) do
 758       params =
 759         params
 760         |> Map.put("type", "Create")
 761         |> Map.put("blocking_user", user)
 762
 763       # adding title is a hack to not make empty lists function like a public timeline
 764       activities =
 765         ActivityPub.fetch_activities([title | following], params)
 766         |> Enum.reverse()
 767
 768       conn
 769       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 770     else
 771       _e ->
 772         conn
 773         |> put_status(403)
 774         |> json(%{error: "Error."})
 775     end
 776   end
 777
 778   def index(%{assigns: %{user: user}} = conn, _params) do
 779     token =
 780       conn
 781       |> get_session(:oauth_token)
 782
 783     if user && token do
 784       mastodon_emoji = mastodonized_emoji()
 785       accounts = Map.put(%{}, user.id, AccountView.render("account.json", %{user: user}))
 786
 787       initial_state =
 788         %{
 789           meta: %{
 790             streaming_api_base_url:
 791               String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 792             access_token: token,
 793             locale: "en",
 794             domain: Pleroma.Web.Endpoint.host(),
 795             admin: "1",
 796             me: "#{user.id}",
 797             unfollow_modal: false,
 798             boost_modal: false,
 799             delete_modal: true,
 800             auto_play_gif: false,
 801             reduce_motion: false
 802           },
 803           compose: %{
 804             me: "#{user.id}",
 805             default_privacy: "public",
 806             default_sensitive: false
 807           },
 808           media_attachments: %{
 809             accept_content_types: [
 810               ".jpg",
 811               ".jpeg",
 812               ".png",
 813               ".gif",
 814               ".webm",
 815               ".mp4",
 816               ".m4v",
 817               "image\/jpeg",
 818               "image\/png",
 819               "image\/gif",
 820               "video\/webm",
 821               "video\/mp4"
 822             ]
 823           },
 824           settings:
 825             Map.get(user.info, "settings") ||
 826               %{
 827                 onboarded: true,
 828                 home: %{
 829                   shows: %{
 830                     reblog: true,
 831                     reply: true
 832                   }
 833                 },
 834                 notifications: %{
 835                   alerts: %{
 836                     follow: true,
 837                     favourite: true,
 838                     reblog: true,
 839                     mention: true
 840                   },
 841                   shows: %{
 842                     follow: true,
 843                     favourite: true,
 844                     reblog: true,
 845                     mention: true
 846                   },
 847                   sounds: %{
 848                     follow: true,
 849                     favourite: true,
 850                     reblog: true,
 851                     mention: true
 852                   }
 853                 }
 854               },
 855           push_subscription: nil,
 856           accounts: accounts,
 857           custom_emojis: mastodon_emoji,
 858           char_limit: Keyword.get(@instance, :limit)
 859         }
 860         |> Jason.encode!()
 861
 862       conn
 863       |> put_layout(false)
 864       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 865     else
 866       conn
 867       |> redirect(to: "/web/login")
 868     end
 869   end
 870
 871   def put_settings(%{assigns: %{user: user}} = conn, %{"data" => settings} = _params) do
 872     with new_info <- Map.put(user.info, "settings", settings),
 873          change <- User.info_changeset(user, %{info: new_info}),
 874          {:ok, _user} <- User.update_and_set_cache(change) do
 875       conn
 876       |> json(%{})
 877     else
 878       e ->
 879         conn
 880         |> json(%{error: inspect(e)})
 881     end
 882   end
 883
 884   def login(conn, _) do
 885     conn
 886     |> render(MastodonView, "login.html", %{error: false})
 887   end
 888
 889   defp get_or_make_app() do
 890     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 891       {:ok, app}
 892     else
 893       _e ->
 894         cs =
 895           App.register_changeset(%App{}, %{
 896             client_name: "Mastodon-Local",
 897             redirect_uris: ".",
 898             scopes: "read,write,follow"
 899           })
 900
 901         Repo.insert(cs)
 902     end
 903   end
 904
 905   def login_post(conn, %{"authorization" => %{"name" => name, "password" => password}}) do
 906     with %User{} = user <- User.get_by_nickname_or_email(name),
 907          true <- Pbkdf2.checkpw(password, user.password_hash),
 908          {:ok, app} <- get_or_make_app(),
 909          {:ok, auth} <- Authorization.create_authorization(app, user),
 910          {:ok, token} <- Token.exchange_token(app, auth) do
 911       conn
 912       |> put_session(:oauth_token, token.token)
 913       |> redirect(to: "/web/getting-started")
 914     else
 915       _e ->
 916         conn
 917         |> render(MastodonView, "login.html", %{error: "Wrong username or password"})
 918     end
 919   end
 920
 921   def logout(conn, _) do
 922     conn
 923     |> clear_session
 924     |> redirect(to: "/")
 925   end
 926
 927   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 928     Logger.debug("Unimplemented, returning unmodified relationship")
 929
 930     with %User{} = target <- Repo.get(User, id) do
 931       render(conn, AccountView, "relationship.json", %{user: user, target: target})
 932     end
 933   end
 934
 935   def empty_array(conn, _) do
 936     Logger.debug("Unimplemented, returning an empty array")
 937     json(conn, [])
 938   end
 939
 940   def empty_object(conn, _) do
 941     Logger.debug("Unimplemented, returning an empty object")
 942     json(conn, %{})
 943   end
 944
 945   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
 946     actor = User.get_cached_by_ap_id(activity.data["actor"])
 947
 948     created_at =
 949       NaiveDateTime.to_iso8601(created_at)
 950       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 951
 952     case activity.data["type"] do
 953       "Create" ->
 954         %{
 955           id: id,
 956           type: "mention",
 957           created_at: created_at,
 958           account: AccountView.render("account.json", %{user: actor}),
 959           status: StatusView.render("status.json", %{activity: activity, for: user})
 960         }
 961
 962       "Like" ->
 963         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 964
 965         %{
 966           id: id,
 967           type: "favourite",
 968           created_at: created_at,
 969           account: AccountView.render("account.json", %{user: actor}),
 970           status: StatusView.render("status.json", %{activity: liked_activity, for: user})
 971         }
 972
 973       "Announce" ->
 974         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 975
 976         %{
 977           id: id,
 978           type: "reblog",
 979           created_at: created_at,
 980           account: AccountView.render("account.json", %{user: actor}),
 981           status: StatusView.render("status.json", %{activity: announced_activity, for: user})
 982         }
 983
 984       "Follow" ->
 985         %{
 986           id: id,
 987           type: "follow",
 988           created_at: created_at,
 989           account: AccountView.render("account.json", %{user: actor})
 990         }
 991
 992       _ ->
 993         nil
 994     end
 995   end
 996
 997   def errors(conn, _) do
 998     conn
 999     |> put_status(500)
1000     |> json("Something went wrong")
1001   end
1002 end