git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug
  13   alias Pleroma.Plugs.OAuthScopesPlug
  14   alias Pleroma.Plugs.RateLimiter
  15   alias Pleroma.User
  16   alias Pleroma.Web.ActivityPub.ActivityPub
  17
  18   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  19   plug(:skip_plug, EnsurePublicOrAuthenticatedPlug when action in [:public, :hashtag])
  20
  21   # TODO: Replace with a macro when there is a Phoenix release with the following commit in it:
  22   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  23
  24   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  25   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  26   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  27   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  28   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  29
  30   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  31   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  32
  33   plug(
  34     OAuthScopesPlug,
  35     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  36     when action in [:public, :hashtag]
  37   )
  38
  39   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  40
  41   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.TimelineOperation
  42
  43   # GET /api/v1/timelines/home
  44   def home(%{assigns: %{user: user}} = conn, params) do
  45     params =
  46       params
  47       |> Map.put(:type, ["Create", "Announce"])
  48       |> Map.put(:blocking_user, user)
  49       |> Map.put(:muting_user, user)
  50       |> Map.put(:reply_filtering_user, user)
  51       |> Map.put(:user, user)
  52
  53     activities =
  54       [user.ap_id | User.following(user)]
  55       |> ActivityPub.fetch_activities(params)
  56       |> Enum.reverse()
  57
  58     conn
  59     |> add_link_headers(activities)
  60     |> render("index.json",
  61       activities: activities,
  62       for: user,
  63       as: :activity
  64     )
  65   end
  66
  67   # GET /api/v1/timelines/direct
  68   def direct(%{assigns: %{user: user}} = conn, params) do
  69     params =
  70       params
  71       |> Map.put(:type, "Create")
  72       |> Map.put(:blocking_user, user)
  73       |> Map.put(:user, user)
  74       |> Map.put(:visibility, "direct")
  75
  76     activities =
  77       [user.ap_id]
  78       |> ActivityPub.fetch_activities_query(params)
  79       |> Pagination.fetch_paginated(params)
  80
  81     conn
  82     |> add_link_headers(activities)
  83     |> render("index.json",
  84       activities: activities,
  85       for: user,
  86       as: :activity
  87     )
  88   end
  89
  90   # GET /api/v1/timelines/public
  91   def public(%{assigns: %{user: user}} = conn, params) do
  92     local_only = params[:local]
  93
  94     cfg_key =
  95       if local_only do
  96         :local
  97       else
  98         :federated
  99       end
 100
 101     restrict? = Pleroma.Config.get([:restrict_unauthenticated, :timelines, cfg_key])
 102
 103     if restrict? and is_nil(user) do
 104       render_error(conn, :unauthorized, "authorization required for timeline view")
 105     else
 106       activities =
 107         params
 108         |> Map.put(:type, ["Create"])
 109         |> Map.put(:local_only, local_only)
 110         |> Map.put(:blocking_user, user)
 111         |> Map.put(:muting_user, user)
 112         |> Map.put(:reply_filtering_user, user)
 113         |> ActivityPub.fetch_public_activities()
 114
 115       conn
 116       |> add_link_headers(activities, %{"local" => local_only})
 117       |> render("index.json",
 118         activities: activities,
 119         for: user,
 120         as: :activity
 121       )
 122     end
 123   end
 124
 125   defp hashtag_fetching(params, user, local_only) do
 126     tags =
 127       [params[:tag], params[:any]]
 128       |> List.flatten()
 129       |> Enum.uniq()
 130       |> Enum.reject(&is_nil/1)
 131       |> Enum.map(&String.downcase/1)
 132
 133     tag_all =
 134       params
 135       |> Map.get(:all, [])
 136       |> Enum.map(&String.downcase/1)
 137
 138     tag_reject =
 139       params
 140       |> Map.get(:none, [])
 141       |> Enum.map(&String.downcase/1)
 142
 143     _activities =
 144       params
 145       |> Map.put(:type, "Create")
 146       |> Map.put(:local_only, local_only)
 147       |> Map.put(:blocking_user, user)
 148       |> Map.put(:muting_user, user)
 149       |> Map.put(:user, user)
 150       |> Map.put(:tag, tags)
 151       |> Map.put(:tag_all, tag_all)
 152       |> Map.put(:tag_reject, tag_reject)
 153       |> ActivityPub.fetch_public_activities()
 154   end
 155
 156   # GET /api/v1/timelines/tag/:tag
 157   def hashtag(%{assigns: %{user: user}} = conn, params) do
 158     local_only = params[:local]
 159     activities = hashtag_fetching(params, user, local_only)
 160
 161     conn
 162     |> add_link_headers(activities, %{"local" => local_only})
 163     |> render("index.json",
 164       activities: activities,
 165       for: user,
 166       as: :activity
 167     )
 168   end
 169
 170   # GET /api/v1/timelines/list/:list_id
 171   def list(%{assigns: %{user: user}} = conn, %{list_id: id} = params) do
 172     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 173       params =
 174         params
 175         |> Map.new(fn {key, value} -> {to_string(key), value} end)
 176         |> Map.put("type", "Create")
 177         |> Map.put("blocking_user", user)
 178         |> Map.put("user", user)
 179         |> Map.put("muting_user", user)
 180
 181       # we must filter the following list for the user to avoid leaking statuses the user
 182       # does not actually have permission to see (for more info, peruse security issue #270).
 183
 184       user_following = User.following(user)
 185
 186       activities =
 187         following
 188         |> Enum.filter(fn x -> x in user_following end)
 189         |> ActivityPub.fetch_activities_bounded(following, params)
 190         |> Enum.reverse()
 191
 192       render(conn, "index.json",
 193         activities: activities,
 194         for: user,
 195         as: :activity
 196       )
 197     else
 198       _e -> render_error(conn, :forbidden, "Error.")
 199     end
 200   end
 201 end