git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.TwitterAPI.TwitterAPI
   8   alias Pleroma.Web.{CommonAPI, OStatus}
   9   alias Pleroma.Web.OAuth.{Authorization, Token, App}
  10   alias Comeonin.Pbkdf2
  11   import Ecto.Query
  12   import Logger
  13
  14   def create_app(conn, params) do
  15     with cs <- App.register_changeset(%App{}, params) |> IO.inspect,
  16          {:ok, app} <- Repo.insert(cs) |> IO.inspect do
  17       res = %{
  18         id: app.id,
  19         client_id: app.client_id,
  20         client_secret: app.client_secret
  21       }
  22
  23       json(conn, res)
  24     end
  25   end
  26
  27   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  28     params = if bio = params["note"] do
  29       Map.put(params, "bio", bio)
  30     else
  31       params
  32     end
  33
  34     params = if name = params["display_name"] do
  35       Map.put(params, "name", name)
  36     else
  37       params
  38     end
  39
  40     user = if avatar = params["avatar"] do
  41       with %Plug.Upload{} <- avatar,
  42            {:ok, object} <- ActivityPub.upload(avatar),
  43            change = Ecto.Changeset.change(user, %{avatar: object.data}),
  44            {:ok, user} = Repo.update(change) do
  45         user
  46       else
  47         _e -> user
  48       end
  49     else
  50       user
  51     end
  52
  53     user = if banner = params["header"] do
  54       with %Plug.Upload{} <- banner,
  55            {:ok, object} <- ActivityPub.upload(banner),
  56            new_info <- Map.put(user.info, "banner", object.data),
  57            change <- User.info_changeset(user, %{info: new_info}),
  58            {:ok, user} <- Repo.update(change) do
  59         user
  60       else
  61         _e -> user
  62       end
  63     else
  64       user
  65     end
  66
  67     with changeset <- User.update_changeset(user, params),
  68          {:ok, user} <- Repo.update(changeset) do
  69       json conn, AccountView.render("account.json", %{user: user})
  70     else
  71       _e ->
  72         conn
  73         |> put_status(403)
  74         |> json(%{error: "Invalid request"})
  75     end
  76   end
  77
  78   def verify_credentials(%{assigns: %{user: user}} = conn, params) do
  79     account = AccountView.render("account.json", %{user: user})
  80     json(conn, account)
  81   end
  82
  83   def user(conn, %{"id" => id}) do
  84     with %User{} = user <- Repo.get(User, id) do
  85       account = AccountView.render("account.json", %{user: user})
  86       json(conn, account)
  87     else
  88       _e -> conn
  89       |> put_status(404)
  90       |> json(%{error: "Can't find user"})
  91     end
  92   end
  93
  94   @instance Application.get_env(:pleroma, :instance)
  95
  96   def masto_instance(conn, _params) do
  97     response = %{
  98       uri: Web.base_url,
  99       title: Keyword.get(@instance, :name),
 100       description: "A Pleroma instance, an alternative fediverse server",
 101       version: Keyword.get(@instance, :version),
 102       email: Keyword.get(@instance, :email),
 103       urls: %{
 104         streaming_api: String.replace(Web.base_url, ["http","https"], "wss")
 105       },
 106       stats: %{
 107         user_count: 1,
 108         status_count: 2,
 109         domain_count: 3
 110       }
 111     }
 112
 113     json(conn, response)
 114   end
 115
 116   defp mastodonized_emoji do
 117     Pleroma.Formatter.get_custom_emoji()
 118     |> Enum.map(fn {shortcode, relative_url} ->
 119       url = to_string URI.merge(Web.base_url(), relative_url)
 120       %{
 121         "shortcode" => shortcode,
 122         "static_url" => url,
 123         "url" => url
 124       }
 125     end)
 126   end
 127
 128   def custom_emojis(conn, _params) do
 129     mastodon_emoji = mastodonized_emoji()
 130     json conn, mastodon_emoji
 131   end
 132
 133   defp add_link_headers(conn, method, activities) do
 134     last = List.last(activities)
 135     first = List.first(activities)
 136     if last do
 137       min = last.id
 138       max = first.id
 139       next_url = mastodon_api_url(Pleroma.Web.Endpoint, method, max_id: min)
 140       prev_url = mastodon_api_url(Pleroma.Web.Endpoint, method, since_id: max)
 141       conn
 142       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 143     else
 144       conn
 145     end
 146   end
 147
 148   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 149     params = params
 150     |> Map.put("type", ["Create", "Announce"])
 151     |> Map.put("blocking_user", user)
 152
 153     activities = ActivityPub.fetch_activities([user.ap_id | user.following], params)
 154     |> Enum.reverse
 155
 156     conn
 157     |> add_link_headers(:home_timeline, activities)
 158     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 159   end
 160
 161   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 162     params = params
 163     |> Map.put("type", ["Create", "Announce"])
 164     |> Map.put("local_only", !!params["local"])
 165     |> Map.put("blocking_user", user)
 166
 167     activities = ActivityPub.fetch_public_activities(params)
 168     |> Enum.reverse
 169
 170     conn
 171     |> add_link_headers(:public_timeline, activities)
 172     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 173   end
 174
 175   # TODO: Link headers
 176   def user_statuses(%{assigns: %{user: user}} = conn, params) do
 177     with %User{ap_id: ap_id} <- Repo.get(User, params["id"]) do
 178       params = params
 179       |> Map.put("type", ["Create", "Announce"])
 180       |> Map.put("actor_id", ap_id)
 181       |> Map.put("whole_db", true)
 182
 183       activities = ActivityPub.fetch_activities([], params)
 184       |> Enum.reverse
 185
 186       render conn, StatusView, "index.json", %{activities: activities, for: user, as: :activity}
 187     end
 188   end
 189
 190   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 191     with %Activity{} = activity <- Repo.get(Activity, id) do
 192       render conn, StatusView, "status.json", %{activity: activity, for: user}
 193     end
 194   end
 195
 196   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 197     with %Activity{} = activity <- Repo.get(Activity, id),
 198          activities <- ActivityPub.fetch_activities_for_context(activity.data["object"]["context"], %{"blocking_user" => user}),
 199          activities <- activities |> Enum.filter(fn (%{id: aid}) -> to_string(aid) != to_string(id) end),
 200          grouped_activities <- Enum.group_by(activities, fn (%{id: id}) -> id < activity.id end) do
 201       result = %{
 202         ancestors: StatusView.render("index.json", for: user, activities: grouped_activities[true] || [], as: :activity) |> Enum.reverse,
 203         descendants: StatusView.render("index.json", for: user, activities: grouped_activities[false] || [], as: :activity) |> Enum.reverse,
 204       }
 205
 206       json(conn, result)
 207     end
 208   end
 209
 210   def post_status(%{assigns: %{user: user}} = conn, %{"status" => status} = params) do
 211     params = params
 212     |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 213
 214     {:ok, activity} = CommonAPI.post(user, params)
 215     render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 216   end
 217
 218   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 219     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 220       json(conn, %{})
 221     else
 222       _e ->
 223         conn
 224         |> put_status(403)
 225         |> json(%{error: "Can't delete this post"})
 226     end
 227   end
 228
 229   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 230     with {:ok, announce, _activity} = CommonAPI.repeat(ap_id_or_id, user) do
 231       render conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity}
 232     end
 233   end
 234
 235   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 236     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 237          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 238       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 239     end
 240   end
 241
 242   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 243     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 244          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 245       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 246     end
 247   end
 248
 249   def notifications(%{assigns: %{user: user}} = conn, params) do
 250     notifications = Notification.for_user(user, params)
 251     result = Enum.map(notifications, fn x ->
 252       render_notification(user, x)
 253     end)
 254     |> Enum.filter(&(&1))
 255
 256     conn
 257     |> add_link_headers(:notifications, notifications)
 258     |> json(result)
 259   end
 260
 261   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 262     with {:ok, notification} <- Notification.get(user, id) do
 263       json(conn, render_notification(user, notification))
 264     else
 265       {:error, reason} ->
 266         conn
 267         |> put_resp_content_type("application/json")
 268         |> send_resp(403, Poison.encode!(%{"error" => reason}))
 269     end
 270   end
 271
 272   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 273     Notification.clear(user)
 274     json(conn, %{})
 275   end
 276
 277   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 278     with {:ok, _notif} <- Notification.dismiss(user, id) do
 279       json(conn, %{})
 280     else
 281       {:error, reason} ->
 282         conn
 283         |> put_resp_content_type("application/json")
 284         |> send_resp(403, Poison.encode!(%{"error" => reason}))
 285     end
 286   end
 287
 288   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 289     id = List.wrap(id)
 290     q = from u in User,
 291       where: u.id in ^id
 292     targets = Repo.all(q)
 293     render conn, AccountView, "relationships.json", %{user: user, targets: targets}
 294   end
 295
 296   def upload(%{assigns: %{user: user}} = conn, %{"file" => file}) do
 297     with {:ok, object} <- ActivityPub.upload(file) do
 298       data = object.data
 299       |> Map.put("id", object.id)
 300
 301       render conn, StatusView, "attachment.json", %{attachment: data}
 302     end
 303   end
 304
 305   def favourited_by(conn, %{"id" => id}) do
 306     with %Activity{data: %{"object" => %{"likes" => likes} = data}} <- Repo.get(Activity, id) do
 307       q = from u in User,
 308         where: u.ap_id in ^likes
 309       users = Repo.all(q)
 310       render conn, AccountView, "accounts.json", %{users: users, as: :user}
 311     else
 312       _ -> json(conn, [])
 313     end
 314   end
 315
 316   def reblogged_by(conn, %{"id" => id}) do
 317     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 318       q = from u in User,
 319         where: u.ap_id in ^announces
 320       users = Repo.all(q)
 321       render conn, AccountView, "accounts.json", %{users: users, as: :user}
 322     else
 323       _ -> json(conn, [])
 324     end
 325   end
 326
 327   # TODO: Link headers
 328   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 329     params = params
 330     |> Map.put("type", "Create")
 331     |> Map.put("local_only", !!params["local"])
 332     |> Map.put("blocking_user", user)
 333
 334     activities = ActivityPub.fetch_public_activities(params)
 335     |> Enum.reverse
 336
 337     conn
 338     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 339   end
 340
 341   # TODO: Pagination
 342   def followers(conn, %{"id" => id}) do
 343     with %User{} = user <- Repo.get(User, id),
 344          {:ok, followers} <- User.get_followers(user) do
 345       render conn, AccountView, "accounts.json", %{users: followers, as: :user}
 346     end
 347   end
 348
 349   def following(conn, %{"id" => id}) do
 350     with %User{} = user <- Repo.get(User, id),
 351          {:ok, followers} <- User.get_friends(user) do
 352       render conn, AccountView, "accounts.json", %{users: followers, as: :user}
 353     end
 354   end
 355
 356   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 357     with %User{} = followed <- Repo.get(User, id),
 358          {:ok, follower} <- User.follow(follower, followed),
 359          {:ok, activity} <- ActivityPub.follow(follower, followed) do
 360       render conn, AccountView, "relationship.json", %{user: follower, target: followed}
 361     else
 362       {:error, message} = err ->
 363         conn
 364         |> put_resp_content_type("application/json")
 365         |> send_resp(403, Poison.encode!(%{"error" => message}))
 366     end
 367   end
 368
 369   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 370     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 371          {:ok, follower} <- User.follow(follower, followed),
 372          {:ok, activity} <- ActivityPub.follow(follower, followed) do
 373       render conn, AccountView, "account.json", %{user: followed}
 374     else
 375       {:error, message} = err ->
 376         conn
 377         |> put_resp_content_type("application/json")
 378         |> send_resp(403, Poison.encode!(%{"error" => message}))
 379     end
 380   end
 381
 382   # TODO: Clean up and unify
 383   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 384     with %User{} = followed <- Repo.get(User, id),
 385          { :ok, follower, follow_activity } <- User.unfollow(follower, followed),
 386          { :ok, _activity } <- ActivityPub.insert(%{
 387            "type" => "Undo",
 388            "actor" => follower.ap_id,
 389            "object" => follow_activity.data["id"] # get latest Follow for these users
 390          }) do
 391       render conn, AccountView, "relationship.json", %{user: follower, target: followed}
 392     end
 393   end
 394
 395   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 396     with %User{} = blocked <- Repo.get(User, id),
 397          {:ok, blocker} <- User.block(blocker, blocked) do
 398       render conn, AccountView, "relationship.json", %{user: blocker, target: blocked}
 399     else
 400       {:error, message} = err ->
 401         conn
 402         |> put_resp_content_type("application/json")
 403         |> send_resp(403, Poison.encode!(%{"error" => message}))
 404     end
 405   end
 406
 407   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 408     with %User{} = blocked <- Repo.get(User, id),
 409          {:ok, blocker} <- User.unblock(blocker, blocked) do
 410       render conn, AccountView, "relationship.json", %{user: blocker, target: blocked}
 411     else
 412       {:error, message} = err ->
 413         conn
 414         |> put_resp_content_type("application/json")
 415         |> send_resp(403, Poison.encode!(%{"error" => message}))
 416     end
 417   end
 418
 419   # TODO: Use proper query
 420   def blocks(%{assigns: %{user: user}} = conn, _) do
 421     with blocked_users <- user.info["blocks"] || [],
 422          accounts <- Enum.map(blocked_users, fn (ap_id) -> User.get_cached_by_ap_id(ap_id) end) do
 423       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 424       json(conn, res)
 425     end
 426   end
 427
 428   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 429     accounts = User.search(query, params["resolve"] == "true")
 430
 431     fetched = if Regex.match?(~r/https?:/, query) do
 432       with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 433         activities
 434       else
 435         _e -> []
 436       end
 437     end || []
 438
 439     q = from a in Activity,
 440       where: fragment("?->>'type' = 'Create'", a.data),
 441       where: fragment("to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)", a.data, ^query),
 442       limit: 20
 443     statuses = Repo.all(q) ++ fetched
 444
 445     res = %{
 446       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 447       "statuses" => StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 448       "hashtags" => []
 449     }
 450
 451     json(conn, res)
 452   end
 453
 454   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 455     accounts = User.search(query, params["resolve"] == "true")
 456
 457     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 458
 459     json(conn, res)
 460   end
 461
 462   def favourites(%{assigns: %{user: user}} = conn, params) do
 463     params = conn
 464     |> Map.put("type", "Create")
 465     |> Map.put("favorited_by", user.ap_id)
 466     |> Map.put("blocking_user", user)
 467
 468     activities = ActivityPub.fetch_activities([], params)
 469     |> Enum.reverse
 470
 471     conn
 472     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 473   end
 474
 475   def index(%{assigns: %{user: user}} = conn, _params) do
 476     token = conn
 477     |> get_session(:oauth_token)
 478
 479     if user && token do
 480       mastodon_emoji = mastodonized_emoji()
 481       accounts = Map.put(%{}, user.id, AccountView.render("account.json", %{user: user}))
 482       initial_state = %{
 483         meta: %{
 484           streaming_api_base_url: String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 485           access_token: token,
 486           locale: "en",
 487           domain: Pleroma.Web.Endpoint.host(),
 488           admin: "1",
 489           me: "#{user.id}",
 490           unfollow_modal: false,
 491           boost_modal: false,
 492           delete_modal: true,
 493           auto_play_gif: false,
 494           reduce_motion: false
 495         },
 496         compose: %{
 497           me: "#{user.id}",
 498           default_privacy: "public",
 499           default_sensitive: false
 500         },
 501         media_attachments: %{
 502           accept_content_types: [
 503             ".jpg",
 504             ".jpeg",
 505             ".png",
 506             ".gif",
 507             ".webm",
 508             ".mp4",
 509             ".m4v",
 510             "image\/jpeg",
 511             "image\/png",
 512             "image\/gif",
 513             "video\/webm",
 514             "video\/mp4"
 515           ]
 516         },
 517         settings: %{
 518           onboarded: true,
 519           home: %{
 520             shows: %{
 521               reblog: true,
 522               reply: true
 523             }
 524           },
 525           notifications: %{
 526             alerts: %{
 527               follow: true,
 528               favourite: true,
 529               reblog: true,
 530               mention: true
 531             },
 532             shows: %{
 533               follow: true,
 534               favourite: true,
 535               reblog: true,
 536               mention: true
 537             },
 538             sounds: %{
 539               follow: true,
 540               favourite: true,
 541               reblog: true,
 542               mention: true
 543             }
 544           }
 545         },
 546         push_subscription: nil,
 547         accounts: accounts,
 548         custom_emojis: mastodon_emoji
 549       } |> Poison.encode!
 550       conn
 551       |> put_layout(false)
 552       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 553     else
 554       conn
 555       |> redirect(to: "/web/login")
 556     end
 557   end
 558
 559   def login(conn, params) do
 560     conn
 561     |> render(MastodonView, "login.html")
 562   end
 563
 564   defp get_or_make_app() do
 565     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 566       {:ok, app}
 567     else
 568       _e ->
 569         cs = App.register_changeset(%App{}, %{client_name: "Mastodon-Local", redirect_uris: ".", scopes: "read,write,follow"})
 570         Repo.insert(cs)
 571     end
 572   end
 573
 574   def login_post(conn, %{"authorization" => %{ "name" => name, "password" => password}}) do
 575     with %User{} = user <- User.get_cached_by_nickname(name),
 576          true <- Pbkdf2.checkpw(password, user.password_hash),
 577          {:ok, app} <- get_or_make_app(),
 578          {:ok, auth} <- Authorization.create_authorization(app, user),
 579          {:ok, token} <- Token.exchange_token(app, auth) do
 580       conn
 581       |> put_session(:oauth_token, token.token)
 582       |> redirect(to: "/web/timelines/public")
 583     end
 584   end
 585
 586   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 587     Logger.debug("Unimplemented, returning unmodified relationship")
 588     with %User{} = target <- Repo.get(User, id) do
 589       render conn, AccountView, "relationship.json", %{user: user, target: target}
 590     end
 591   end
 592
 593   def empty_array(conn, _) do
 594     Logger.debug("Unimplemented, returning an empty array")
 595     json(conn, [])
 596   end
 597
 598   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
 599     actor = User.get_cached_by_ap_id(activity.data["actor"])
 600     created_at = NaiveDateTime.to_iso8601(created_at)
 601     |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 602     case activity.data["type"] do
 603       "Create" ->
 604         %{id: id, type: "mention", created_at: created_at, account: AccountView.render("account.json", %{user: actor}), status: StatusView.render("status.json", %{activity: activity, for: user})}
 605       "Like" ->
 606         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 607         %{id: id, type: "favourite", created_at: created_at, account: AccountView.render("account.json", %{user: actor}), status: StatusView.render("status.json", %{activity: liked_activity, for: user})}
 608       "Announce" ->
 609         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 610         %{id: id, type: "reblog", created_at: created_at, account: AccountView.render("account.json", %{user: actor}), status: StatusView.render("status.json", %{activity: announced_activity, for: user})}
 611       "Follow" ->
 612         %{id: id, type: "follow", created_at: created_at, account: AccountView.render("account.json", %{user: actor})}
 613       _ -> nil
 614     end
 615   end
 616 end