git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification, Stats}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.{CommonAPI, OStatus}
   8   alias Pleroma.Web.OAuth.{Authorization, Token, App}
   9   alias Comeonin.Pbkdf2
  10   import Ecto.Query
  11   require Logger
  12
  13   def create_app(conn, params) do
  14     with cs <- App.register_changeset(%App{}, params) |> IO.inspect(),
  15          {:ok, app} <- Repo.insert(cs) |> IO.inspect() do
  16       res = %{
  17         id: app.id,
  18         client_id: app.client_id,
  19         client_secret: app.client_secret
  20       }
  21
  22       json(conn, res)
  23     end
  24   end
  25
  26   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  27     original_user = user
  28
  29     params =
  30       if bio = params["note"] do
  31         Map.put(params, "bio", bio)
  32       else
  33         params
  34       end
  35
  36     params =
  37       if name = params["display_name"] do
  38         Map.put(params, "name", name)
  39       else
  40         params
  41       end
  42
  43     user =
  44       if avatar = params["avatar"] do
  45         with %Plug.Upload{} <- avatar,
  46              {:ok, object} <- ActivityPub.upload(avatar),
  47              change = Ecto.Changeset.change(user, %{avatar: object.data}),
  48              {:ok, user} = User.update_and_set_cache(change) do
  49           user
  50         else
  51           _e -> user
  52         end
  53       else
  54         user
  55       end
  56
  57     user =
  58       if banner = params["header"] do
  59         with %Plug.Upload{} <- banner,
  60              {:ok, object} <- ActivityPub.upload(banner),
  61              new_info <- Map.put(user.info, "banner", object.data),
  62              change <- User.info_changeset(user, %{info: new_info}),
  63              {:ok, user} <- User.update_and_set_cache(change) do
  64           user
  65         else
  66           _e -> user
  67         end
  68       else
  69         user
  70       end
  71
  72     with changeset <- User.update_changeset(user, params),
  73          {:ok, user} <- User.update_and_set_cache(changeset) do
  74       if original_user != user do
  75         CommonAPI.update(user)
  76       end
  77
  78       json(conn, AccountView.render("account.json", %{user: user}))
  79     else
  80       _e ->
  81         conn
  82         |> put_status(403)
  83         |> json(%{error: "Invalid request"})
  84     end
  85   end
  86
  87   def verify_credentials(%{assigns: %{user: user}} = conn, _) do
  88     account = AccountView.render("account.json", %{user: user})
  89     json(conn, account)
  90   end
  91
  92   def user(conn, %{"id" => id}) do
  93     with %User{} = user <- Repo.get(User, id) do
  94       account = AccountView.render("account.json", %{user: user})
  95       json(conn, account)
  96     else
  97       _e ->
  98         conn
  99         |> put_status(404)
 100         |> json(%{error: "Can't find user"})
 101     end
 102   end
 103
 104   @instance Application.get_env(:pleroma, :instance)
 105   @mastodon_api_level "2.3.3"
 106
 107   def masto_instance(conn, _params) do
 108     response = %{
 109       uri: Web.base_url(),
 110       title: Keyword.get(@instance, :name),
 111       description: "A Pleroma instance, an alternative fediverse server",
 112       version: "#{@mastodon_api_level} (compatible; #{Keyword.get(@instance, :version)})",
 113       email: Keyword.get(@instance, :email),
 114       urls: %{
 115         streaming_api: String.replace(Web.base_url(), ["http", "https"], "wss")
 116       },
 117       stats: Stats.get_stats(),
 118       thumbnail: Web.base_url() <> "/instance/thumbnail.jpeg",
 119       max_toot_chars: Keyword.get(@instance, :limit)
 120     }
 121
 122     json(conn, response)
 123   end
 124
 125   def peers(conn, _params) do
 126     json(conn, Stats.get_peers())
 127   end
 128
 129   defp mastodonized_emoji do
 130     Pleroma.Formatter.get_custom_emoji()
 131     |> Enum.map(fn {shortcode, relative_url} ->
 132       url = to_string(URI.merge(Web.base_url(), relative_url))
 133
 134       %{
 135         "shortcode" => shortcode,
 136         "static_url" => url,
 137         "url" => url
 138       }
 139     end)
 140   end
 141
 142   def custom_emojis(conn, _params) do
 143     mastodon_emoji = mastodonized_emoji()
 144     json(conn, mastodon_emoji)
 145   end
 146
 147   defp add_link_headers(conn, method, activities, param \\ false) do
 148     last = List.last(activities)
 149     first = List.first(activities)
 150
 151     if last do
 152       min = last.id
 153       max = first.id
 154
 155       {next_url, prev_url} =
 156         if param do
 157           {
 158             mastodon_api_url(Pleroma.Web.Endpoint, method, param, max_id: min),
 159             mastodon_api_url(Pleroma.Web.Endpoint, method, param, since_id: max)
 160           }
 161         else
 162           {
 163             mastodon_api_url(Pleroma.Web.Endpoint, method, max_id: min),
 164             mastodon_api_url(Pleroma.Web.Endpoint, method, since_id: max)
 165           }
 166         end
 167
 168       conn
 169       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 170     else
 171       conn
 172     end
 173   end
 174
 175   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 176     params =
 177       params
 178       |> Map.put("type", ["Create", "Announce"])
 179       |> Map.put("blocking_user", user)
 180       |> Map.put("user", user)
 181
 182     activities =
 183       ActivityPub.fetch_activities([user.ap_id | user.following], params)
 184       |> Enum.reverse()
 185
 186     conn
 187     |> add_link_headers(:home_timeline, activities)
 188     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 189   end
 190
 191   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 192     params =
 193       params
 194       |> Map.put("type", ["Create", "Announce"])
 195       |> Map.put("local_only", params["local"] in [true, "True", "true", "1"])
 196       |> Map.put("blocking_user", user)
 197
 198     activities =
 199       ActivityPub.fetch_public_activities(params)
 200       |> Enum.reverse()
 201
 202     conn
 203     |> add_link_headers(:public_timeline, activities)
 204     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 205   end
 206
 207   def user_statuses(%{assigns: %{user: user}} = conn, params) do
 208     with %User{ap_id: ap_id} <- Repo.get(User, params["id"]) do
 209       params =
 210         params
 211         |> Map.put("type", ["Create", "Announce"])
 212         |> Map.put("actor_id", ap_id)
 213         |> Map.put("whole_db", true)
 214
 215       if params["pinned"] == "true" do
 216         # Since Pleroma has no "pinned" posts feature, we'll just set an empty list here
 217         activities = []
 218       else
 219         activities =
 220          ActivityPub.fetch_public_activities(params)
 221          |> Enum.reverse()
 222       end
 223
 224       conn
 225       |> add_link_headers(:user_statuses, activities, params["id"])
 226       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 227     end
 228   end
 229
 230   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 231     with %Activity{} = activity <- Repo.get(Activity, id),
 232          true <- ActivityPub.visible_for_user?(activity, user) do
 233       render(conn, StatusView, "status.json", %{activity: activity, for: user})
 234     end
 235   end
 236
 237   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 238     with %Activity{} = activity <- Repo.get(Activity, id),
 239          activities <-
 240            ActivityPub.fetch_activities_for_context(activity.data["context"], %{
 241              "blocking_user" => user,
 242              "user" => user
 243            }),
 244          activities <-
 245            activities |> Enum.filter(fn %{id: aid} -> to_string(aid) != to_string(id) end),
 246          activities <-
 247            activities |> Enum.filter(fn %{data: %{"type" => type}} -> type == "Create" end),
 248          grouped_activities <- Enum.group_by(activities, fn %{id: id} -> id < activity.id end) do
 249       result = %{
 250         ancestors:
 251           StatusView.render(
 252             "index.json",
 253             for: user,
 254             activities: grouped_activities[true] || [],
 255             as: :activity
 256           )
 257           |> Enum.reverse(),
 258         descendants:
 259           StatusView.render(
 260             "index.json",
 261             for: user,
 262             activities: grouped_activities[false] || [],
 263             as: :activity
 264           )
 265           |> Enum.reverse()
 266       }
 267
 268       json(conn, result)
 269     end
 270   end
 271
 272   def post_status(%{assigns: %{user: user}} = conn, %{"status" => _} = params) do
 273     params =
 274       params
 275       |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 276       |> Map.put("no_attachment_links", true)
 277
 278     {:ok, activity} = CommonAPI.post(user, params)
 279     render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 280   end
 281
 282   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 283     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 284       json(conn, %{})
 285     else
 286       _e ->
 287         conn
 288         |> put_status(403)
 289         |> json(%{error: "Can't delete this post"})
 290     end
 291   end
 292
 293   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 294     with {:ok, announce, _activity} = CommonAPI.repeat(ap_id_or_id, user) do
 295       render(conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity})
 296     end
 297   end
 298
 299   def unreblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 300     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unrepeat(ap_id_or_id, user),
 301          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 302       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 303     end
 304   end
 305
 306   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 307     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 308          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 309       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 310     end
 311   end
 312
 313   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 314     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 315          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 316       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 317     end
 318   end
 319
 320   def notifications(%{assigns: %{user: user}} = conn, params) do
 321     notifications = Notification.for_user(user, params)
 322
 323     result =
 324       Enum.map(notifications, fn x ->
 325         render_notification(user, x)
 326       end)
 327       |> Enum.filter(& &1)
 328
 329     conn
 330     |> add_link_headers(:notifications, notifications)
 331     |> json(result)
 332   end
 333
 334   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 335     with {:ok, notification} <- Notification.get(user, id) do
 336       json(conn, render_notification(user, notification))
 337     else
 338       {:error, reason} ->
 339         conn
 340         |> put_resp_content_type("application/json")
 341         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 342     end
 343   end
 344
 345   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 346     Notification.clear(user)
 347     json(conn, %{})
 348   end
 349
 350   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 351     with {:ok, _notif} <- Notification.dismiss(user, id) do
 352       json(conn, %{})
 353     else
 354       {:error, reason} ->
 355         conn
 356         |> put_resp_content_type("application/json")
 357         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 358     end
 359   end
 360
 361   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 362     id = List.wrap(id)
 363     q = from(u in User, where: u.id in ^id)
 364     targets = Repo.all(q)
 365     render(conn, AccountView, "relationships.json", %{user: user, targets: targets})
 366   end
 367
 368   def upload(%{assigns: %{user: _}} = conn, %{"file" => file}) do
 369     with {:ok, object} <- ActivityPub.upload(file) do
 370       data =
 371         object.data
 372         |> Map.put("id", object.id)
 373
 374       render(conn, StatusView, "attachment.json", %{attachment: data})
 375     end
 376   end
 377
 378   def favourited_by(conn, %{"id" => id}) do
 379     with %Activity{data: %{"object" => %{"likes" => likes}}} <- Repo.get(Activity, id) do
 380       q = from(u in User, where: u.ap_id in ^likes)
 381       users = Repo.all(q)
 382       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 383     else
 384       _ -> json(conn, [])
 385     end
 386   end
 387
 388   def reblogged_by(conn, %{"id" => id}) do
 389     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 390       q = from(u in User, where: u.ap_id in ^announces)
 391       users = Repo.all(q)
 392       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 393     else
 394       _ -> json(conn, [])
 395     end
 396   end
 397
 398   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 399     params =
 400       params
 401       |> Map.put("type", "Create")
 402       |> Map.put("local_only", !!params["local"])
 403       |> Map.put("blocking_user", user)
 404
 405     activities =
 406       ActivityPub.fetch_public_activities(params)
 407       |> Enum.reverse()
 408
 409     conn
 410     |> add_link_headers(:hashtag_timeline, activities, params["tag"])
 411     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 412   end
 413
 414   # TODO: Pagination
 415   def followers(conn, %{"id" => id}) do
 416     with %User{} = user <- Repo.get(User, id),
 417          {:ok, followers} <- User.get_followers(user) do
 418       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 419     end
 420   end
 421
 422   def following(conn, %{"id" => id}) do
 423     with %User{} = user <- Repo.get(User, id),
 424          {:ok, followers} <- User.get_friends(user) do
 425       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 426     end
 427   end
 428
 429   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 430     with %User{} = followed <- Repo.get(User, id),
 431          {:ok, follower} <- User.follow(follower, followed),
 432          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 433       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 434     else
 435       {:error, message} ->
 436         conn
 437         |> put_resp_content_type("application/json")
 438         |> send_resp(403, Jason.encode!(%{"error" => message}))
 439     end
 440   end
 441
 442   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 443     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 444          {:ok, follower} <- User.follow(follower, followed),
 445          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 446       render(conn, AccountView, "account.json", %{user: followed})
 447     else
 448       {:error, message} ->
 449         conn
 450         |> put_resp_content_type("application/json")
 451         |> send_resp(403, Jason.encode!(%{"error" => message}))
 452     end
 453   end
 454
 455   # TODO: Clean up and unify
 456   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 457     with %User{} = followed <- Repo.get(User, id),
 458          {:ok, follower, follow_activity} <- User.unfollow(follower, followed),
 459          {:ok, _activity} <-
 460            ActivityPub.insert(%{
 461              "type" => "Undo",
 462              "actor" => follower.ap_id,
 463              # get latest Follow for these users
 464              "object" => follow_activity.data["id"]
 465            }) do
 466       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 467     end
 468   end
 469
 470   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 471     with %User{} = blocked <- Repo.get(User, id),
 472          {:ok, blocker} <- User.block(blocker, blocked) do
 473       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 474     else
 475       {:error, message} ->
 476         conn
 477         |> put_resp_content_type("application/json")
 478         |> send_resp(403, Jason.encode!(%{"error" => message}))
 479     end
 480   end
 481
 482   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 483     with %User{} = blocked <- Repo.get(User, id),
 484          {:ok, blocker} <- User.unblock(blocker, blocked) do
 485       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 486     else
 487       {:error, message} ->
 488         conn
 489         |> put_resp_content_type("application/json")
 490         |> send_resp(403, Jason.encode!(%{"error" => message}))
 491     end
 492   end
 493
 494   # TODO: Use proper query
 495   def blocks(%{assigns: %{user: user}} = conn, _) do
 496     with blocked_users <- user.info["blocks"] || [],
 497          accounts <- Enum.map(blocked_users, fn ap_id -> User.get_cached_by_ap_id(ap_id) end) do
 498       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 499       json(conn, res)
 500     end
 501   end
 502
 503   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 504     accounts = User.search(query, params["resolve"] == "true")
 505
 506     fetched =
 507       if Regex.match?(~r/https?:/, query) do
 508         with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 509           activities
 510           |> Enum.filter(fn
 511             %{data: %{"type" => "Create"}} -> true
 512             _ -> false
 513           end)
 514         else
 515           _e -> []
 516         end
 517       end || []
 518
 519     q =
 520       from(
 521         a in Activity,
 522         where: fragment("?->>'type' = 'Create'", a.data),
 523         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 524         where:
 525           fragment(
 526             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 527             a.data,
 528             ^query
 529           ),
 530         limit: 20,
 531         order_by: [desc: :inserted_at]
 532       )
 533
 534     statuses = Repo.all(q) ++ fetched
 535
 536     tags =
 537       String.split(query)
 538       |> Enum.uniq()
 539       |> Enum.filter(fn tag -> String.starts_with?(tag, "#") end)
 540       |> Enum.map(fn tag -> String.slice(tag, 1..-1) end)
 541
 542     res = %{
 543       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 544       "statuses" =>
 545         StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 546       "hashtags" => tags
 547     }
 548
 549     json(conn, res)
 550   end
 551
 552   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 553     accounts = User.search(query, params["resolve"] == "true")
 554
 555     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 556
 557     json(conn, res)
 558   end
 559
 560   def favourites(%{assigns: %{user: user}} = conn, _) do
 561     params =
 562       %{}
 563       |> Map.put("type", "Create")
 564       |> Map.put("favorited_by", user.ap_id)
 565       |> Map.put("blocking_user", user)
 566
 567     activities =
 568       ActivityPub.fetch_public_activities(params)
 569       |> Enum.reverse()
 570
 571     conn
 572     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 573   end
 574
 575   def index(%{assigns: %{user: user}} = conn, _params) do
 576     token =
 577       conn
 578       |> get_session(:oauth_token)
 579
 580     if user && token do
 581       mastodon_emoji = mastodonized_emoji()
 582       accounts = Map.put(%{}, user.id, AccountView.render("account.json", %{user: user}))
 583
 584       initial_state =
 585         %{
 586           meta: %{
 587             streaming_api_base_url:
 588               String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 589             access_token: token,
 590             locale: "en",
 591             domain: Pleroma.Web.Endpoint.host(),
 592             admin: "1",
 593             me: "#{user.id}",
 594             unfollow_modal: false,
 595             boost_modal: false,
 596             delete_modal: true,
 597             auto_play_gif: false,
 598             reduce_motion: false
 599           },
 600           compose: %{
 601             me: "#{user.id}",
 602             default_privacy: "public",
 603             default_sensitive: false
 604           },
 605           media_attachments: %{
 606             accept_content_types: [
 607               ".jpg",
 608               ".jpeg",
 609               ".png",
 610               ".gif",
 611               ".webm",
 612               ".mp4",
 613               ".m4v",
 614               "image\/jpeg",
 615               "image\/png",
 616               "image\/gif",
 617               "video\/webm",
 618               "video\/mp4"
 619             ]
 620           },
 621           settings:
 622             Map.get(user.info, "settings") ||
 623               %{
 624                 onboarded: true,
 625                 home: %{
 626                   shows: %{
 627                     reblog: true,
 628                     reply: true
 629                   }
 630                 },
 631                 notifications: %{
 632                   alerts: %{
 633                     follow: true,
 634                     favourite: true,
 635                     reblog: true,
 636                     mention: true
 637                   },
 638                   shows: %{
 639                     follow: true,
 640                     favourite: true,
 641                     reblog: true,
 642                     mention: true
 643                   },
 644                   sounds: %{
 645                     follow: true,
 646                     favourite: true,
 647                     reblog: true,
 648                     mention: true
 649                   }
 650                 }
 651               },
 652           push_subscription: nil,
 653           accounts: accounts,
 654           custom_emojis: mastodon_emoji,
 655           char_limit: Keyword.get(@instance, :limit)
 656         }
 657         |> Jason.encode!()
 658
 659       conn
 660       |> put_layout(false)
 661       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 662     else
 663       conn
 664       |> redirect(to: "/web/login")
 665     end
 666   end
 667
 668   def put_settings(%{assigns: %{user: user}} = conn, %{"data" => settings} = _params) do
 669     with new_info <- Map.put(user.info, "settings", settings),
 670          change <- User.info_changeset(user, %{info: new_info}),
 671          {:ok, _user} <- User.update_and_set_cache(change) do
 672       conn
 673       |> json(%{})
 674     else
 675       e ->
 676         conn
 677         |> json(%{error: inspect(e)})
 678     end
 679   end
 680
 681   def login(conn, _) do
 682     conn
 683     |> render(MastodonView, "login.html", %{error: false})
 684   end
 685
 686   defp get_or_make_app() do
 687     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 688       {:ok, app}
 689     else
 690       _e ->
 691         cs =
 692           App.register_changeset(%App{}, %{
 693             client_name: "Mastodon-Local",
 694             redirect_uris: ".",
 695             scopes: "read,write,follow"
 696           })
 697
 698         Repo.insert(cs)
 699     end
 700   end
 701
 702   def login_post(conn, %{"authorization" => %{"name" => name, "password" => password}}) do
 703     with %User{} = user <- User.get_cached_by_nickname(name),
 704          true <- Pbkdf2.checkpw(password, user.password_hash),
 705          {:ok, app} <- get_or_make_app(),
 706          {:ok, auth} <- Authorization.create_authorization(app, user),
 707          {:ok, token} <- Token.exchange_token(app, auth) do
 708       conn
 709       |> put_session(:oauth_token, token.token)
 710       |> redirect(to: "/web/getting-started")
 711     else
 712       _e ->
 713         conn
 714         |> render(MastodonView, "login.html", %{error: "Wrong username or password"})
 715     end
 716   end
 717
 718   def logout(conn, _) do
 719     conn
 720     |> clear_session
 721     |> redirect(to: "/")
 722   end
 723
 724   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 725     Logger.debug("Unimplemented, returning unmodified relationship")
 726
 727     with %User{} = target <- Repo.get(User, id) do
 728       render(conn, AccountView, "relationship.json", %{user: user, target: target})
 729     end
 730   end
 731
 732   def empty_array(conn, _) do
 733     Logger.debug("Unimplemented, returning an empty array")
 734     json(conn, [])
 735   end
 736
 737   def empty_object(conn, _) do
 738     Logger.debug("Unimplemented, returning an empty object")
 739     json(conn, %{})
 740   end
 741
 742   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
 743     actor = User.get_cached_by_ap_id(activity.data["actor"])
 744
 745     created_at =
 746       NaiveDateTime.to_iso8601(created_at)
 747       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 748
 749     case activity.data["type"] do
 750       "Create" ->
 751         %{
 752           id: id,
 753           type: "mention",
 754           created_at: created_at,
 755           account: AccountView.render("account.json", %{user: actor}),
 756           status: StatusView.render("status.json", %{activity: activity, for: user})
 757         }
 758
 759       "Like" ->
 760         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 761
 762         %{
 763           id: id,
 764           type: "favourite",
 765           created_at: created_at,
 766           account: AccountView.render("account.json", %{user: actor}),
 767           status: StatusView.render("status.json", %{activity: liked_activity, for: user})
 768         }
 769
 770       "Announce" ->
 771         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 772
 773         %{
 774           id: id,
 775           type: "reblog",
 776           created_at: created_at,
 777           account: AccountView.render("account.json", %{user: actor}),
 778           status: StatusView.render("status.json", %{activity: announced_activity, for: user})
 779         }
 780
 781       "Follow" ->
 782         %{
 783           id: id,
 784           type: "follow",
 785           created_at: created_at,
 786           account: AccountView.render("account.json", %{user: actor})
 787         }
 788
 789       _ ->
 790         nil
 791     end
 792   end
 793 end