git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Object, Activity, User, Notification, Stats}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView, ListView, FilterView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.ActivityPub.Utils
   8   alias Pleroma.Web.CommonAPI
   9   alias Pleroma.Web.OAuth.{Authorization, Token, App}
  10   alias Pleroma.Web.MediaProxy
  11   alias Comeonin.Pbkdf2
  12   import Ecto.Query
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   action_fallback(:errors)
  18
  19   def create_app(conn, params) do
  20     with cs <- App.register_changeset(%App{}, params) |> IO.inspect(),
  21          {:ok, app} <- Repo.insert(cs) |> IO.inspect() do
  22       res = %{
  23         id: app.id |> to_string,
  24         name: app.client_name,
  25         client_id: app.client_id,
  26         client_secret: app.client_secret,
  27         redirect_uri: app.redirect_uris,
  28         website: app.website
  29       }
  30
  31       json(conn, res)
  32     end
  33   end
  34
  35   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  36     original_user = user
  37
  38     params =
  39       if bio = params["note"] do
  40         Map.put(params, "bio", bio)
  41       else
  42         params
  43       end
  44
  45     params =
  46       if name = params["display_name"] do
  47         Map.put(params, "name", name)
  48       else
  49         params
  50       end
  51
  52     user =
  53       if avatar = params["avatar"] do
  54         with %Plug.Upload{} <- avatar,
  55              {:ok, object} <- ActivityPub.upload(avatar),
  56              change = Ecto.Changeset.change(user, %{avatar: object.data}),
  57              {:ok, user} = User.update_and_set_cache(change) do
  58           user
  59         else
  60           _e -> user
  61         end
  62       else
  63         user
  64       end
  65
  66     user =
  67       if banner = params["header"] do
  68         with %Plug.Upload{} <- banner,
  69              {:ok, object} <- ActivityPub.upload(banner),
  70              new_info <- Map.put(user.info, "banner", object.data),
  71              change <- User.info_changeset(user, %{info: new_info}),
  72              {:ok, user} <- User.update_and_set_cache(change) do
  73           user
  74         else
  75           _e -> user
  76         end
  77       else
  78         user
  79       end
  80
  81     user =
  82       if locked = params["locked"] do
  83         with locked <- locked == "true",
  84              new_info <- Map.put(user.info, "locked", locked),
  85              change <- User.info_changeset(user, %{info: new_info}),
  86              {:ok, user} <- User.update_and_set_cache(change) do
  87           user
  88         else
  89           _e -> user
  90         end
  91       else
  92         user
  93       end
  94
  95     with changeset <- User.update_changeset(user, params),
  96          {:ok, user} <- User.update_and_set_cache(changeset) do
  97       if original_user != user do
  98         CommonAPI.update(user)
  99       end
 100
 101       json(conn, AccountView.render("account.json", %{user: user, for: user}))
 102     else
 103       _e ->
 104         conn
 105         |> put_status(403)
 106         |> json(%{error: "Invalid request"})
 107     end
 108   end
 109
 110   def verify_credentials(%{assigns: %{user: user}} = conn, _) do
 111     account = AccountView.render("account.json", %{user: user, for: user})
 112     json(conn, account)
 113   end
 114
 115   def user(%{assigns: %{user: for_user}} = conn, %{"id" => id}) do
 116     with %User{} = user <- Repo.get(User, id) do
 117       account = AccountView.render("account.json", %{user: user, for: for_user})
 118       json(conn, account)
 119     else
 120       _e ->
 121         conn
 122         |> put_status(404)
 123         |> json(%{error: "Can't find user"})
 124     end
 125   end
 126
 127   @instance Application.get_env(:pleroma, :instance)
 128   @mastodon_api_level "2.5.0"
 129
 130   def masto_instance(conn, _params) do
 131     response = %{
 132       uri: Web.base_url(),
 133       title: Keyword.get(@instance, :name),
 134       description: Keyword.get(@instance, :description),
 135       version: "#{@mastodon_api_level} (compatible; #{Keyword.get(@instance, :version)})",
 136       email: Keyword.get(@instance, :email),
 137       urls: %{
 138         streaming_api: String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws")
 139       },
 140       stats: Stats.get_stats(),
 141       thumbnail: Web.base_url() <> "/instance/thumbnail.jpeg",
 142       max_toot_chars: Keyword.get(@instance, :limit)
 143     }
 144
 145     json(conn, response)
 146   end
 147
 148   def peers(conn, _params) do
 149     json(conn, Stats.get_peers())
 150   end
 151
 152   defp mastodonized_emoji do
 153     Pleroma.Formatter.get_custom_emoji()
 154     |> Enum.map(fn {shortcode, relative_url} ->
 155       url = to_string(URI.merge(Web.base_url(), relative_url))
 156
 157       %{
 158         "shortcode" => shortcode,
 159         "static_url" => url,
 160         "visible_in_picker" => true,
 161         "url" => url
 162       }
 163     end)
 164   end
 165
 166   def custom_emojis(conn, _params) do
 167     mastodon_emoji = mastodonized_emoji()
 168     json(conn, mastodon_emoji)
 169   end
 170
 171   defp add_link_headers(conn, method, activities, param \\ nil, params \\ %{}) do
 172     last = List.last(activities)
 173     first = List.first(activities)
 174
 175     if last do
 176       min = last.id
 177       max = first.id
 178
 179       {next_url, prev_url} =
 180         if param do
 181           {
 182             mastodon_api_url(
 183               Pleroma.Web.Endpoint,
 184               method,
 185               param,
 186               Map.merge(params, %{max_id: min})
 187             ),
 188             mastodon_api_url(
 189               Pleroma.Web.Endpoint,
 190               method,
 191               param,
 192               Map.merge(params, %{since_id: max})
 193             )
 194           }
 195         else
 196           {
 197             mastodon_api_url(
 198               Pleroma.Web.Endpoint,
 199               method,
 200               Map.merge(params, %{max_id: min})
 201             ),
 202             mastodon_api_url(
 203               Pleroma.Web.Endpoint,
 204               method,
 205               Map.merge(params, %{since_id: max})
 206             )
 207           }
 208         end
 209
 210       conn
 211       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 212     else
 213       conn
 214     end
 215   end
 216
 217   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 218     params =
 219       params
 220       |> Map.put("type", ["Create", "Announce"])
 221       |> Map.put("blocking_user", user)
 222       |> Map.put("user", user)
 223
 224     activities =
 225       ActivityPub.fetch_activities([user.ap_id | user.following], params)
 226       |> Enum.reverse()
 227
 228     conn
 229     |> add_link_headers(:home_timeline, activities)
 230     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 231   end
 232
 233   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 234     local_only = params["local"] in [true, "True", "true", "1"]
 235
 236     params =
 237       params
 238       |> Map.put("type", ["Create", "Announce"])
 239       |> Map.put("local_only", local_only)
 240       |> Map.put("blocking_user", user)
 241
 242     activities =
 243       ActivityPub.fetch_public_activities(params)
 244       |> Enum.reverse()
 245
 246     conn
 247     |> add_link_headers(:public_timeline, activities, false, %{"local" => local_only})
 248     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 249   end
 250
 251   def user_statuses(%{assigns: %{user: reading_user}} = conn, params) do
 252     with %User{} = user <- Repo.get(User, params["id"]) do
 253       # Since Pleroma has no "pinned" posts feature, we'll just set an empty list here
 254       activities =
 255         if params["pinned"] == "true" do
 256           []
 257         else
 258           ActivityPub.fetch_user_activities(user, reading_user, params)
 259         end
 260
 261       conn
 262       |> add_link_headers(:user_statuses, activities, params["id"])
 263       |> render(StatusView, "index.json", %{
 264         activities: activities,
 265         for: reading_user,
 266         as: :activity
 267       })
 268     end
 269   end
 270
 271   def dm_timeline(%{assigns: %{user: user}} = conn, _params) do
 272     query =
 273       ActivityPub.fetch_activities_query([user.ap_id], %{"type" => "Create", visibility: "direct"})
 274
 275     activities = Repo.all(query)
 276
 277     conn
 278     |> add_link_headers(:dm_timeline, activities)
 279     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 280   end
 281
 282   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 283     with %Activity{} = activity <- Repo.get(Activity, id),
 284          true <- ActivityPub.visible_for_user?(activity, user) do
 285       render(conn, StatusView, "status.json", %{activity: activity, for: user})
 286     end
 287   end
 288
 289   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 290     with %Activity{} = activity <- Repo.get(Activity, id),
 291          activities <-
 292            ActivityPub.fetch_activities_for_context(activity.data["context"], %{
 293              "blocking_user" => user,
 294              "user" => user
 295            }),
 296          activities <-
 297            activities |> Enum.filter(fn %{id: aid} -> to_string(aid) != to_string(id) end),
 298          activities <-
 299            activities |> Enum.filter(fn %{data: %{"type" => type}} -> type == "Create" end),
 300          grouped_activities <- Enum.group_by(activities, fn %{id: id} -> id < activity.id end) do
 301       result = %{
 302         ancestors:
 303           StatusView.render(
 304             "index.json",
 305             for: user,
 306             activities: grouped_activities[true] || [],
 307             as: :activity
 308           )
 309           |> Enum.reverse(),
 310         descendants:
 311           StatusView.render(
 312             "index.json",
 313             for: user,
 314             activities: grouped_activities[false] || [],
 315             as: :activity
 316           )
 317           |> Enum.reverse()
 318       }
 319
 320       json(conn, result)
 321     end
 322   end
 323
 324   def post_status(conn, %{"status" => "", "media_ids" => media_ids} = params)
 325       when length(media_ids) > 0 do
 326     params =
 327       params
 328       |> Map.put("status", ".")
 329
 330     post_status(conn, params)
 331   end
 332
 333   def post_status(%{assigns: %{user: user}} = conn, %{"status" => _} = params) do
 334     params =
 335       params
 336       |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 337       |> Map.put("no_attachment_links", true)
 338
 339     idempotency_key =
 340       case get_req_header(conn, "idempotency-key") do
 341         [key] -> key
 342         _ -> Ecto.UUID.generate()
 343       end
 344
 345     {:ok, activity} =
 346       Cachex.fetch!(:idempotency_cache, idempotency_key, fn _ -> CommonAPI.post(user, params) end)
 347
 348     render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 349   end
 350
 351   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 352     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 353       json(conn, %{})
 354     else
 355       _e ->
 356         conn
 357         |> put_status(403)
 358         |> json(%{error: "Can't delete this post"})
 359     end
 360   end
 361
 362   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 363     with {:ok, announce, _activity} <- CommonAPI.repeat(ap_id_or_id, user) do
 364       render(conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity})
 365     end
 366   end
 367
 368   def unreblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 369     with {:ok, _unannounce, %{data: %{"id" => id}}} <- CommonAPI.unrepeat(ap_id_or_id, user),
 370          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 371       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 372     end
 373   end
 374
 375   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 376     with {:ok, _fav, %{data: %{"id" => id}}} <- CommonAPI.favorite(ap_id_or_id, user),
 377          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 378       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 379     end
 380   end
 381
 382   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 383     with {:ok, _, _, %{data: %{"id" => id}}} <- CommonAPI.unfavorite(ap_id_or_id, user),
 384          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 385       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 386     end
 387   end
 388
 389   def notifications(%{assigns: %{user: user}} = conn, params) do
 390     notifications = Notification.for_user(user, params)
 391
 392     result =
 393       Enum.map(notifications, fn x ->
 394         render_notification(user, x)
 395       end)
 396       |> Enum.filter(& &1)
 397
 398     conn
 399     |> add_link_headers(:notifications, notifications)
 400     |> json(result)
 401   end
 402
 403   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 404     with {:ok, notification} <- Notification.get(user, id) do
 405       json(conn, render_notification(user, notification))
 406     else
 407       {:error, reason} ->
 408         conn
 409         |> put_resp_content_type("application/json")
 410         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 411     end
 412   end
 413
 414   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 415     Notification.clear(user)
 416     json(conn, %{})
 417   end
 418
 419   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 420     with {:ok, _notif} <- Notification.dismiss(user, id) do
 421       json(conn, %{})
 422     else
 423       {:error, reason} ->
 424         conn
 425         |> put_resp_content_type("application/json")
 426         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 427     end
 428   end
 429
 430   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 431     id = List.wrap(id)
 432     q = from(u in User, where: u.id in ^id)
 433     targets = Repo.all(q)
 434     render(conn, AccountView, "relationships.json", %{user: user, targets: targets})
 435   end
 436
 437   def update_media(%{assigns: %{user: _}} = conn, data) do
 438     with %Object{} = object <- Repo.get(Object, data["id"]),
 439          true <- is_binary(data["description"]),
 440          description <- data["description"] do
 441       new_data = %{object.data | "name" => description}
 442
 443       change = Object.change(object, %{data: new_data})
 444       {:ok, _} = Repo.update(change)
 445
 446       data =
 447         new_data
 448         |> Map.put("id", object.id)
 449
 450       render(conn, StatusView, "attachment.json", %{attachment: data})
 451     end
 452   end
 453
 454   def upload(%{assigns: %{user: _}} = conn, %{"file" => file} = data) do
 455     with {:ok, object} <- ActivityPub.upload(file) do
 456       objdata =
 457         if Map.has_key?(data, "description") do
 458           Map.put(object.data, "name", data["description"])
 459         else
 460           object.data
 461         end
 462
 463       change = Object.change(object, %{data: objdata})
 464       {:ok, object} = Repo.update(change)
 465
 466       objdata =
 467         objdata
 468         |> Map.put("id", object.id)
 469
 470       render(conn, StatusView, "attachment.json", %{attachment: objdata})
 471     end
 472   end
 473
 474   def favourited_by(conn, %{"id" => id}) do
 475     with %Activity{data: %{"object" => %{"likes" => likes}}} <- Repo.get(Activity, id) do
 476       q = from(u in User, where: u.ap_id in ^likes)
 477       users = Repo.all(q)
 478       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 479     else
 480       _ -> json(conn, [])
 481     end
 482   end
 483
 484   def reblogged_by(conn, %{"id" => id}) do
 485     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 486       q = from(u in User, where: u.ap_id in ^announces)
 487       users = Repo.all(q)
 488       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 489     else
 490       _ -> json(conn, [])
 491     end
 492   end
 493
 494   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 495     local_only = params["local"] in [true, "True", "true", "1"]
 496
 497     params =
 498       params
 499       |> Map.put("type", "Create")
 500       |> Map.put("local_only", local_only)
 501       |> Map.put("blocking_user", user)
 502
 503     activities =
 504       ActivityPub.fetch_public_activities(params)
 505       |> Enum.reverse()
 506
 507     conn
 508     |> add_link_headers(:hashtag_timeline, activities, params["tag"], %{"local" => local_only})
 509     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 510   end
 511
 512   # TODO: Pagination
 513   def followers(conn, %{"id" => id}) do
 514     with %User{} = user <- Repo.get(User, id),
 515          {:ok, followers} <- User.get_followers(user) do
 516       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 517     end
 518   end
 519
 520   def following(conn, %{"id" => id}) do
 521     with %User{} = user <- Repo.get(User, id),
 522          {:ok, followers} <- User.get_friends(user) do
 523       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 524     end
 525   end
 526
 527   def follow_requests(%{assigns: %{user: followed}} = conn, _params) do
 528     with {:ok, follow_requests} <- User.get_follow_requests(followed) do
 529       render(conn, AccountView, "accounts.json", %{users: follow_requests, as: :user})
 530     end
 531   end
 532
 533   def authorize_follow_request(%{assigns: %{user: followed}} = conn, %{"id" => id}) do
 534     with %User{} = follower <- Repo.get(User, id),
 535          {:ok, follower} <- User.maybe_follow(follower, followed),
 536          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 537          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 538          {:ok, _activity} <-
 539            ActivityPub.accept(%{
 540              to: [follower.ap_id],
 541              actor: followed.ap_id,
 542              object: follow_activity.data["id"],
 543              type: "Accept"
 544            }) do
 545       render(conn, AccountView, "relationship.json", %{user: followed, target: follower})
 546     else
 547       {:error, message} ->
 548         conn
 549         |> put_resp_content_type("application/json")
 550         |> send_resp(403, Jason.encode!(%{"error" => message}))
 551     end
 552   end
 553
 554   def reject_follow_request(%{assigns: %{user: followed}} = conn, %{"id" => id}) do
 555     with %User{} = follower <- Repo.get(User, id),
 556          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 557          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 558          {:ok, _activity} <-
 559            ActivityPub.reject(%{
 560              to: [follower.ap_id],
 561              actor: followed.ap_id,
 562              object: follow_activity.data["id"],
 563              type: "Reject"
 564            }) do
 565       render(conn, AccountView, "relationship.json", %{user: followed, target: follower})
 566     else
 567       {:error, message} ->
 568         conn
 569         |> put_resp_content_type("application/json")
 570         |> send_resp(403, Jason.encode!(%{"error" => message}))
 571     end
 572   end
 573
 574   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 575     with %User{} = followed <- Repo.get(User, id),
 576          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 577          {:ok, _activity} <- ActivityPub.follow(follower, followed),
 578          {:ok, follower, followed} <- User.wait_and_refresh(500, follower, followed) do
 579       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 580     else
 581       {:error, message} ->
 582         conn
 583         |> put_resp_content_type("application/json")
 584         |> send_resp(403, Jason.encode!(%{"error" => message}))
 585     end
 586   end
 587
 588   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 589     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 590          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 591          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 592       render(conn, AccountView, "account.json", %{user: followed, for: follower})
 593     else
 594       {:error, message} ->
 595         conn
 596         |> put_resp_content_type("application/json")
 597         |> send_resp(403, Jason.encode!(%{"error" => message}))
 598     end
 599   end
 600
 601   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 602     with %User{} = followed <- Repo.get(User, id),
 603          {:ok, _activity} <- ActivityPub.unfollow(follower, followed),
 604          {:ok, follower, _} <- User.unfollow(follower, followed) do
 605       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 606     end
 607   end
 608
 609   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 610     with %User{} = blocked <- Repo.get(User, id),
 611          {:ok, blocker} <- User.block(blocker, blocked),
 612          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
 613       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 614     else
 615       {:error, message} ->
 616         conn
 617         |> put_resp_content_type("application/json")
 618         |> send_resp(403, Jason.encode!(%{"error" => message}))
 619     end
 620   end
 621
 622   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 623     with %User{} = blocked <- Repo.get(User, id),
 624          {:ok, blocker} <- User.unblock(blocker, blocked),
 625          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
 626       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 627     else
 628       {:error, message} ->
 629         conn
 630         |> put_resp_content_type("application/json")
 631         |> send_resp(403, Jason.encode!(%{"error" => message}))
 632     end
 633   end
 634
 635   # TODO: Use proper query
 636   def blocks(%{assigns: %{user: user}} = conn, _) do
 637     with blocked_users <- user.info["blocks"] || [],
 638          accounts <- Enum.map(blocked_users, fn ap_id -> User.get_cached_by_ap_id(ap_id) end) do
 639       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 640       json(conn, res)
 641     end
 642   end
 643
 644   def domain_blocks(%{assigns: %{user: %{info: info}}} = conn, _) do
 645     json(conn, info["domain_blocks"] || [])
 646   end
 647
 648   def block_domain(%{assigns: %{user: blocker}} = conn, %{"domain" => domain}) do
 649     User.block_domain(blocker, domain)
 650     json(conn, %{})
 651   end
 652
 653   def unblock_domain(%{assigns: %{user: blocker}} = conn, %{"domain" => domain}) do
 654     User.unblock_domain(blocker, domain)
 655     json(conn, %{})
 656   end
 657
 658   def status_search(query) do
 659     fetched =
 660       if Regex.match?(~r/https?:/, query) do
 661         with {:ok, object} <- ActivityPub.fetch_object_from_id(query) do
 662           [Activity.get_create_activity_by_object_ap_id(object.data["id"])]
 663         else
 664           _e -> []
 665         end
 666       end || []
 667
 668     q =
 669       from(
 670         a in Activity,
 671         where: fragment("?->>'type' = 'Create'", a.data),
 672         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 673         where:
 674           fragment(
 675             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 676             a.data,
 677             ^query
 678           ),
 679         limit: 20,
 680         order_by: [desc: :id]
 681       )
 682
 683     Repo.all(q) ++ fetched
 684   end
 685
 686   def search2(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 687     accounts = User.search(query, params["resolve"] == "true")
 688
 689     statuses = status_search(query)
 690
 691     tags_path = Web.base_url() <> "/tag/"
 692
 693     tags =
 694       String.split(query)
 695       |> Enum.uniq()
 696       |> Enum.filter(fn tag -> String.starts_with?(tag, "#") end)
 697       |> Enum.map(fn tag -> String.slice(tag, 1..-1) end)
 698       |> Enum.map(fn tag -> %{name: tag, url: tags_path <> tag} end)
 699
 700     res = %{
 701       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 702       "statuses" =>
 703         StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 704       "hashtags" => tags
 705     }
 706
 707     json(conn, res)
 708   end
 709
 710   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 711     accounts = User.search(query, params["resolve"] == "true")
 712
 713     statuses = status_search(query)
 714
 715     tags =
 716       String.split(query)
 717       |> Enum.uniq()
 718       |> Enum.filter(fn tag -> String.starts_with?(tag, "#") end)
 719       |> Enum.map(fn tag -> String.slice(tag, 1..-1) end)
 720
 721     res = %{
 722       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 723       "statuses" =>
 724         StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 725       "hashtags" => tags
 726     }
 727
 728     json(conn, res)
 729   end
 730
 731   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 732     accounts = User.search(query, params["resolve"] == "true")
 733
 734     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 735
 736     json(conn, res)
 737   end
 738
 739   def favourites(%{assigns: %{user: user}} = conn, _) do
 740     params =
 741       %{}
 742       |> Map.put("type", "Create")
 743       |> Map.put("favorited_by", user.ap_id)
 744       |> Map.put("blocking_user", user)
 745
 746     activities =
 747       ActivityPub.fetch_public_activities(params)
 748       |> Enum.reverse()
 749
 750     conn
 751     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 752   end
 753
 754   def get_lists(%{assigns: %{user: user}} = conn, opts) do
 755     lists = Pleroma.List.for_user(user, opts)
 756     res = ListView.render("lists.json", lists: lists)
 757     json(conn, res)
 758   end
 759
 760   def get_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 761     with %Pleroma.List{} = list <- Pleroma.List.get(id, user) do
 762       res = ListView.render("list.json", list: list)
 763       json(conn, res)
 764     else
 765       _e -> json(conn, "error")
 766     end
 767   end
 768
 769   def delete_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 770     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 771          {:ok, _list} <- Pleroma.List.delete(list) do
 772       json(conn, %{})
 773     else
 774       _e ->
 775         json(conn, "error")
 776     end
 777   end
 778
 779   def create_list(%{assigns: %{user: user}} = conn, %{"title" => title}) do
 780     with {:ok, %Pleroma.List{} = list} <- Pleroma.List.create(title, user) do
 781       res = ListView.render("list.json", list: list)
 782       json(conn, res)
 783     end
 784   end
 785
 786   def add_to_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 787     accounts
 788     |> Enum.each(fn account_id ->
 789       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 790            %User{} = followed <- Repo.get(User, account_id) do
 791         Pleroma.List.follow(list, followed)
 792       end
 793     end)
 794
 795     json(conn, %{})
 796   end
 797
 798   def remove_from_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 799     accounts
 800     |> Enum.each(fn account_id ->
 801       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 802            %User{} = followed <- Repo.get(Pleroma.User, account_id) do
 803         Pleroma.List.unfollow(list, followed)
 804       end
 805     end)
 806
 807     json(conn, %{})
 808   end
 809
 810   def list_accounts(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 811     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 812          {:ok, users} = Pleroma.List.get_following(list) do
 813       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 814     end
 815   end
 816
 817   def rename_list(%{assigns: %{user: user}} = conn, %{"id" => id, "title" => title}) do
 818     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 819          {:ok, list} <- Pleroma.List.rename(list, title) do
 820       res = ListView.render("list.json", list: list)
 821       json(conn, res)
 822     else
 823       _e ->
 824         json(conn, "error")
 825     end
 826   end
 827
 828   def list_timeline(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 829     with %Pleroma.List{title: title, following: following} <- Pleroma.List.get(id, user) do
 830       params =
 831         params
 832         |> Map.put("type", "Create")
 833         |> Map.put("blocking_user", user)
 834
 835       # we must filter the following list for the user to avoid leaking statuses the user
 836       # does not actually have permission to see (for more info, peruse security issue #270).
 837       following_to =
 838         following
 839         |> Enum.filter(fn x -> x in user.following end)
 840
 841       activities =
 842         ActivityPub.fetch_activities_bounded(following_to, following, params)
 843         |> Enum.reverse()
 844
 845       conn
 846       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 847     else
 848       _e ->
 849         conn
 850         |> put_status(403)
 851         |> json(%{error: "Error."})
 852     end
 853   end
 854
 855   def index(%{assigns: %{user: user}} = conn, _params) do
 856     token =
 857       conn
 858       |> get_session(:oauth_token)
 859
 860     if user && token do
 861       mastodon_emoji = mastodonized_emoji()
 862
 863       accounts =
 864         Map.put(%{}, user.id, AccountView.render("account.json", %{user: user, for: user}))
 865
 866       initial_state =
 867         %{
 868           meta: %{
 869             streaming_api_base_url:
 870               String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 871             access_token: token,
 872             locale: "en",
 873             domain: Pleroma.Web.Endpoint.host(),
 874             admin: "1",
 875             me: "#{user.id}",
 876             unfollow_modal: false,
 877             boost_modal: false,
 878             delete_modal: true,
 879             auto_play_gif: false,
 880             display_sensitive_media: false,
 881             reduce_motion: false,
 882             max_toot_chars: Keyword.get(@instance, :limit)
 883           },
 884           rights: %{
 885             delete_others_notice: !!user.info["is_moderator"]
 886           },
 887           compose: %{
 888             me: "#{user.id}",
 889             default_privacy: user.info["default_scope"] || "public",
 890             default_sensitive: false
 891           },
 892           media_attachments: %{
 893             accept_content_types: [
 894               ".jpg",
 895               ".jpeg",
 896               ".png",
 897               ".gif",
 898               ".webm",
 899               ".mp4",
 900               ".m4v",
 901               "image\/jpeg",
 902               "image\/png",
 903               "image\/gif",
 904               "video\/webm",
 905               "video\/mp4"
 906             ]
 907           },
 908           settings:
 909             Map.get(user.info, "settings") ||
 910               %{
 911                 onboarded: true,
 912                 home: %{
 913                   shows: %{
 914                     reblog: true,
 915                     reply: true
 916                   }
 917                 },
 918                 notifications: %{
 919                   alerts: %{
 920                     follow: true,
 921                     favourite: true,
 922                     reblog: true,
 923                     mention: true
 924                   },
 925                   shows: %{
 926                     follow: true,
 927                     favourite: true,
 928                     reblog: true,
 929                     mention: true
 930                   },
 931                   sounds: %{
 932                     follow: true,
 933                     favourite: true,
 934                     reblog: true,
 935                     mention: true
 936                   }
 937                 }
 938               },
 939           push_subscription: nil,
 940           accounts: accounts,
 941           custom_emojis: mastodon_emoji,
 942           char_limit: Keyword.get(@instance, :limit)
 943         }
 944         |> Jason.encode!()
 945
 946       conn
 947       |> put_layout(false)
 948       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 949     else
 950       conn
 951       |> redirect(to: "/web/login")
 952     end
 953   end
 954
 955   def put_settings(%{assigns: %{user: user}} = conn, %{"data" => settings} = _params) do
 956     with new_info <- Map.put(user.info, "settings", settings),
 957          change <- User.info_changeset(user, %{info: new_info}),
 958          {:ok, _user} <- User.update_and_set_cache(change) do
 959       conn
 960       |> json(%{})
 961     else
 962       e ->
 963         conn
 964         |> json(%{error: inspect(e)})
 965     end
 966   end
 967
 968   def login(conn, _) do
 969     conn
 970     |> render(MastodonView, "login.html", %{error: false})
 971   end
 972
 973   defp get_or_make_app() do
 974     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 975       {:ok, app}
 976     else
 977       _e ->
 978         cs =
 979           App.register_changeset(%App{}, %{
 980             client_name: "Mastodon-Local",
 981             redirect_uris: ".",
 982             scopes: "read,write,follow"
 983           })
 984
 985         Repo.insert(cs)
 986     end
 987   end
 988
 989   def login_post(conn, %{"authorization" => %{"name" => name, "password" => password}}) do
 990     with %User{} = user <- User.get_by_nickname_or_email(name),
 991          true <- Pbkdf2.checkpw(password, user.password_hash),
 992          {:ok, app} <- get_or_make_app(),
 993          {:ok, auth} <- Authorization.create_authorization(app, user),
 994          {:ok, token} <- Token.exchange_token(app, auth) do
 995       conn
 996       |> put_session(:oauth_token, token.token)
 997       |> redirect(to: "/web/getting-started")
 998     else
 999       _e ->
1000         conn
1001         |> render(MastodonView, "login.html", %{error: "Wrong username or password"})
1002     end
1003   end
1004
1005   def logout(conn, _) do
1006     conn
1007     |> clear_session
1008     |> redirect(to: "/")
1009   end
1010
1011   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
1012     Logger.debug("Unimplemented, returning unmodified relationship")
1013
1014     with %User{} = target <- Repo.get(User, id) do
1015       render(conn, AccountView, "relationship.json", %{user: user, target: target})
1016     end
1017   end
1018
1019   def empty_array(conn, _) do
1020     Logger.debug("Unimplemented, returning an empty array")
1021     json(conn, [])
1022   end
1023
1024   def empty_object(conn, _) do
1025     Logger.debug("Unimplemented, returning an empty object")
1026     json(conn, %{})
1027   end
1028
1029   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
1030     actor = User.get_cached_by_ap_id(activity.data["actor"])
1031
1032     created_at =
1033       NaiveDateTime.to_iso8601(created_at)
1034       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
1035
1036     id = id |> to_string
1037
1038     case activity.data["type"] do
1039       "Create" ->
1040         %{
1041           id: id,
1042           type: "mention",
1043           created_at: created_at,
1044           account: AccountView.render("account.json", %{user: actor, for: user}),
1045           status: StatusView.render("status.json", %{activity: activity, for: user})
1046         }
1047
1048       "Like" ->
1049         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
1050
1051         %{
1052           id: id,
1053           type: "favourite",
1054           created_at: created_at,
1055           account: AccountView.render("account.json", %{user: actor, for: user}),
1056           status: StatusView.render("status.json", %{activity: liked_activity, for: user})
1057         }
1058
1059       "Announce" ->
1060         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
1061
1062         %{
1063           id: id,
1064           type: "reblog",
1065           created_at: created_at,
1066           account: AccountView.render("account.json", %{user: actor, for: user}),
1067           status: StatusView.render("status.json", %{activity: announced_activity, for: user})
1068         }
1069
1070       "Follow" ->
1071         %{
1072           id: id,
1073           type: "follow",
1074           created_at: created_at,
1075           account: AccountView.render("account.json", %{user: actor, for: user})
1076         }
1077
1078       _ ->
1079         nil
1080     end
1081   end
1082
1083   def get_filters(%{assigns: %{user: user}} = conn, _) do
1084     filters = Pleroma.Filter.get_filters(user)
1085     res = FilterView.render("filters.json", filters: filters)
1086     json(conn, res)
1087   end
1088
1089   def create_filter(
1090         %{assigns: %{user: user}} = conn,
1091         %{"phrase" => phrase, "context" => context} = params
1092       ) do
1093     query = %Pleroma.Filter{
1094       user_id: user.id,
1095       phrase: phrase,
1096       context: context,
1097       hide: Map.get(params, "irreversible", nil),
1098       whole_word: Map.get(params, "boolean", true)
1099       # expires_at
1100     }
1101
1102     {:ok, response} = Pleroma.Filter.create(query)
1103     res = FilterView.render("filter.json", filter: response)
1104     json(conn, res)
1105   end
1106
1107   def get_filter(%{assigns: %{user: user}} = conn, %{"id" => filter_id}) do
1108     filter = Pleroma.Filter.get(filter_id, user)
1109     res = FilterView.render("filter.json", filter: filter)
1110     json(conn, res)
1111   end
1112
1113   def update_filter(
1114         %{assigns: %{user: user}} = conn,
1115         %{"phrase" => phrase, "context" => context, "id" => filter_id} = params
1116       ) do
1117     query = %Pleroma.Filter{
1118       user_id: user.id,
1119       filter_id: filter_id,
1120       phrase: phrase,
1121       context: context,
1122       hide: Map.get(params, "irreversible", nil),
1123       whole_word: Map.get(params, "boolean", true)
1124       # expires_at
1125     }
1126
1127     {:ok, response} = Pleroma.Filter.update(query)
1128     res = FilterView.render("filter.json", filter: response)
1129     json(conn, res)
1130   end
1131
1132   def delete_filter(%{assigns: %{user: user}} = conn, %{"id" => filter_id}) do
1133     query = %Pleroma.Filter{
1134       user_id: user.id,
1135       filter_id: filter_id
1136     }
1137
1138     {:ok, _} = Pleroma.Filter.delete(query)
1139     json(conn, %{})
1140   end
1141
1142   def errors(conn, _) do
1143     conn
1144     |> put_status(500)
1145     |> json("Something went wrong")
1146   end
1147
1148   @suggestions Application.get_env(:pleroma, :suggestions)
1149
1150   def suggestions(%{assigns: %{user: user}} = conn, _) do
1151     if Keyword.get(@suggestions, :enabled, false) do
1152       api = Keyword.get(@suggestions, :third_party_engine, "")
1153       timeout = Keyword.get(@suggestions, :timeout, 5000)
1154       limit = Keyword.get(@suggestions, :limit, 23)
1155
1156       host =
1157         Application.get_env(:pleroma, Pleroma.Web.Endpoint)
1158         |> Keyword.get(:url)
1159         |> Keyword.get(:host)
1160
1161       user = user.nickname
1162       url = String.replace(api, "{{host}}", host) |> String.replace("{{user}}", user)
1163
1164       with {:ok, %{status_code: 200, body: body}} <-
1165              @httpoison.get(url, [], timeout: timeout, recv_timeout: timeout),
1166            {:ok, data} <- Jason.decode(body) do
1167         data2 =
1168           Enum.slice(data, 0, limit)
1169           |> Enum.map(fn x ->
1170             Map.put(
1171               x,
1172               "id",
1173               case User.get_or_fetch(x["acct"]) do
1174                 %{id: id} -> id
1175                 _ -> 0
1176               end
1177             )
1178           end)
1179           |> Enum.map(fn x ->
1180             Map.put(x, "avatar", MediaProxy.url(x["avatar"]))
1181           end)
1182           |> Enum.map(fn x ->
1183             Map.put(x, "avatar_static", MediaProxy.url(x["avatar_static"]))
1184           end)
1185
1186         conn
1187         |> json(data2)
1188       else
1189         e -> Logger.error("Could not retrieve suggestions at fetch #{url}, #{inspect(e)}")
1190       end
1191     else
1192       json(conn, [])
1193     end
1194   end
1195 end