git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api_controller.ex

   1 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Repo, Activity}
   4   alias Pleroma.Web.OAuth.App
   5   alias Pleroma.Web
   6   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView}
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Pleroma.Web.TwitterAPI.TwitterAPI
   9   alias Pleroma.Web.CommonAPI
  10   import Logger
  11
  12   def create_app(conn, params) do
  13     with cs <- App.register_changeset(%App{}, params) |> IO.inspect,
  14          {:ok, app} <- Repo.insert(cs) |> IO.inspect do
  15       res = %{
  16         id: app.id,
  17         client_id: app.client_id,
  18         client_secret: app.client_secret
  19       }
  20
  21       json(conn, res)
  22     end
  23   end
  24
  25   def verify_credentials(%{assigns: %{user: user}} = conn, params) do
  26     account = AccountView.render("account.json", %{user: user})
  27     json(conn, account)
  28   end
  29
  30   def masto_instance(conn, _params) do
  31     response = %{
  32       uri: Web.base_url,
  33       title: Web.base_url,
  34       description: "A Pleroma instance, an alternative fediverse server",
  35       version: "Pleroma Dev"
  36     }
  37
  38     json(conn, response)
  39   end
  40
  41   def home_timeline(%{assigns: %{user: user}} = conn, params) do
  42     activities = ActivityPub.fetch_activities([user.ap_id | user.following], Map.put(params, "type", "Create"))
  43     |> Enum.reverse
  44     render conn, StatusView, "index.json", %{activities: activities, for: user, as: :activity}
  45   end
  46
  47   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  48     params = params
  49     |> Map.put("type", "Create")
  50     |> Map.put("local_only", !!params["local"])
  51
  52     activities = ActivityPub.fetch_public_activities(params)
  53     |> Enum.reverse
  54
  55     render conn, StatusView, "index.json", %{activities: activities, for: user, as: :activity}
  56   end
  57
  58   def get_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
  59     with %Activity{} = activity <- Repo.get(Activity, id) do
  60       render conn, StatusView, "status.json", %{activity: activity, for: user}
  61     end
  62   end
  63
  64   def get_context(%{assigns: %{user: user}} = conn, %{"id" => id}) do
  65     with %Activity{} = activity <- Repo.get(Activity, id),
  66          activities <- ActivityPub.fetch_activities_for_context(activity.data["object"]["context"]),
  67          activities <- activities |> Enum.filter(fn (%{id: aid}) -> to_string(aid) != to_string(id) end),
  68          grouped_activities <- Enum.group_by(activities, fn (%{id: id}) -> id < activity.id end) do
  69       result = %{
  70         ancestors: StatusView.render("index.json", for: user, activities: grouped_activities[true] || [], as: :activity) |> Enum.reverse,
  71         descendants: StatusView.render("index.json", for: user, activities: grouped_activities[false] || [], as: :activity) |> Enum.reverse,
  72       }
  73
  74       json(conn, result)
  75     end
  76   end
  77
  78   def post_status(%{assigns: %{user: user}} = conn, %{"status" => status} = params) do
  79     l = status |> String.trim |> String.length
  80
  81     params = params
  82     |> Map.put("in_reply_to_status_id", params["in_reply_to_id"])
  83
  84     if l > 0 && l < 5000 do
  85       {:ok, activity} = TwitterAPI.create_status(user, params)
  86       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
  87     end
  88   end
  89
  90   def delete_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
  91     with {:ok, %Activity{}} <- CommonAPI.delete(id, user) do
  92       json(conn, %{})
  93     else
  94       _e ->
  95         conn
  96         |> put_status(403)
  97         |> json(%{error: "Can't delete this post"})
  98     end
  99   end
 100
 101   def reblog_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 102     with {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(ap_id_or_id, user),
 103          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 104       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 105     end
 106   end
 107
 108   def fav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 109     with {:ok, _fav, %{data: %{"id" => id}}} = CommonAPI.favorite(ap_id_or_id, user),
 110          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 111       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 112     end
 113   end
 114
 115   def unfav_status(%{assigns: %{user: user}} = conn, %{"id" => ap_id_or_id}) do
 116     with {:ok, %{data: %{"id" => id}}} = CommonAPI.unfavorite(ap_id_or_id, user),
 117          %Activity{} = activity <- Activity.get_create_activity_by_object_ap_id(id) do
 118       render conn, StatusView, "status.json", %{activity: activity, for: user, as: :activity}
 119     end
 120   end
 121
 122   def empty_array(conn, _) do
 123     Logger.debug("Unimplemented, returning an empty array")
 124     json(conn, [])
 125   end
 126 end