git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification, Stats}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView, ListView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.{CommonAPI, OStatus}
   8   alias Pleroma.Web.OAuth.{Authorization, Token, App}
   9   alias Comeonin.Pbkdf2
  10   import Ecto.Query
  11   require Logger
  12
  13   def create_app(conn, params) do
  14     with cs <- App.register_changeset(%App{}, params) |> IO.inspect(),
  15          {:ok, app} <- Repo.insert(cs) |> IO.inspect() do
  16       res = %{
  17         id: app.id,
  18         client_id: app.client_id,
  19         client_secret: app.client_secret
  20       }
  21
  22       json(conn, res)
  23     end
  24   end
  25
  26   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  27     original_user = user
  28
  29     params =
  30       if bio = params["note"] do
  31         Map.put(params, "bio", bio)
  32       else
  33         params
  34       end
  35
  36     params =
  37       if name = params["display_name"] do
  38         Map.put(params, "name", name)
  39       else
  40         params
  41       end
  42
  43     user =
  44       if avatar = params["avatar"] do
  45         with %Plug.Upload{} <- avatar,
  46              {:ok, object} <- ActivityPub.upload(avatar),
  47              change = Ecto.Changeset.change(user, %{avatar: object.data}),
  48              {:ok, user} = User.update_and_set_cache(change) do
  49           user
  50         else
  51           _e -> user
  52         end
  53       else
  54         user
  55       end
  56
  57     user =
  58       if banner = params["header"] do
  59         with %Plug.Upload{} <- banner,
  60              {:ok, object} <- ActivityPub.upload(banner),
  61              new_info <- Map.put(user.info, "banner", object.data),
  62              change <- User.info_changeset(user, %{info: new_info}),
  63              {:ok, user} <- User.update_and_set_cache(change) do
  64           user
  65         else
  66           _e -> user
  67         end
  68       else
  69         user
  70       end
  71
  72     with changeset <- User.update_changeset(user, params),
  73          {:ok, user} <- User.update_and_set_cache(changeset) do
  74       if original_user != user do
  75         CommonAPI.update(user)
  76       end
  77
  78       json(conn, AccountView.render("account.json", %{user: user}))
  79     else
  80       _e ->
  81         conn
  82         |> put_status(403)
  83         |> json(%{error: "Invalid request"})
  84     end
  85   end
  86
  87   def verify_credentials(%{assigns: %{user: user}} = conn, _) do
  88     account = AccountView.render("account.json", %{user: user})
  89     json(conn, account)
  90   end
  91
  92   def user(conn, %{"id" => id}) do
  93     with %User{} = user <- Repo.get(User, id) do
  94       account = AccountView.render("account.json", %{user: user})
  95       json(conn, account)
  96     else
  97       _e ->
  98         conn
  99         |> put_status(404)
 100         |> json(%{error: "Can't find user"})
 101     end
 102   end
 103
 104   @instance Application.get_env(:pleroma, :instance)
 105   @mastodon_api_level "2.3.3"
 106
 107   def masto_instance(conn, _params) do
 108     response = %{
 109       uri: Web.base_url(),
 110       title: Keyword.get(@instance, :name),
 111       description: "A Pleroma instance, an alternative fediverse server",
 112       version: "#{@mastodon_api_level} (compatible; #{Keyword.get(@instance, :version)})",
 113       email: Keyword.get(@instance, :email),
 114       urls: %{
 115         streaming_api: String.replace(Web.base_url(), ["http", "https"], "wss")
 116       },
 117       stats: Stats.get_stats(),
 118       thumbnail: Web.base_url() <> "/instance/thumbnail.jpeg",
 119       max_toot_chars: Keyword.get(@instance, :limit)
 120     }
 121
 122     json(conn, response)
 123   end
 124
 125   def peers(conn, _params) do
 126     json(conn, Stats.get_peers())
 127   end
 128
 129   defp mastodonized_emoji do
 130     Pleroma.Formatter.get_custom_emoji()
 131     |> Enum.map(fn {shortcode, relative_url} ->
 132       url = to_string(URI.merge(Web.base_url(), relative_url))
 133
 134       %{
 135         "shortcode" => shortcode,
 136         "static_url" => url,
 137         "url" => url
 138       }
 139     end)
 140   end
 141
 142   def custom_emojis(conn, _params) do
 143     mastodon_emoji = mastodonized_emoji()
 144     json(conn, mastodon_emoji)
 145   end
 146
 147   defp add_link_headers(conn, method, activities, param \\ false) do
 148     last = List.last(activities)
 149     first = List.first(activities)
 150
 151     if last do
 152       min = last.id
 153       max = first.id
 154
 155       {next_url, prev_url} =
 156         if param do
 157           {
 158             mastodon_api_url(Pleroma.Web.Endpoint, method, param, max_id: min),
 159             mastodon_api_url(Pleroma.Web.Endpoint, method, param, since_id: max)
 160           }
 161         else
 162           {
 163             mastodon_api_url(Pleroma.Web.Endpoint, method, max_id: min),
 164             mastodon_api_url(Pleroma.Web.Endpoint, method, since_id: max)
 165           }
 166         end
 167
 168       conn
 169       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 170     else
 171       conn
 172     end
 173   end
 174
 175   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 176     params =
 177       params
 178       |> Map.put("type", ["Create", "Announce"])
 179       |> Map.put("blocking_user", user)
 180       |> Map.put("user", user)
 181
 182     activities =
 183       ActivityPub.fetch_activities([user.ap_id | user.following], params)
 184       |> Enum.reverse()
 185
 186     conn
 187     |> add_link_headers(:home_timeline, activities)
 188     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 189   end
 190
 191   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 192     params =
 193       params
 194       |> Map.put("type", ["Create", "Announce"])
 195       |> Map.put("local_only", params["local"] in [true, "True", "true", "1"])
 196       |> Map.put("blocking_user", user)
 197
 198     activities =
 199       ActivityPub.fetch_public_activities(params)
 200       |> Enum.reverse()
 201
 202     conn
 203     |> add_link_headers(:public_timeline, activities)
 204     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 205   end
 206
 207   def user_statuses(%{assigns: %{user: user}} = conn, params) do
 208     with %User{ap_id: ap_id} <- Repo.get(User, params["id"]) do
 209       params =
 210         params
 211         |> Map.put("type", ["Create", "Announce"])
 212         |> Map.put("actor_id", ap_id)
 213         |> Map.put("whole_db", true)
 214
 215       if params["pinned"] == "true" do
 216         # Since Pleroma has no "pinned" posts feature, we'll just set an empty list here
 217         activities = []
 218       else
 219         activities =
 220           ActivityPub.fetch_public_activities(params)
 221           |> Enum.reverse()
 222       end
 223
 224       conn
 225       |> add_link_headers(:user_statuses, activities, params["id"])
 226       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 227     end
 228   end
 229
 230   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 231     with %Activity{} = activity <- Repo.get(Activity, id),
 232          true <- ActivityPub.visible_for_user?(activity, user) do
 233       render(conn, StatusView, "status.json", %{activity: activity, for: user})
 234     end
 235   end
 236
 237   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 238     with %Activity{} = activity <- Repo.get(Activity, id),
 239          activities <-
 240            ActivityPub.fetch_activities_for_context(activity.data["context"], %{
 241              "blocking_user" => user,
 242              "user" => user
 243            }),
 244          activities <-
 245            activities |> Enum.filter(fn %{id: aid} -> to_string(aid) != to_string(id) end),
 246          activities <-
 247            activities |> Enum.filter(fn %{data: %{"type" => type}} -> type == "Create" end),
 248          grouped_activities <- Enum.group_by(activities, fn %{id: id} -> id < activity.id end) do
 249       result = %{
 250         ancestors:
 251           StatusView.render(
 252             "index.json",
 253             for: user,
 254             activities: grouped_activities[true] || [],
 255             as: :activity
 256           )
 257           |> Enum.reverse(),
 258         descendants:
 259           StatusView.render(
 260             "index.json",
 261             for: user,
 262             activities: grouped_activities[false] || [],
 263             as: :activity
 264           )
 265           |> Enum.reverse()
 266       }
 267
 268       json(conn, result)
 269     end
 270   end
 271
 272   def post_status(%{assigns: %{user: user}} = conn, %{"status" => _} = params) do
 273     params =
 274       params
 275       |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 276       |> Map.put("no_attachment_links", true)
 277
 278     {:ok, activity} = CommonAPI.post(user, params)
 279     render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 280   end
 281
 282   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 283     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 284       json(conn, %{})
 285     else
 286       _e ->
 287         conn
 288         |> put_status(403)
 289         |> json(%{error: "Can't delete this post"})
 290     end
 291   end
 292
 293   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 294     with {:ok, announce, _activity} = CommonAPI.repeat(ap_id_or_id, user) do
 295       render(conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity})
 296     end
 297   end
 298
 299   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 300     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 301          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 302       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 303     end
 304   end
 305
 306   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 307     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 308          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 309       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 310     end
 311   end
 312
 313   def notifications(%{assigns: %{user: user}} = conn, params) do
 314     notifications = Notification.for_user(user, params)
 315
 316     result =
 317       Enum.map(notifications, fn x ->
 318         render_notification(user, x)
 319       end)
 320       |> Enum.filter(& &1)
 321
 322     conn
 323     |> add_link_headers(:notifications, notifications)
 324     |> json(result)
 325   end
 326
 327   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 328     with {:ok, notification} <- Notification.get(user, id) do
 329       json(conn, render_notification(user, notification))
 330     else
 331       {:error, reason} ->
 332         conn
 333         |> put_resp_content_type("application/json")
 334         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 335     end
 336   end
 337
 338   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 339     Notification.clear(user)
 340     json(conn, %{})
 341   end
 342
 343   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 344     with {:ok, _notif} <- Notification.dismiss(user, id) do
 345       json(conn, %{})
 346     else
 347       {:error, reason} ->
 348         conn
 349         |> put_resp_content_type("application/json")
 350         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 351     end
 352   end
 353
 354   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 355     id = List.wrap(id)
 356     q = from(u in User, where: u.id in ^id)
 357     targets = Repo.all(q)
 358     render(conn, AccountView, "relationships.json", %{user: user, targets: targets})
 359   end
 360
 361   def upload(%{assigns: %{user: _}} = conn, %{"file" => file}) do
 362     with {:ok, object} <- ActivityPub.upload(file) do
 363       data =
 364         object.data
 365         |> Map.put("id", object.id)
 366
 367       render(conn, StatusView, "attachment.json", %{attachment: data})
 368     end
 369   end
 370
 371   def favourited_by(conn, %{"id" => id}) do
 372     with %Activity{data: %{"object" => %{"likes" => likes}}} <- Repo.get(Activity, id) do
 373       q = from(u in User, where: u.ap_id in ^likes)
 374       users = Repo.all(q)
 375       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 376     else
 377       _ -> json(conn, [])
 378     end
 379   end
 380
 381   def reblogged_by(conn, %{"id" => id}) do
 382     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 383       q = from(u in User, where: u.ap_id in ^announces)
 384       users = Repo.all(q)
 385       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 386     else
 387       _ -> json(conn, [])
 388     end
 389   end
 390
 391   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 392     params =
 393       params
 394       |> Map.put("type", "Create")
 395       |> Map.put("local_only", !!params["local"])
 396       |> Map.put("blocking_user", user)
 397
 398     activities =
 399       ActivityPub.fetch_public_activities(params)
 400       |> Enum.reverse()
 401
 402     conn
 403     |> add_link_headers(:hashtag_timeline, activities, params["tag"])
 404     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 405   end
 406
 407   # TODO: Pagination
 408   def followers(conn, %{"id" => id}) do
 409     with %User{} = user <- Repo.get(User, id),
 410          {:ok, followers} <- User.get_followers(user) do
 411       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 412     end
 413   end
 414
 415   def following(conn, %{"id" => id}) do
 416     with %User{} = user <- Repo.get(User, id),
 417          {:ok, followers} <- User.get_friends(user) do
 418       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 419     end
 420   end
 421
 422   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 423     with %User{} = followed <- Repo.get(User, id),
 424          {:ok, follower} <- User.follow(follower, followed),
 425          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 426       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 427     else
 428       {:error, message} ->
 429         conn
 430         |> put_resp_content_type("application/json")
 431         |> send_resp(403, Jason.encode!(%{"error" => message}))
 432     end
 433   end
 434
 435   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 436     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 437          {:ok, follower} <- User.follow(follower, followed),
 438          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 439       render(conn, AccountView, "account.json", %{user: followed})
 440     else
 441       {:error, message} ->
 442         conn
 443         |> put_resp_content_type("application/json")
 444         |> send_resp(403, Jason.encode!(%{"error" => message}))
 445     end
 446   end
 447
 448   # TODO: Clean up and unify
 449   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 450     with %User{} = followed <- Repo.get(User, id),
 451          {:ok, follower, follow_activity} <- User.unfollow(follower, followed),
 452          {:ok, _activity} <-
 453            ActivityPub.insert(%{
 454              "type" => "Undo",
 455              "actor" => follower.ap_id,
 456              # get latest Follow for these users
 457              "object" => follow_activity.data["id"]
 458            }) do
 459       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 460     end
 461   end
 462
 463   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 464     with %User{} = blocked <- Repo.get(User, id),
 465          {:ok, blocker} <- User.block(blocker, blocked) do
 466       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 467     else
 468       {:error, message} ->
 469         conn
 470         |> put_resp_content_type("application/json")
 471         |> send_resp(403, Jason.encode!(%{"error" => message}))
 472     end
 473   end
 474
 475   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 476     with %User{} = blocked <- Repo.get(User, id),
 477          {:ok, blocker} <- User.unblock(blocker, blocked) do
 478       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 479     else
 480       {:error, message} ->
 481         conn
 482         |> put_resp_content_type("application/json")
 483         |> send_resp(403, Jason.encode!(%{"error" => message}))
 484     end
 485   end
 486
 487   # TODO: Use proper query
 488   def blocks(%{assigns: %{user: user}} = conn, _) do
 489     with blocked_users <- user.info["blocks"] || [],
 490          accounts <- Enum.map(blocked_users, fn ap_id -> User.get_cached_by_ap_id(ap_id) end) do
 491       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 492       json(conn, res)
 493     end
 494   end
 495
 496   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 497     accounts = User.search(query, params["resolve"] == "true")
 498
 499     fetched =
 500       if Regex.match?(~r/https?:/, query) do
 501         with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 502           activities
 503           |> Enum.filter(fn
 504             %{data: %{"type" => "Create"}} -> true
 505             _ -> false
 506           end)
 507         else
 508           _e -> []
 509         end
 510       end || []
 511
 512     q =
 513       from(
 514         a in Activity,
 515         where: fragment("?->>'type' = 'Create'", a.data),
 516         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 517         where:
 518           fragment(
 519             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 520             a.data,
 521             ^query
 522           ),
 523         limit: 20,
 524         order_by: [desc: :id]
 525       )
 526
 527     statuses = Repo.all(q) ++ fetched
 528
 529     tags =
 530       String.split(query)
 531       |> Enum.uniq()
 532       |> Enum.filter(fn tag -> String.starts_with?(tag, "#") end)
 533       |> Enum.map(fn tag -> String.slice(tag, 1..-1) end)
 534
 535     res = %{
 536       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 537       "statuses" =>
 538         StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 539       "hashtags" => tags
 540     }
 541
 542     json(conn, res)
 543   end
 544
 545   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 546     accounts = User.search(query, params["resolve"] == "true")
 547
 548     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 549
 550     json(conn, res)
 551   end
 552
 553   def favourites(%{assigns: %{user: user}} = conn, _) do
 554     params =
 555       %{}
 556       |> Map.put("type", "Create")
 557       |> Map.put("favorited_by", user.ap_id)
 558       |> Map.put("blocking_user", user)
 559
 560     activities =
 561       ActivityPub.fetch_public_activities(params)
 562       |> Enum.reverse()
 563
 564     conn
 565     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 566   end
 567
 568   def get_lists(%{assigns: %{user: user}} = conn, opts) do
 569     lists = Pleroma.List.for_user(user, opts)
 570     res = ListView.render("lists.json", lists: lists)
 571     json(conn, res)
 572   end
 573
 574   def get_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 575     with %Pleroma.List{} = list <- Pleroma.List.get(id, user) do
 576       res = ListView.render("list.json", list: list)
 577       json(conn, res)
 578     else
 579       _e -> json(conn, "error")
 580     end
 581   end
 582
 583   def delete_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 584     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 585          {:ok, _list} <- Pleroma.List.delete(list) do
 586       json(conn, %{})
 587     else
 588       _e ->
 589         json(conn, "error")
 590     end
 591   end
 592
 593   def create_list(%{assigns: %{user: user}} = conn, %{"title" => title}) do
 594     with {:ok, %Pleroma.List{} = list} <- Pleroma.List.create(title, user) do
 595       res = ListView.render("list.json", list: list)
 596       json(conn, res)
 597     end
 598   end
 599
 600   def add_to_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 601     accounts
 602     |> Enum.each(fn account_id ->
 603       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 604            %User{} = followed <- Repo.get(User, account_id) do
 605         Pleroma.List.follow(list, followed)
 606       end
 607     end)
 608
 609     json(conn, %{})
 610   end
 611
 612   def remove_from_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 613     accounts
 614     |> Enum.each(fn account_id ->
 615       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 616            %User{} = followed <- Repo.get(Pleroma.User, account_id) do
 617         Pleroma.List.unfollow(list, followed)
 618       end
 619     end)
 620
 621     json(conn, %{})
 622   end
 623
 624   def list_accounts(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 625     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 626          {:ok, users} = Pleroma.List.get_following(list) do
 627       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 628     end
 629   end
 630
 631   def rename_list(%{assigns: %{user: user}} = conn, %{"id" => id, "title" => title}) do
 632     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 633          {:ok, list} <- Pleroma.List.rename(list, title) do
 634       res = ListView.render("list.json", list: list)
 635       json(conn, res)
 636     else
 637       _e ->
 638         json(conn, "error")
 639     end
 640   end
 641
 642   def list_timeline(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 643     with %Pleroma.List{title: title, following: following} <- Pleroma.List.get(id, user) do
 644       params =
 645         params
 646         |> Map.put("type", "Create")
 647         |> Map.put("blocking_user", user)
 648
 649       # adding title is a hack to not make empty lists function like a public timeline
 650       activities =
 651         ActivityPub.fetch_activities([title | following], params)
 652         |> Enum.reverse()
 653
 654       conn
 655       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 656     else
 657       _e ->
 658         conn
 659         |> put_status(403)
 660         |> json(%{error: "Error."})
 661     end
 662   end
 663
 664   def index(%{assigns: %{user: user}} = conn, _params) do
 665     token =
 666       conn
 667       |> get_session(:oauth_token)
 668
 669     if user && token do
 670       mastodon_emoji = mastodonized_emoji()
 671       accounts = Map.put(%{}, user.id, AccountView.render("account.json", %{user: user}))
 672
 673       initial_state =
 674         %{
 675           meta: %{
 676             streaming_api_base_url:
 677               String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 678             access_token: token,
 679             locale: "en",
 680             domain: Pleroma.Web.Endpoint.host(),
 681             admin: "1",
 682             me: "#{user.id}",
 683             unfollow_modal: false,
 684             boost_modal: false,
 685             delete_modal: true,
 686             auto_play_gif: false,
 687             reduce_motion: false
 688           },
 689           compose: %{
 690             me: "#{user.id}",
 691             default_privacy: "public",
 692             default_sensitive: false
 693           },
 694           media_attachments: %{
 695             accept_content_types: [
 696               ".jpg",
 697               ".jpeg",
 698               ".png",
 699               ".gif",
 700               ".webm",
 701               ".mp4",
 702               ".m4v",
 703               "image\/jpeg",
 704               "image\/png",
 705               "image\/gif",
 706               "video\/webm",
 707               "video\/mp4"
 708             ]
 709           },
 710           settings:
 711             Map.get(user.info, "settings") ||
 712               %{
 713                 onboarded: true,
 714                 home: %{
 715                   shows: %{
 716                     reblog: true,
 717                     reply: true
 718                   }
 719                 },
 720                 notifications: %{
 721                   alerts: %{
 722                     follow: true,
 723                     favourite: true,
 724                     reblog: true,
 725                     mention: true
 726                   },
 727                   shows: %{
 728                     follow: true,
 729                     favourite: true,
 730                     reblog: true,
 731                     mention: true
 732                   },
 733                   sounds: %{
 734                     follow: true,
 735                     favourite: true,
 736                     reblog: true,
 737                     mention: true
 738                   }
 739                 }
 740               },
 741           push_subscription: nil,
 742           accounts: accounts,
 743           custom_emojis: mastodon_emoji,
 744           char_limit: Keyword.get(@instance, :limit)
 745         }
 746         |> Jason.encode!()
 747
 748       conn
 749       |> put_layout(false)
 750       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 751     else
 752       conn
 753       |> redirect(to: "/web/login")
 754     end
 755   end
 756
 757   def put_settings(%{assigns: %{user: user}} = conn, %{"data" => settings} = _params) do
 758     with new_info <- Map.put(user.info, "settings", settings),
 759          change <- User.info_changeset(user, %{info: new_info}),
 760          {:ok, _user} <- User.update_and_set_cache(change) do
 761       conn
 762       |> json(%{})
 763     else
 764       e ->
 765         conn
 766         |> json(%{error: inspect(e)})
 767     end
 768   end
 769
 770   def login(conn, _) do
 771     conn
 772     |> render(MastodonView, "login.html", %{error: false})
 773   end
 774
 775   defp get_or_make_app() do
 776     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 777       {:ok, app}
 778     else
 779       _e ->
 780         cs =
 781           App.register_changeset(%App{}, %{
 782             client_name: "Mastodon-Local",
 783             redirect_uris: ".",
 784             scopes: "read,write,follow"
 785           })
 786
 787         Repo.insert(cs)
 788     end
 789   end
 790
 791   def login_post(conn, %{"authorization" => %{"name" => name, "password" => password}}) do
 792     with %User{} = user <- User.get_by_nickname_or_email(name),
 793          true <- Pbkdf2.checkpw(password, user.password_hash),
 794          {:ok, app} <- get_or_make_app(),
 795          {:ok, auth} <- Authorization.create_authorization(app, user),
 796          {:ok, token} <- Token.exchange_token(app, auth) do
 797       conn
 798       |> put_session(:oauth_token, token.token)
 799       |> redirect(to: "/web/getting-started")
 800     else
 801       _e ->
 802         conn
 803         |> render(MastodonView, "login.html", %{error: "Wrong username or password"})
 804     end
 805   end
 806
 807   def logout(conn, _) do
 808     conn
 809     |> clear_session
 810     |> redirect(to: "/")
 811   end
 812
 813   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 814     Logger.debug("Unimplemented, returning unmodified relationship")
 815
 816     with %User{} = target <- Repo.get(User, id) do
 817       render(conn, AccountView, "relationship.json", %{user: user, target: target})
 818     end
 819   end
 820
 821   def empty_array(conn, _) do
 822     Logger.debug("Unimplemented, returning an empty array")
 823     json(conn, [])
 824   end
 825
 826   def empty_object(conn, _) do
 827     Logger.debug("Unimplemented, returning an empty object")
 828     json(conn, %{})
 829   end
 830
 831   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
 832     actor = User.get_cached_by_ap_id(activity.data["actor"])
 833
 834     created_at =
 835       NaiveDateTime.to_iso8601(created_at)
 836       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 837
 838     case activity.data["type"] do
 839       "Create" ->
 840         %{
 841           id: id,
 842           type: "mention",
 843           created_at: created_at,
 844           account: AccountView.render("account.json", %{user: actor}),
 845           status: StatusView.render("status.json", %{activity: activity, for: user})
 846         }
 847
 848       "Like" ->
 849         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 850
 851         %{
 852           id: id,
 853           type: "favourite",
 854           created_at: created_at,
 855           account: AccountView.render("account.json", %{user: actor}),
 856           status: StatusView.render("status.json", %{activity: liked_activity, for: user})
 857         }
 858
 859       "Announce" ->
 860         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 861
 862         %{
 863           id: id,
 864           type: "reblog",
 865           created_at: created_at,
 866           account: AccountView.render("account.json", %{user: actor}),
 867           status: StatusView.render("status.json", %{activity: announced_activity, for: user})
 868         }
 869
 870       "Follow" ->
 871         %{
 872           id: id,
 873           type: "follow",
 874           created_at: created_at,
 875           account: AccountView.render("account.json", %{user: actor})
 876         }
 877
 878       _ ->
 879         nil
 880     end
 881   end
 882 end