git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity, User, Notification, Stats}
   4   alias Pleroma.Web
   5   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView, MastodonView, ListView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.{CommonAPI, OStatus}
   8   alias Pleroma.Web.OAuth.{Authorization, Token, App}
   9   alias Comeonin.Pbkdf2
  10   import Ecto.Query
  11   require Logger
  12
  13   def create_app(conn, params) do
  14     with cs <- App.register_changeset(%App{}, params) |> IO.inspect(),
  15          {:ok, app} <- Repo.insert(cs) |> IO.inspect() do
  16       res = %{
  17         id: app.id,
  18         client_id: app.client_id,
  19         client_secret: app.client_secret
  20       }
  21
  22       json(conn, res)
  23     end
  24   end
  25
  26   def update_credentials(%{assigns: %{user: user}} = conn, params) do
  27     original_user = user
  28
  29     params =
  30       if bio = params["note"] do
  31         Map.put(params, "bio", bio)
  32       else
  33         params
  34       end
  35
  36     params =
  37       if name = params["display_name"] do
  38         Map.put(params, "name", name)
  39       else
  40         params
  41       end
  42
  43     user =
  44       if avatar = params["avatar"] do
  45         with %Plug.Upload{} <- avatar,
  46              {:ok, object} <- ActivityPub.upload(avatar),
  47              change = Ecto.Changeset.change(user, %{avatar: object.data}),
  48              {:ok, user} = User.update_and_set_cache(change) do
  49           user
  50         else
  51           _e -> user
  52         end
  53       else
  54         user
  55       end
  56
  57     user =
  58       if banner = params["header"] do
  59         with %Plug.Upload{} <- banner,
  60              {:ok, object} <- ActivityPub.upload(banner),
  61              new_info <- Map.put(user.info, "banner", object.data),
  62              change <- User.info_changeset(user, %{info: new_info}),
  63              {:ok, user} <- User.update_and_set_cache(change) do
  64           user
  65         else
  66           _e -> user
  67         end
  68       else
  69         user
  70       end
  71
  72     with changeset <- User.update_changeset(user, params),
  73          {:ok, user} <- User.update_and_set_cache(changeset) do
  74       if original_user != user do
  75         CommonAPI.update(user)
  76       end
  77
  78       json(conn, AccountView.render("account.json", %{user: user}))
  79     else
  80       _e ->
  81         conn
  82         |> put_status(403)
  83         |> json(%{error: "Invalid request"})
  84     end
  85   end
  86
  87   def verify_credentials(%{assigns: %{user: user}} = conn, _) do
  88     account = AccountView.render("account.json", %{user: user})
  89     json(conn, account)
  90   end
  91
  92   def user(conn, %{"id" => id}) do
  93     with %User{} = user <- Repo.get(User, id) do
  94       account = AccountView.render("account.json", %{user: user})
  95       json(conn, account)
  96     else
  97       _e ->
  98         conn
  99         |> put_status(404)
 100         |> json(%{error: "Can't find user"})
 101     end
 102   end
 103
 104   @instance Application.get_env(:pleroma, :instance)
 105   @mastodon_api_level "2.3.3"
 106
 107   def masto_instance(conn, _params) do
 108     response = %{
 109       uri: Web.base_url(),
 110       title: Keyword.get(@instance, :name),
 111       description: "A Pleroma instance, an alternative fediverse server",
 112       version: "#{@mastodon_api_level} (compatible; #{Keyword.get(@instance, :version)})",
 113       email: Keyword.get(@instance, :email),
 114       urls: %{
 115         streaming_api: String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws")
 116       },
 117       stats: Stats.get_stats(),
 118       thumbnail: Web.base_url() <> "/instance/thumbnail.jpeg",
 119       max_toot_chars: Keyword.get(@instance, :limit)
 120     }
 121
 122     json(conn, response)
 123   end
 124
 125   def peers(conn, _params) do
 126     json(conn, Stats.get_peers())
 127   end
 128
 129   defp mastodonized_emoji do
 130     Pleroma.Formatter.get_custom_emoji()
 131     |> Enum.map(fn {shortcode, relative_url} ->
 132       url = to_string(URI.merge(Web.base_url(), relative_url))
 133
 134       %{
 135         "shortcode" => shortcode,
 136         "static_url" => url,
 137         "url" => url
 138       }
 139     end)
 140   end
 141
 142   def custom_emojis(conn, _params) do
 143     mastodon_emoji = mastodonized_emoji()
 144     json(conn, mastodon_emoji)
 145   end
 146
 147   defp add_link_headers(conn, method, activities, param \\ nil, params \\ %{}) do
 148     last = List.last(activities)
 149     first = List.first(activities)
 150
 151     if last do
 152       min = last.id
 153       max = first.id
 154
 155       {next_url, prev_url} =
 156         if param do
 157           {
 158             mastodon_api_url(
 159               Pleroma.Web.Endpoint,
 160               method,
 161               param,
 162               Map.merge(params, %{max_id: min})
 163             ),
 164             mastodon_api_url(
 165               Pleroma.Web.Endpoint,
 166               method,
 167               param,
 168               Map.merge(params, %{since_id: max})
 169             )
 170           }
 171         else
 172           {
 173             mastodon_api_url(
 174               Pleroma.Web.Endpoint,
 175               method,
 176               Map.merge(params, %{max_id: min})
 177             ),
 178             mastodon_api_url(
 179               Pleroma.Web.Endpoint,
 180               method,
 181               Map.merge(params, %{since_id: max})
 182             )
 183           }
 184         end
 185
 186       conn
 187       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 188     else
 189       conn
 190     end
 191   end
 192
 193   def home_timeline(%{assigns: %{user: user}} = conn, params) do
 194     params =
 195       params
 196       |> Map.put("type", ["Create", "Announce"])
 197       |> Map.put("blocking_user", user)
 198       |> Map.put("user", user)
 199
 200     activities =
 201       ActivityPub.fetch_activities([user.ap_id | user.following], params)
 202       |> Enum.reverse()
 203
 204     conn
 205     |> add_link_headers(:home_timeline, activities)
 206     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 207   end
 208
 209   def public_timeline(%{assigns: %{user: user}} = conn, params) do
 210     local_only = params["local"] in [true, "True", "true", "1"]
 211
 212     params =
 213       params
 214       |> Map.put("type", ["Create", "Announce"])
 215       |> Map.put("local_only", local_only)
 216       |> Map.put("blocking_user", user)
 217
 218     activities =
 219       ActivityPub.fetch_public_activities(params)
 220       |> Enum.reverse()
 221
 222     conn
 223     |> add_link_headers(:public_timeline, activities, false, %{"local" => local_only})
 224     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 225   end
 226
 227   def user_statuses(%{assigns: %{user: reading_user}} = conn, params) do
 228     with %User{} = user <- Repo.get(User, params["id"]) do
 229       # Since Pleroma has no "pinned" posts feature, we'll just set an empty list here
 230       activities =
 231         if params["pinned"] == "true" do
 232           []
 233         else
 234           ActivityPub.fetch_user_activities(user, reading_user, params)
 235         end
 236
 237       conn
 238       |> add_link_headers(:user_statuses, activities, params["id"])
 239       |> render(StatusView, "index.json", %{
 240         activities: activities,
 241         for: reading_user,
 242         as: :activity
 243       })
 244     end
 245   end
 246
 247   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 248     query =
 249       ActivityPub.fetch_activities_query([user.ap_id], %{"type" => "Create", visibility: "direct"})
 250
 251     activities = Repo.all(query)
 252
 253     conn
 254     |> add_link_headers(:dm_timeline, activities)
 255     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 256   end
 257
 258   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 259     with %Activity{} = activity <- Repo.get(Activity, id),
 260          true <- ActivityPub.visible_for_user?(activity, user) do
 261       render(conn, StatusView, "status.json", %{activity: activity, for: user})
 262     end
 263   end
 264
 265   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 266     with %Activity{} = activity <- Repo.get(Activity, id),
 267          activities <-
 268            ActivityPub.fetch_activities_for_context(activity.data["context"], %{
 269              "blocking_user" => user,
 270              "user" => user
 271            }),
 272          activities <-
 273            activities |> Enum.filter(fn %{id: aid} -> to_string(aid) != to_string(id) end),
 274          activities <-
 275            activities |> Enum.filter(fn %{data: %{"type" => type}} -> type == "Create" end),
 276          grouped_activities <- Enum.group_by(activities, fn %{id: id} -> id < activity.id end) do
 277       result = %{
 278         ancestors:
 279           StatusView.render(
 280             "index.json",
 281             for: user,
 282             activities: grouped_activities[true] || [],
 283             as: :activity
 284           )
 285           |> Enum.reverse(),
 286         descendants:
 287           StatusView.render(
 288             "index.json",
 289             for: user,
 290             activities: grouped_activities[false] || [],
 291             as: :activity
 292           )
 293           |> Enum.reverse()
 294       }
 295
 296       json(conn, result)
 297     end
 298   end
 299
 300   def post_status(%{assigns: %{user: user}} = conn, %{"status" => _} = params) do
 301     params =
 302       params
 303       |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
 304       |> Map.put("no_attachment_links", true)
 305
 306     idempotency_key =
 307       case get_req_header(conn, "idempotency-key") do
 308         [key] -> key
 309         _ -> Ecto.UUID.generate()
 310       end
 311
 312     {:ok, activity} =
 313       Cachex.fetch!(:idempotency_cache, idempotency_key, fn _ -> CommonAPI.post(user, params) end)
 314
 315     render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 316   end
 317
 318   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 319     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
 320       json(conn, %{})
 321     else
 322       _e ->
 323         conn
 324         |> put_status(403)
 325         |> json(%{error: "Can't delete this post"})
 326     end
 327   end
 328
 329   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 330     with {:ok, announce, _activity} = CommonAPI.repeat(ap_id_or_id, user) do
 331       render(conn, StatusView, "status.json", %{activity: announce, for: user, as: :activity})
 332     end
 333   end
 334
 335   def unreblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 336     with {:ok, _, _, %{data: %{"id" => id}}} = CommonAPI.unrepeat(ap_id_or_id, user),
 337          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 338       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 339     end
 340   end
 341
 342   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 343     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 344          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 345       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 346     end
 347   end
 348
 349   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 350     with {:ok, _, _, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 351          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 352       render(conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity})
 353     end
 354   end
 355
 356   def notifications(%{assigns: %{user: user}} = conn, params) do
 357     notifications = Notification.for_user(user, params)
 358
 359     result =
 360       Enum.map(notifications, fn x ->
 361         render_notification(user, x)
 362       end)
 363       |> Enum.filter(& &1)
 364
 365     conn
 366     |> add_link_headers(:notifications, notifications)
 367     |> json(result)
 368   end
 369
 370   def get_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 371     with {:ok, notification} <- Notification.get(user, id) do
 372       json(conn, render_notification(user, notification))
 373     else
 374       {:error, reason} ->
 375         conn
 376         |> put_resp_content_type("application/json")
 377         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 378     end
 379   end
 380
 381   def clear_notifications(%{assigns: %{user: user}} = conn, _params) do
 382     Notification.clear(user)
 383     json(conn, %{})
 384   end
 385
 386   def dismiss_notification(%{assigns: %{user: user}} = conn, %{"id" => id} = _params) do
 387     with {:ok, _notif} <- Notification.dismiss(user, id) do
 388       json(conn, %{})
 389     else
 390       {:error, reason} ->
 391         conn
 392         |> put_resp_content_type("application/json")
 393         |> send_resp(403, Jason.encode!(%{"error" => reason}))
 394     end
 395   end
 396
 397   def relationships(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 398     id = List.wrap(id)
 399     q = from(u in User, where: u.id in ^id)
 400     targets = Repo.all(q)
 401     render(conn, AccountView, "relationships.json", %{user: user, targets: targets})
 402   end
 403
 404   def upload(%{assigns: %{user: _}} = conn, %{"file" => file}) do
 405     with {:ok, object} <- ActivityPub.upload(file) do
 406       data =
 407         object.data
 408         |> Map.put("id", object.id)
 409
 410       render(conn, StatusView, "attachment.json", %{attachment: data})
 411     end
 412   end
 413
 414   def favourited_by(conn, %{"id" => id}) do
 415     with %Activity{data: %{"object" => %{"likes" => likes}}} <- Repo.get(Activity, id) do
 416       q = from(u in User, where: u.ap_id in ^likes)
 417       users = Repo.all(q)
 418       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 419     else
 420       _ -> json(conn, [])
 421     end
 422   end
 423
 424   def reblogged_by(conn, %{"id" => id}) do
 425     with %Activity{data: %{"object" => %{"announcements" => announces}}} <- Repo.get(Activity, id) do
 426       q = from(u in User, where: u.ap_id in ^announces)
 427       users = Repo.all(q)
 428       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 429     else
 430       _ -> json(conn, [])
 431     end
 432   end
 433
 434   def hashtag_timeline(%{assigns: %{user: user}} = conn, params) do
 435     local_only = params["local"] in [true, "True", "true", "1"]
 436
 437     params =
 438       params
 439       |> Map.put("type", "Create")
 440       |> Map.put("local_only", local_only)
 441       |> Map.put("blocking_user", user)
 442
 443     activities =
 444       ActivityPub.fetch_public_activities(params)
 445       |> Enum.reverse()
 446
 447     conn
 448     |> add_link_headers(:hashtag_timeline, activities, params["tag"], %{"local" => local_only})
 449     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 450   end
 451
 452   # TODO: Pagination
 453   def followers(conn, %{"id" => id}) do
 454     with %User{} = user <- Repo.get(User, id),
 455          {:ok, followers} <- User.get_followers(user) do
 456       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 457     end
 458   end
 459
 460   def following(conn, %{"id" => id}) do
 461     with %User{} = user <- Repo.get(User, id),
 462          {:ok, followers} <- User.get_friends(user) do
 463       render(conn, AccountView, "accounts.json", %{users: followers, as: :user})
 464     end
 465   end
 466
 467   def follow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 468     with %User{} = followed <- Repo.get(User, id),
 469          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 470          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 471       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 472     else
 473       {:error, message} ->
 474         conn
 475         |> put_resp_content_type("application/json")
 476         |> send_resp(403, Jason.encode!(%{"error" => message}))
 477     end
 478   end
 479
 480   def follow(%{assigns: %{user: follower}} = conn, %{"uri" => uri}) do
 481     with %User{} = followed <- Repo.get_by(User, nickname: uri),
 482          {:ok, follower} <- User.maybe_direct_follow(follower, followed),
 483          {:ok, _activity} <- ActivityPub.follow(follower, followed) do
 484       render(conn, AccountView, "account.json", %{user: followed})
 485     else
 486       {:error, message} ->
 487         conn
 488         |> put_resp_content_type("application/json")
 489         |> send_resp(403, Jason.encode!(%{"error" => message}))
 490     end
 491   end
 492
 493   def unfollow(%{assigns: %{user: follower}} = conn, %{"id" => id}) do
 494     with %User{} = followed <- Repo.get(User, id),
 495          {:ok, _activity} <- ActivityPub.unfollow(follower, followed),
 496          {:ok, follower, _} <- User.unfollow(follower, followed) do
 497       render(conn, AccountView, "relationship.json", %{user: follower, target: followed})
 498     end
 499   end
 500
 501   def block(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 502     with %User{} = blocked <- Repo.get(User, id),
 503          {:ok, blocker} <- User.block(blocker, blocked),
 504          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
 505       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 506     else
 507       {:error, message} ->
 508         conn
 509         |> put_resp_content_type("application/json")
 510         |> send_resp(403, Jason.encode!(%{"error" => message}))
 511     end
 512   end
 513
 514   def unblock(%{assigns: %{user: blocker}} = conn, %{"id" => id}) do
 515     with %User{} = blocked <- Repo.get(User, id),
 516          {:ok, blocker} <- User.unblock(blocker, blocked),
 517          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
 518       render(conn, AccountView, "relationship.json", %{user: blocker, target: blocked})
 519     else
 520       {:error, message} ->
 521         conn
 522         |> put_resp_content_type("application/json")
 523         |> send_resp(403, Jason.encode!(%{"error" => message}))
 524     end
 525   end
 526
 527   # TODO: Use proper query
 528   def blocks(%{assigns: %{user: user}} = conn, _) do
 529     with blocked_users <- user.info["blocks"] || [],
 530          accounts <- Enum.map(blocked_users, fn ap_id -> User.get_cached_by_ap_id(ap_id) end) do
 531       res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 532       json(conn, res)
 533     end
 534   end
 535
 536   def search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 537     accounts = User.search(query, params["resolve"] == "true")
 538
 539     fetched =
 540       if Regex.match?(~r/https?:/, query) do
 541         with {:ok, activities} <- OStatus.fetch_activity_from_url(query) do
 542           activities
 543           |> Enum.filter(fn
 544             %{data: %{"type" => "Create"}} -> true
 545             _ -> false
 546           end)
 547         else
 548           _e -> []
 549         end
 550       end || []
 551
 552     q =
 553       from(
 554         a in Activity,
 555         where: fragment("?->>'type' = 'Create'", a.data),
 556         where: "https://www.w3.org/ns/activitystreams#Public" in a.recipients,
 557         where:
 558           fragment(
 559             "to_tsvector('english', ?->'object'->>'content') @@ plainto_tsquery('english', ?)",
 560             a.data,
 561             ^query
 562           ),
 563         limit: 20,
 564         order_by: [desc: :id]
 565       )
 566
 567     statuses = Repo.all(q) ++ fetched
 568
 569     tags =
 570       String.split(query)
 571       |> Enum.uniq()
 572       |> Enum.filter(fn tag -> String.starts_with?(tag, "#") end)
 573       |> Enum.map(fn tag -> String.slice(tag, 1..-1) end)
 574
 575     res = %{
 576       "accounts" => AccountView.render("accounts.json", users: accounts, for: user, as: :user),
 577       "statuses" =>
 578         StatusView.render("index.json", activities: statuses, for: user, as: :activity),
 579       "hashtags" => tags
 580     }
 581
 582     json(conn, res)
 583   end
 584
 585   def account_search(%{assigns: %{user: user}} = conn, %{"q" => query} = params) do
 586     accounts = User.search(query, params["resolve"] == "true")
 587
 588     res = AccountView.render("accounts.json", users: accounts, for: user, as: :user)
 589
 590     json(conn, res)
 591   end
 592
 593   def favourites(%{assigns: %{user: user}} = conn, _) do
 594     params =
 595       %{}
 596       |> Map.put("type", "Create")
 597       |> Map.put("favorited_by", user.ap_id)
 598       |> Map.put("blocking_user", user)
 599
 600     activities =
 601       ActivityPub.fetch_public_activities(params)
 602       |> Enum.reverse()
 603
 604     conn
 605     |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 606   end
 607
 608   def get_lists(%{assigns: %{user: user}} = conn, opts) do
 609     lists = Pleroma.List.for_user(user, opts)
 610     res = ListView.render("lists.json", lists: lists)
 611     json(conn, res)
 612   end
 613
 614   def get_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 615     with %Pleroma.List{} = list <- Pleroma.List.get(id, user) do
 616       res = ListView.render("list.json", list: list)
 617       json(conn, res)
 618     else
 619       _e -> json(conn, "error")
 620     end
 621   end
 622
 623   def delete_list(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 624     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 625          {:ok, _list} <- Pleroma.List.delete(list) do
 626       json(conn, %{})
 627     else
 628       _e ->
 629         json(conn, "error")
 630     end
 631   end
 632
 633   def create_list(%{assigns: %{user: user}} = conn, %{"title" => title}) do
 634     with {:ok, %Pleroma.List{} = list} <- Pleroma.List.create(title, user) do
 635       res = ListView.render("list.json", list: list)
 636       json(conn, res)
 637     end
 638   end
 639
 640   def add_to_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 641     accounts
 642     |> Enum.each(fn account_id ->
 643       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 644            %User{} = followed <- Repo.get(User, account_id) do
 645         Pleroma.List.follow(list, followed)
 646       end
 647     end)
 648
 649     json(conn, %{})
 650   end
 651
 652   def remove_from_list(%{assigns: %{user: user}} = conn, %{"id" => id, "account_ids" => accounts}) do
 653     accounts
 654     |> Enum.each(fn account_id ->
 655       with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 656            %User{} = followed <- Repo.get(Pleroma.User, account_id) do
 657         Pleroma.List.unfollow(list, followed)
 658       end
 659     end)
 660
 661     json(conn, %{})
 662   end
 663
 664   def list_accounts(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 665     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 666          {:ok, users} = Pleroma.List.get_following(list) do
 667       render(conn, AccountView, "accounts.json", %{users: users, as: :user})
 668     end
 669   end
 670
 671   def rename_list(%{assigns: %{user: user}} = conn, %{"id" => id, "title" => title}) do
 672     with %Pleroma.List{} = list <- Pleroma.List.get(id, user),
 673          {:ok, list} <- Pleroma.List.rename(list, title) do
 674       res = ListView.render("list.json", list: list)
 675       json(conn, res)
 676     else
 677       _e ->
 678         json(conn, "error")
 679     end
 680   end
 681
 682   def list_timeline(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 683     with %Pleroma.List{title: title, following: following} <- Pleroma.List.get(id, user) do
 684       params =
 685         params
 686         |> Map.put("type", "Create")
 687         |> Map.put("blocking_user", user)
 688
 689       # adding title is a hack to not make empty lists function like a public timeline
 690       activities =
 691         ActivityPub.fetch_activities([title | following], params)
 692         |> Enum.reverse()
 693
 694       conn
 695       |> render(StatusView, "index.json", %{activities: activities, for: user, as: :activity})
 696     else
 697       _e ->
 698         conn
 699         |> put_status(403)
 700         |> json(%{error: "Error."})
 701     end
 702   end
 703
 704   def index(%{assigns: %{user: user}} = conn, _params) do
 705     token =
 706       conn
 707       |> get_session(:oauth_token)
 708
 709     if user && token do
 710       mastodon_emoji = mastodonized_emoji()
 711       accounts = Map.put(%{}, user.id, AccountView.render("account.json", %{user: user}))
 712
 713       initial_state =
 714         %{
 715           meta: %{
 716             streaming_api_base_url:
 717               String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws"),
 718             access_token: token,
 719             locale: "en",
 720             domain: Pleroma.Web.Endpoint.host(),
 721             admin: "1",
 722             me: "#{user.id}",
 723             unfollow_modal: false,
 724             boost_modal: false,
 725             delete_modal: true,
 726             auto_play_gif: false,
 727             reduce_motion: false
 728           },
 729           compose: %{
 730             me: "#{user.id}",
 731             default_privacy: "public",
 732             default_sensitive: false
 733           },
 734           media_attachments: %{
 735             accept_content_types: [
 736               ".jpg",
 737               ".jpeg",
 738               ".png",
 739               ".gif",
 740               ".webm",
 741               ".mp4",
 742               ".m4v",
 743               "image\/jpeg",
 744               "image\/png",
 745               "image\/gif",
 746               "video\/webm",
 747               "video\/mp4"
 748             ]
 749           },
 750           settings:
 751             Map.get(user.info, "settings") ||
 752               %{
 753                 onboarded: true,
 754                 home: %{
 755                   shows: %{
 756                     reblog: true,
 757                     reply: true
 758                   }
 759                 },
 760                 notifications: %{
 761                   alerts: %{
 762                     follow: true,
 763                     favourite: true,
 764                     reblog: true,
 765                     mention: true
 766                   },
 767                   shows: %{
 768                     follow: true,
 769                     favourite: true,
 770                     reblog: true,
 771                     mention: true
 772                   },
 773                   sounds: %{
 774                     follow: true,
 775                     favourite: true,
 776                     reblog: true,
 777                     mention: true
 778                   }
 779                 }
 780               },
 781           push_subscription: nil,
 782           accounts: accounts,
 783           custom_emojis: mastodon_emoji,
 784           char_limit: Keyword.get(@instance, :limit)
 785         }
 786         |> Jason.encode!()
 787
 788       conn
 789       |> put_layout(false)
 790       |> render(MastodonView, "index.html", %{initial_state: initial_state})
 791     else
 792       conn
 793       |> redirect(to: "/web/login")
 794     end
 795   end
 796
 797   def put_settings(%{assigns: %{user: user}} = conn, %{"data" => settings} = _params) do
 798     with new_info <- Map.put(user.info, "settings", settings),
 799          change <- User.info_changeset(user, %{info: new_info}),
 800          {:ok, _user} <- User.update_and_set_cache(change) do
 801       conn
 802       |> json(%{})
 803     else
 804       e ->
 805         conn
 806         |> json(%{error: inspect(e)})
 807     end
 808   end
 809
 810   def login(conn, _) do
 811     conn
 812     |> render(MastodonView, "login.html", %{error: false})
 813   end
 814
 815   defp get_or_make_app() do
 816     with %App{} = app <- Repo.get_by(App, client_name: "Mastodon-Local") do
 817       {:ok, app}
 818     else
 819       _e ->
 820         cs =
 821           App.register_changeset(%App{}, %{
 822             client_name: "Mastodon-Local",
 823             redirect_uris: ".",
 824             scopes: "read,write,follow"
 825           })
 826
 827         Repo.insert(cs)
 828     end
 829   end
 830
 831   def login_post(conn, %{"authorization" => %{"name" => name, "password" => password}}) do
 832     with %User{} = user <- User.get_by_nickname_or_email(name),
 833          true <- Pbkdf2.checkpw(password, user.password_hash),
 834          {:ok, app} <- get_or_make_app(),
 835          {:ok, auth} <- Authorization.create_authorization(app, user),
 836          {:ok, token} <- Token.exchange_token(app, auth) do
 837       conn
 838       |> put_session(:oauth_token, token.token)
 839       |> redirect(to: "/web/getting-started")
 840     else
 841       _e ->
 842         conn
 843         |> render(MastodonView, "login.html", %{error: "Wrong username or password"})
 844     end
 845   end
 846
 847   def logout(conn, _) do
 848     conn
 849     |> clear_session
 850     |> redirect(to: "/")
 851   end
 852
 853   def relationship_noop(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 854     Logger.debug("Unimplemented, returning unmodified relationship")
 855
 856     with %User{} = target <- Repo.get(User, id) do
 857       render(conn, AccountView, "relationship.json", %{user: user, target: target})
 858     end
 859   end
 860
 861   def empty_array(conn, _) do
 862     Logger.debug("Unimplemented, returning an empty array")
 863     json(conn, [])
 864   end
 865
 866   def empty_object(conn, _) do
 867     Logger.debug("Unimplemented, returning an empty object")
 868     json(conn, %{})
 869   end
 870
 871   def render_notification(user, %{id: id, activity: activity, inserted_at: created_at} = _params) do
 872     actor = User.get_cached_by_ap_id(activity.data["actor"])
 873
 874     created_at =
 875       NaiveDateTime.to_iso8601(created_at)
 876       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 877
 878     case activity.data["type"] do
 879       "Create" ->
 880         %{
 881           id: id,
 882           type: "mention",
 883           created_at: created_at,
 884           account: AccountView.render("account.json", %{user: actor}),
 885           status: StatusView.render("status.json", %{activity: activity, for: user})
 886         }
 887
 888       "Like" ->
 889         liked_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 890
 891         %{
 892           id: id,
 893           type: "favourite",
 894           created_at: created_at,
 895           account: AccountView.render("account.json", %{user: actor}),
 896           status: StatusView.render("status.json", %{activity: liked_activity, for: user})
 897         }
 898
 899       "Announce" ->
 900         announced_activity = Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 901
 902         %{
 903           id: id,
 904           type: "reblog",
 905           created_at: created_at,
 906           account: AccountView.render("account.json", %{user: actor}),
 907           status: StatusView.render("status.json", %{activity: announced_activity, for: user})
 908         }
 909
 910       "Follow" ->
 911         %{
 912           id: id,
 913           type: "follow",
 914           created_at: created_at,
 915           account: AccountView.render("account.json", %{user: actor})
 916         }
 917
 918       _ ->
 919         nil
 920     end
 921   end
 922 end