git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.MastodonAPI do
   6   import Ecto.Query
   7   import Ecto.Changeset
   8
   9   alias Pleroma.Notification
  10   alias Pleroma.Pagination
  11   alias Pleroma.ScheduledActivity
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14
  15   @spec follow(User.t(), User.t(), map) :: {:ok, User.t()} | {:error, String.t()}
  16   def follow(follower, followed, params \\ %{}) do
  17     result =
  18       if not User.following?(follower, followed) do
  19         CommonAPI.follow(follower, followed)
  20       else
  21         {:ok, follower, followed, nil}
  22       end
  23
  24     with {:ok, follower, _followed, _} <- result do
  25       options = cast_params(params)
  26       set_reblogs_visibility(options[:reblogs], result)
  27       set_subscription(options[:notify], result)
  28       {:ok, follower}
  29     end
  30   end
  31
  32   defp set_reblogs_visibility(false, {:ok, follower, followed, _}) do
  33     CommonAPI.hide_reblogs(follower, followed)
  34   end
  35
  36   defp set_reblogs_visibility(_, {:ok, follower, followed, _}) do
  37     CommonAPI.show_reblogs(follower, followed)
  38   end
  39
  40   defp set_subscription(true, {:ok, follower, followed, _}) do
  41     User.subscribe(follower, followed)
  42   end
  43
  44   defp set_subscription(false, {:ok, follower, followed, _}) do
  45     User.unsubscribe(follower, followed)
  46   end
  47
  48   defp set_subscription(_, _), do: {:ok, nil}
  49
  50   @spec get_followers(User.t(), map()) :: list(User.t())
  51   def get_followers(user, params \\ %{}) do
  52     user
  53     |> User.get_followers_query()
  54     |> Pagination.fetch_paginated(params)
  55   end
  56
  57   def get_friends(user, params \\ %{}) do
  58     user
  59     |> User.get_friends_query()
  60     |> Pagination.fetch_paginated(params)
  61   end
  62
  63   def get_notifications(user, params \\ %{}) do
  64     options = cast_params(params)
  65
  66     query =
  67       user
  68       |> Notification.for_user_query(options)
  69       |> restrict(:include_types, options)
  70       |> restrict(:exclude_types, options)
  71       |> restrict(:account_ap_id, options)
  72
  73     IO.inspect(Pleroma.Repo.to_sql(:all, query))
  74
  75     query
  76     |> Pagination.fetch_paginated(params)
  77   end
  78
  79   def get_scheduled_activities(user, params \\ %{}) do
  80     user
  81     |> ScheduledActivity.for_user_query()
  82     |> Pagination.fetch_paginated(params)
  83   end
  84
  85   defp cast_params(params) do
  86     param_types = %{
  87       exclude_types: {:array, :string},
  88       include_types: {:array, :string},
  89       exclude_visibilities: {:array, :string},
  90       reblogs: :boolean,
  91       with_muted: :boolean,
  92       account_ap_id: :string,
  93       notify: :boolean
  94     }
  95
  96     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
  97     changeset.changes
  98   end
  99
 100   defp restrict(query, :include_types, %{include_types: mastodon_types = [_ | _]}) do
 101     where(query, [n], n.type in ^mastodon_types)
 102   end
 103
 104   defp restrict(query, :exclude_types, %{exclude_types: mastodon_types = [_ | _]}) do
 105     where(query, [n], n.type not in ^mastodon_types)
 106   end
 107
 108   defp restrict(query, :account_ap_id, %{account_ap_id: account_ap_id}) do
 109     where(query, [n, a], a.actor == ^account_ap_id)
 110   end
 111
 112   defp restrict(query, _, _), do: query
 113 end