git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification, Stats}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView, ListView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.{CommonAPI, OStatus}
   8   alias Pleroma.Web.OAuth.{Authorization, Token, App}
   9   alias Comeonin.Pbkdf2
  10   import Ecto.Query
  11   require Logger
  12
  13   def create_app(conn, params) do
  14     with cs <- App.register_changeset(%App{}, params) |> IO.inspect(),
  15          {:ok, app} <- Repo.insert(cs) |> IO.inspect() do
  16       res = %{
  17         id: app.id,
  18         client_id: app.client_id,
  19         client_secret: app.client_secret
  20       }
  21
  22       json(conn, res)
  23     end
  24   end
  25
  26   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  27     original_user = user
  28
  29     params =
  30       if bio = params["note"] do
  31         Map.put(params, "bio", bio)
  32       else
  33         params
  34       end
  35
  36     params =
  37       if name = params["display_name"] do
  38         Map.put(params, "name", name)
  39       else
  40         params
  41       end
  42
  43     user =
  44       if avatar = params["avatar"] do
  45         with %Plug.Upload{} <- avatar,
  46              {:ok, object} <- ActivityPub.upload(avatar),
  47              change = Ecto.Changeset.change(user, %{avatar: object.data}),
  48              {:ok, user} = User.update_and_set_cache(change) do
  49           user
  50         else
  51           _e -> user
  52         end
  53       else
  54         user
  55       end
  56
  57     user =
  58       if banner = params["header"] do
  59         with %Plug.Upload{} <- banner,
  60              {:ok, object} <- ActivityPub.upload(banner),
  61              new_info <- Map.put(user.info, "banner", object.data),
  62              change <- User.info_changeset(user, %{info: new_info}),
  63              {:ok, user} <- User.update_and_set_cache(change) do
  64           user
  65         else
  66           _e -> user
  67         end
  68       else
  69         user
  70       end
  71
  72     with changeset <- User.update_changeset(user, params),
  73          {:ok, user} <- User.update_and_set_cache(changeset) do
  74       if original_user != user do
  75         CommonAPI.update(user)
  76       end
  77
  78       json(conn, AccountView.render("account.json", %{user: user}))
  79     else
  80       _e ->
  81         conn
  82         |> put_status(403)
  83         |> json(%{error: "Invalid request"})
  84     end
  85   end
  86
  87   def verify_credentials(%{assigns: %{user: user}} = conn, _) do
  88     account = AccountView.render("account.json", %{user: user})
  89     json(conn, account)
  90   end
  91
  92   def user(conn, %{"id" => id}) do
  93     with %User{} = user <- Repo.get(User, id) do
  94       account = AccountView.render("account.json", %{user: user})
  95       json(conn, account)
  96     else
  97       _e ->
  98         conn
  99         |> put_status(404)
 100         |> json(%{error: "Can't find user"})
 101     end
 102   end
 103
 104   @instance Application.get_env(:pleroma, :instance)
 105   @mastodon_api_level "2.3.3"
 106
 107   def masto_instance(conn, _params) do
 108     response = %{
 109       uri: Web.base_url(),
 110       title: Keyword.get(@instance, :name),
 111       description: "A Pleroma instance, an alternative fediverse server",
 112       version: "#{@mastodon_api_level} (compatible; #{Keyword.get(@instance, :version)})",
 113       email: Keyword.get(@instance, :email),
 114       urls: %{
 115         streaming_api: String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws")
 116       },
 117       stats: Stats.get_stats(),
 118       thumbnail: Web.base_url() <> "/instance/thumbnail.jpeg",
 119       max_toot_chars: Keyword.get(@instance, :limit)
 120     }
 121
 122     json(conn, response)
 123   end
 124
 125   def peers(conn, _params) do
 126     json(conn, Stats.get_peers())
 127   end
 128
 129   defp mastodonized_emoji do
 130     Pleroma.Formatter.get_custom_emoji()
 131     |> Enum.map(fn {shortcode, relative_url} ->
 132       url = to_string(URI.merge(Web.base_url(), relative_url))
 133
 134       %{
 135         "shortcode" => shortcode,
 136         "static_url" => url,
 137         "url" => url
 138       }
 139     end)
 140   end
 141
 142   def custom_emojis(conn, _params) do
 143     mastodon_emoji = mastodonized_emoji()
 144     json(conn, mastodon_emoji)
 145   end
 146
 147   defp add_link_headers(conn, method, activities, param \\ nil, params \\ %{}) do
 148     last = List.last(activities)
 149     first = List.first(activities)
 150
 151     if last do
 152       min = last.id
 153       max = first.id
 154
 155       {next_url, prev_url} =
 156         if param do
 157           {
 158             mastodon_api_url(
 159               Pleroma.Web.Endpoint,
 160               method,
 161               param,
 162               Map.merge(params, %{max_id: min})
 163             ),
 164             mastodon_api_url(
 165               Pleroma.Web.Endpoint,
 166               method,
 167               param,
 168               Map.merge(params, %{since_id: max})
 169             )
 170           }
 171         else
 172           {
 173             mastodon_api_url(
 174               Pleroma.Web.Endpoint,
 175               method,
 176               Map.merge(params, %{max_id: min})
 177             ),
 178             mastodon_api_url(
 179               Pleroma.Web.Endpoint,
 180               method,
 181               Map.merge(params, %{since_id: max})
 182             )
 183           }
 184         end
 185
 186       conn
 187       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 188     else
 189       conn
 190     end
 191   end
 192
 193   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 194     params =
 195       params
 196       |> Map.put("type", ["Create", "Announce"])
 197       |> Map.put("blocking_user", user)
 198       |> Map.put("user", user)
 199
 200     activities =
 201       ActivityPub.fetch_activities([user.ap_id | user.following], params)
 202       |> Enum.reverse()
 203
 204     conn
 205     |> add_link_headers(:home_timeline, activities)
 206     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 207   end
 208
 209   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 210     local_only = params["local"] in [true, "True", "true", "1"]
 211
 212     params =
 213       params
 214       |> Map.put("type", ["Create", "Announce"])
 215       |> Map.put("local_only", local_only)
 216       |> Map.put("blocking_user", user)
 217
 218     activities =
 219       ActivityPub.fetch_public_activities(params)
 220       |> Enum.reverse()
 221
 222     conn
 223     |> add_link_headers(:public_timeline, activities, false, %{"local" => local_only})
 224     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 225   end
 226
 227   def user_statuses(%{assigns: %{user: reading_user}} = conn, params) do
 228     with %User{} = user <- Repo.get(User, params["id"]) do
 229       # Since Pleroma has no "pinned" posts feature, we'll just set an empty list here
 230       activities =
 231         if params["pinned"] == "true" do
 232           []
 233         else
 234           ActivityPub.fetch_user_activities(user, reading_user, params)
 235         end
 236
 237       conn
 238       |> add_link_headers(:user_statuses, activities, params["id"])
 239       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 240     end
 241   end
 242
 243   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 244     query =
 245       ActivityPub.fetch_activities_query([user.ap_id], %{"type" => "Create", visibility: "direct"})
 246
 247     activities = Repo.all(query)
 248
 249     conn
 250     |> add_link_headers(:dm_timeline, activities)
 251     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 252   end
 253
 254   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 255     with %Activity{} = activity <- Repo.get(Activity, id),
 256          true <- ActivityPub.visible_for_user?(activity, user) do
 257       render(conn, StatusView, "status.json", %{activity: activity, for: user})
 258     end
 259   end
 260
 261   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 262     with %Activity{} = activity <- Repo.get(Activity, id),
 263          activities <-
 264            ActivityPub.fetch_activities_for_context(activity.data["context"], %{
 265              "blocking_user" => user,
 266              "user" => user
 267            }),
 268          activities <-
 269            activities |> Enum.filter(fn %{id: aid} -> to_string(aid) != to_string(id) end),
 270          activities <-
 271            activities |> Enum.filter(fn %{data: %{"type" => type}} -> type == "Create" end),
 272          grouped_activities <- Enum.group_by(activities, fn %{id: id} -> id < activity.id end) do
 273       result = %{
 274         ancestors:
 275           StatusView.render(
 276             "index.json",
 277             for: user,
 278             activities: grouped_activities[true] || [],
 279             as: :activity
 280           )
 281           |> Enum.reverse(),
 282         descendants:
 283           StatusView.render(
 284             "index.json",
 285             for: user,
 286             activities: grouped_activities[false] || [],
 287             as: :activity
 288           )
 289           |> Enum.reverse()
 290       }
 291
 292       json(conn, result)
 293     end
 294   end
 295
 296   def post_status(%{assigns: %{user: user}} = conn, %{"status" => _} = params) do
 297     params =
 298       params
 299       |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 300       |> Map.put("no_attachment_links", true)
 301
 302     idempotency_key =
 303       case get_req_header(conn, "idempotency-key") do
 304         [key] -> key
 305         _ -> Ecto.UUID.generate()
 306       end
 307
 308     {:ok, activity} =
 309       Cachex.fetch!(:idempotency_cache, idempotency_key, fn _ -> CommonAPI.post(user, params) end)
 310
 311     render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 312   end
 313
 314   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 315     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 316       json(conn, %{})
 317     else
 318       _e ->
 319         conn
 320         |> put_status(403)
 321         |> json(%{error: "Can't delete this post"})
 322     end
 323   end
 324
 325   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 326     with {:ok, announce, _activity} = CommonAPI.repeat(ap_id_or_id, user) do
 327       render(conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity})
 328     end
 329   end
 330
 331   def unreblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 332     with {:ok, _, _, %{data: %{"id" => id}}} = CommonAPI.unrepeat(ap_id_or_id, user),
 333          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 334       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 335     end
 336   end
 337
 338   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 339     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 340          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 341       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 342     end
 343   end
 344
 345   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 346     with {:ok, _, _, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 347          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 348       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 349     end
 350   end
 351
 352   def notifications(%{assigns: %{user: user}} = conn, params) do
 353     notifications = Notification.for_user(user, params)
 354
 355     result =
 356       Enum.map(notifications, fn x ->
 357         render_notification(user, x)
 358       end)
 359       |> Enum.filter(& &1)
 360
 361     conn
 362     |> add_link_headers(:notifications, notifications)
 363     |> json(result)
 364   end
 365
 366   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 367     with {:ok, notification} <- Notification.get(user, id) do
 368       json(conn, render_notification(user, notification))
 369     else
 370       {:error, reason} ->
 371         conn
 372         |> put_resp_content_type("application/json")
 373         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 374     end
 375   end
 376
 377   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 378     Notification.clear(user)
 379     json(conn, %{})
 380   end
 381
 382   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 383     with {:ok, _notif} <- Notification.dismiss(user, id) do
 384       json(conn, %{})
 385     else
 386       {:error, reason} ->
 387         conn
 388         |> put_resp_content_type("application/json")
 389         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 390     end
 391   end
 392
 393   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 394     id = List.wrap(id)
 395     q = from(u in User, where: u.id in ^id)
 396     targets = Repo.all(q)
 397     render(conn, AccountView, "relationships.json", %{user: user, targets: targets})
 398   end
 399
 400   def upload(%{assigns: %{user: _}} = conn, %{"file" => file}) do
 401     with {:ok, object} <- ActivityPub.upload(file) do
 402       data =
 403         object.data
 404         |> Map.put("id", object.id)
 405
 406       render(conn, StatusView, "attachment.json", %{attachment: data})
 407     end
 408   end
 409
 410   def favourited_by(conn, %{"id" => id}) do
 411     with %Activity{data: %{"object" => %{"likes" => likes}}} <- Repo.get(Activity, id) do
 412       q = from(u in User, where: u.ap_id in ^likes)
 413       users = Repo.all(q)
 414       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 415     else
 416       _ -> json(conn, [])
 417     end
 418   end
 419
 420   def reblogged_by(conn, %{"id" => id}) do
 421     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 422       q = from(u in User, where: u.ap_id in ^announces)
 423       users = Repo.all(q)
 424       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 425     else
 426       _ -> json(conn, [])
 427     end
 428   end
 429
 430   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 431     local_only = params["local"] in [true, "True", "true", "1"]
 432
 433     params =
 434       params
 435       |> Map.put("type", "Create")
 436       |> Map.put("local_only", local_only)
 437       |> Map.put("blocking_user", user)
 438
 439     activities =
 440       ActivityPub.fetch_public_activities(params)
 441       |> Enum.reverse()
 442
 443     conn
 444     |> add_link_headers(:hashtag_timeline, activities, params["tag"], %{"local" => local_only})
 445     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 446   end
 447
 448   # TODO: Pagination
 449   def followers(conn, %{"id" => id}) do
 450     with %User{} = user <- Repo.get(User, id),
 451          {:ok, followers} <- User.get_followers(user) do
 452       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 453     end
 454   end
 455
 456   def following(conn, %{"id" => id}) do
 457     with %User{} = user <- Repo.get(User, id),
 458          {:ok, followers} <- User.get_friends(user) do
 459       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 460     end
 461   end
 462
 463   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 464     with %User{} = followed <- Repo.get(User, id),
 465          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 466          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 467       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 468     else
 469       {:error, message} ->
 470         conn
 471         |> put_resp_content_type("application/json")
 472         |> send_resp(403, Jason.encode!(%{"error" => message}))
 473     end
 474   end
 475
 476   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 477     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 478          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 479          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 480       render(conn, AccountView, "account.json", %{user: followed})
 481     else
 482       {:error, message} ->
 483         conn
 484         |> put_resp_content_type("application/json")
 485         |> send_resp(403, Jason.encode!(%{"error" => message}))
 486     end
 487   end
 488
 489   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 490     with %User{} = followed <- Repo.get(User, id),
 491          {:ok, _activity} <- ActivityPub.unfollow(follower, followed),
 492          {:ok, follower, _} <- User.unfollow(follower, followed) do
 493       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 494     end
 495   end
 496
 497   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 498     with %User{} = blocked <- Repo.get(User, id),
 499          {:ok, blocker} <- User.block(blocker, blocked),
 500          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
 501       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 502     else
 503       {:error, message} ->
 504         conn
 505         |> put_resp_content_type("application/json")
 506         |> send_resp(403, Jason.encode!(%{"error" => message}))
 507     end
 508   end
 509
 510   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 511     with %User{} = blocked <- Repo.get(User, id),
 512          {:ok, blocker} <- User.unblock(blocker, blocked),
 513          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
 514       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 515     else
 516       {:error, message} ->
 517         conn
 518         |> put_resp_content_type("application/json")
 519         |> send_resp(403, Jason.encode!(%{"error" => message}))
 520     end
 521   end
 522
 523   # TODO: Use proper query
 524   def blocks(%{assigns: %{user: user}} = conn, _) do
 525     with blocked_users <- user.info["blocks"] || [],
 526          accounts <- Enum.map(blocked_users, fn ap_id -> User.get_cached_by_ap_id(ap_id) end) do
 527       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 528       json(conn, res)
 529     end
 530   end
 531
 532   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 533     accounts = User.search(query, params["resolve"] == "true")
 534
 535     fetched =
 536       if Regex.match?(~r/https?:/, query) do
 537         with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 538           activities
 539           |> Enum.filter(fn
 540             %{data: %{"type" => "Create"}} -> true
 541             _ -> false
 542           end)
 543         else
 544           _e -> []
 545         end
 546       end || []
 547
 548     q =
 549       from(
 550         a in Activity,
 551         where: fragment("?->>'type' = 'Create'", a.data),
 552         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 553         where:
 554           fragment(
 555             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 556             a.data,
 557             ^query
 558           ),
 559         limit: 20,
 560         order_by: [desc: :id]
 561       )
 562
 563     statuses = Repo.all(q) ++ fetched
 564
 565     tags =
 566       String.split(query)
 567       |> Enum.uniq()
 568       |> Enum.filter(fn tag -> String.starts_with?(tag, "#") end)
 569       |> Enum.map(fn tag -> String.slice(tag, 1..-1) end)
 570
 571     res = %{
 572       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 573       "statuses" =>
 574         StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 575       "hashtags" => tags
 576     }
 577
 578     json(conn, res)
 579   end
 580
 581   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 582     accounts = User.search(query, params["resolve"] == "true")
 583
 584     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 585
 586     json(conn, res)
 587   end
 588
 589   def favourites(%{assigns: %{user: user}} = conn, _) do
 590     params =
 591       %{}
 592       |> Map.put("type", "Create")
 593       |> Map.put("favorited_by", user.ap_id)
 594       |> Map.put("blocking_user", user)
 595
 596     activities =
 597       ActivityPub.fetch_public_activities(params)
 598       |> Enum.reverse()
 599
 600     conn
 601     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 602   end
 603
 604   def get_lists(%{assigns: %{user: user}} = conn, opts) do
 605     lists = Pleroma.List.for_user(user, opts)
 606     res = ListView.render("lists.json", lists: lists)
 607     json(conn, res)
 608   end
 609
 610   def get_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 611     with %Pleroma.List{} = list <- Pleroma.List.get(id, user) do
 612       res = ListView.render("list.json", list: list)
 613       json(conn, res)
 614     else
 615       _e -> json(conn, "error")
 616     end
 617   end
 618
 619   def delete_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 620     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 621          {:ok, _list} <- Pleroma.List.delete(list) do
 622       json(conn, %{})
 623     else
 624       _e ->
 625         json(conn, "error")
 626     end
 627   end
 628
 629   def create_list(%{assigns: %{user: user}} = conn, %{"title" => title}) do
 630     with {:ok, %Pleroma.List{} = list} <- Pleroma.List.create(title, user) do
 631       res = ListView.render("list.json", list: list)
 632       json(conn, res)
 633     end
 634   end
 635
 636   def add_to_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 637     accounts
 638     |> Enum.each(fn account_id ->
 639       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 640            %User{} = followed <- Repo.get(User, account_id) do
 641         Pleroma.List.follow(list, followed)
 642       end
 643     end)
 644
 645     json(conn, %{})
 646   end
 647
 648   def remove_from_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 649     accounts
 650     |> Enum.each(fn account_id ->
 651       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 652            %User{} = followed <- Repo.get(Pleroma.User, account_id) do
 653         Pleroma.List.unfollow(list, followed)
 654       end
 655     end)
 656
 657     json(conn, %{})
 658   end
 659
 660   def list_accounts(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 661     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 662          {:ok, users} = Pleroma.List.get_following(list) do
 663       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 664     end
 665   end
 666
 667   def rename_list(%{assigns: %{user: user}} = conn, %{"id" => id, "title" => title}) do
 668     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 669          {:ok, list} <- Pleroma.List.rename(list, title) do
 670       res = ListView.render("list.json", list: list)
 671       json(conn, res)
 672     else
 673       _e ->
 674         json(conn, "error")
 675     end
 676   end
 677
 678   def list_timeline(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 679     with %Pleroma.List{title: title, following: following} <- Pleroma.List.get(id, user) do
 680       params =
 681         params
 682         |> Map.put("type", "Create")
 683         |> Map.put("blocking_user", user)
 684
 685       # adding title is a hack to not make empty lists function like a public timeline
 686       activities =
 687         ActivityPub.fetch_activities([title | following], params)
 688         |> Enum.reverse()
 689
 690       conn
 691       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 692     else
 693       _e ->
 694         conn
 695         |> put_status(403)
 696         |> json(%{error: "Error."})
 697     end
 698   end
 699
 700   def index(%{assigns: %{user: user}} = conn, _params) do
 701     token =
 702       conn
 703       |> get_session(:oauth_token)
 704
 705     if user && token do
 706       mastodon_emoji = mastodonized_emoji()
 707       accounts = Map.put(%{}, user.id, AccountView.render("account.json", %{user: user}))
 708
 709       initial_state =
 710         %{
 711           meta: %{
 712             streaming_api_base_url:
 713               String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 714             access_token: token,
 715             locale: "en",
 716             domain: Pleroma.Web.Endpoint.host(),
 717             admin: "1",
 718             me: "#{user.id}",
 719             unfollow_modal: false,
 720             boost_modal: false,
 721             delete_modal: true,
 722             auto_play_gif: false,
 723             reduce_motion: false
 724           },
 725           compose: %{
 726             me: "#{user.id}",
 727             default_privacy: "public",
 728             default_sensitive: false
 729           },
 730           media_attachments: %{
 731             accept_content_types: [
 732               ".jpg",
 733               ".jpeg",
 734               ".png",
 735               ".gif",
 736               ".webm",
 737               ".mp4",
 738               ".m4v",
 739               "image\/jpeg",
 740               "image\/png",
 741               "image\/gif",
 742               "video\/webm",
 743               "video\/mp4"
 744             ]
 745           },
 746           settings:
 747             Map.get(user.info, "settings") ||
 748               %{
 749                 onboarded: true,
 750                 home: %{
 751                   shows: %{
 752                     reblog: true,
 753                     reply: true
 754                   }
 755                 },
 756                 notifications: %{
 757                   alerts: %{
 758                     follow: true,
 759                     favourite: true,
 760                     reblog: true,
 761                     mention: true
 762                   },
 763                   shows: %{
 764                     follow: true,
 765                     favourite: true,
 766                     reblog: true,
 767                     mention: true
 768                   },
 769                   sounds: %{
 770                     follow: true,
 771                     favourite: true,
 772                     reblog: true,
 773                     mention: true
 774                   }
 775                 }
 776               },
 777           push_subscription: nil,
 778           accounts: accounts,
 779           custom_emojis: mastodon_emoji,
 780           char_limit: Keyword.get(@instance, :limit)
 781         }
 782         |> Jason.encode!()
 783
 784       conn
 785       |> put_layout(false)
 786       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 787     else
 788       conn
 789       |> redirect(to: "/web/login")
 790     end
 791   end
 792
 793   def put_settings(%{assigns: %{user: user}} = conn, %{"data" => settings} = _params) do
 794     with new_info <- Map.put(user.info, "settings", settings),
 795          change <- User.info_changeset(user, %{info: new_info}),
 796          {:ok, _user} <- User.update_and_set_cache(change) do
 797       conn
 798       |> json(%{})
 799     else
 800       e ->
 801         conn
 802         |> json(%{error: inspect(e)})
 803     end
 804   end
 805
 806   def login(conn, _) do
 807     conn
 808     |> render(MastodonView, "login.html", %{error: false})
 809   end
 810
 811   defp get_or_make_app() do
 812     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 813       {:ok, app}
 814     else
 815       _e ->
 816         cs =
 817           App.register_changeset(%App{}, %{
 818             client_name: "Mastodon-Local",
 819             redirect_uris: ".",
 820             scopes: "read,write,follow"
 821           })
 822
 823         Repo.insert(cs)
 824     end
 825   end
 826
 827   def login_post(conn, %{"authorization" => %{"name" => name, "password" => password}}) do
 828     with %User{} = user <- User.get_by_nickname_or_email(name),
 829          true <- Pbkdf2.checkpw(password, user.password_hash),
 830          {:ok, app} <- get_or_make_app(),
 831          {:ok, auth} <- Authorization.create_authorization(app, user),
 832          {:ok, token} <- Token.exchange_token(app, auth) do
 833       conn
 834       |> put_session(:oauth_token, token.token)
 835       |> redirect(to: "/web/getting-started")
 836     else
 837       _e ->
 838         conn
 839         |> render(MastodonView, "login.html", %{error: "Wrong username or password"})
 840     end
 841   end
 842
 843   def logout(conn, _) do
 844     conn
 845     |> clear_session
 846     |> redirect(to: "/")
 847   end
 848
 849   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 850     Logger.debug("Unimplemented, returning unmodified relationship")
 851
 852     with %User{} = target <- Repo.get(User, id) do
 853       render(conn, AccountView, "relationship.json", %{user: user, target: target})
 854     end
 855   end
 856
 857   def empty_array(conn, _) do
 858     Logger.debug("Unimplemented, returning an empty array")
 859     json(conn, [])
 860   end
 861
 862   def empty_object(conn, _) do
 863     Logger.debug("Unimplemented, returning an empty object")
 864     json(conn, %{})
 865   end
 866
 867   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
 868     actor = User.get_cached_by_ap_id(activity.data["actor"])
 869
 870     created_at =
 871       NaiveDateTime.to_iso8601(created_at)
 872       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 873
 874     case activity.data["type"] do
 875       "Create" ->
 876         %{
 877           id: id,
 878           type: "mention",
 879           created_at: created_at,
 880           account: AccountView.render("account.json", %{user: actor}),
 881           status: StatusView.render("status.json", %{activity: activity, for: user})
 882         }
 883
 884       "Like" ->
 885         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 886
 887         %{
 888           id: id,
 889           type: "favourite",
 890           created_at: created_at,
 891           account: AccountView.render("account.json", %{user: actor}),
 892           status: StatusView.render("status.json", %{activity: liked_activity, for: user})
 893         }
 894
 895       "Announce" ->
 896         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 897
 898         %{
 899           id: id,
 900           type: "reblog",
 901           created_at: created_at,
 902           account: AccountView.render("account.json", %{user: actor}),
 903           status: StatusView.render("status.json", %{activity: announced_activity, for: user})
 904         }
 905
 906       "Follow" ->
 907         %{
 908           id: id,
 909           type: "follow",
 910           created_at: created_at,
 911           account: AccountView.render("account.json", %{user: actor})
 912         }
 913
 914       _ ->
 915         nil
 916     end
 917   end
 918 end