git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.MastodonAPI do
   6   import Ecto.Query
   7   import Ecto.Changeset
   8
   9   alias Pleroma.Activity
  10   alias Pleroma.Notification
  11   alias Pleroma.Pagination
  12   alias Pleroma.ScheduledActivity
  13   alias Pleroma.User
  14   alias Pleroma.Web.CommonAPI
  15
  16   @spec follow(User.t(), User.t(), map) :: {:ok, User.t()} | {:error, String.t()}
  17   def follow(follower, followed, params \\ %{}) do
  18     result =
  19       if not User.following?(follower, followed) do
  20         CommonAPI.follow(follower, followed)
  21       else
  22         {:ok, follower, followed, nil}
  23       end
  24
  25     with {:ok, follower, _followed, _} <- result do
  26       options = cast_params(params)
  27
  28       case reblogs_visibility(options[:reblogs], result) do
  29         {:ok, follower} -> {:ok, follower}
  30         _ -> {:ok, follower}
  31       end
  32     end
  33   end
  34
  35   defp reblogs_visibility(false, {:ok, follower, followed, _}) do
  36     CommonAPI.hide_reblogs(follower, followed)
  37   end
  38
  39   defp reblogs_visibility(_, {:ok, follower, followed, _}) do
  40     CommonAPI.show_reblogs(follower, followed)
  41   end
  42
  43   @spec get_followers(User.t(), map()) :: list(User.t())
  44   def get_followers(user, params \\ %{}) do
  45     user
  46     |> User.get_followers_query()
  47     |> Pagination.fetch_paginated(params)
  48   end
  49
  50   def get_friends(user, params \\ %{}) do
  51     user
  52     |> User.get_friends_query()
  53     |> Pagination.fetch_paginated(params)
  54   end
  55
  56   def get_notifications(user, params \\ %{}) do
  57     options = cast_params(params)
  58
  59     user
  60     |> Notification.for_user_query(options)
  61     |> restrict(:exclude_types, options)
  62     |> Pagination.fetch_paginated(params)
  63   end
  64
  65   def get_scheduled_activities(user, params \\ %{}) do
  66     user
  67     |> ScheduledActivity.for_user_query()
  68     |> Pagination.fetch_paginated(params)
  69   end
  70
  71   defp cast_params(params) do
  72     param_types = %{
  73       exclude_types: {:array, :string},
  74       exclude_visibilities: {:array, :string},
  75       reblogs: :boolean,
  76       with_muted: :boolean
  77     }
  78
  79     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
  80     changeset.changes
  81   end
  82
  83   defp restrict(query, :exclude_types, %{exclude_types: mastodon_types = [_ | _]}) do
  84     ap_types =
  85       mastodon_types
  86       |> Enum.map(&Activity.from_mastodon_notification_type/1)
  87       |> Enum.filter(& &1)
  88
  89     query
  90     |> where([q, a], not fragment("? @> ARRAY[?->>'type']::varchar[]", ^ap_types, a.data))
  91   end
  92
  93   defp restrict(query, _, _), do: query
  94 end