git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug
  13   alias Pleroma.Plugs.OAuthScopesPlug
  14   alias Pleroma.Plugs.RateLimiter
  15   alias Pleroma.User
  16   alias Pleroma.Web.ActivityPub.ActivityPub
  17
  18   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  19   plug(:skip_plug, EnsurePublicOrAuthenticatedPlug when action in [:public, :hashtag])
  20
  21   # TODO: Replace with a macro when there is a Phoenix release with the following commit in it:
  22   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  23
  24   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  25   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  26   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  27   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  28   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  29
  30   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  31   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  32
  33   plug(
  34     OAuthScopesPlug,
  35     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  36     when action in [:public, :hashtag]
  37   )
  38
  39   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  40
  41   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.TimelineOperation
  42
  43   # GET /api/v1/timelines/home
  44   def home(%{assigns: %{user: user}} = conn, params) do
  45     params =
  46       params
  47       |> Map.put(:type, ["Create", "Announce"])
  48       |> Map.put(:blocking_user, user)
  49       |> Map.put(:muting_user, user)
  50       |> Map.put(:reply_filtering_user, user)
  51       |> Map.put(:announce_filtering_user, user)
  52       |> Map.put(:user, user)
  53
  54     activities =
  55       [user.ap_id | User.following(user)]
  56       |> ActivityPub.fetch_activities(params)
  57       |> Enum.reverse()
  58
  59     conn
  60     |> add_link_headers(activities)
  61     |> render("index.json",
  62       activities: activities,
  63       for: user,
  64       as: :activity
  65     )
  66   end
  67
  68   # GET /api/v1/timelines/direct
  69   def direct(%{assigns: %{user: user}} = conn, params) do
  70     params =
  71       params
  72       |> Map.put(:type, "Create")
  73       |> Map.put(:blocking_user, user)
  74       |> Map.put(:user, user)
  75       |> Map.put(:visibility, "direct")
  76
  77     activities =
  78       [user.ap_id]
  79       |> ActivityPub.fetch_activities_query(params)
  80       |> Pagination.fetch_paginated(params)
  81
  82     conn
  83     |> add_link_headers(activities)
  84     |> render("index.json",
  85       activities: activities,
  86       for: user,
  87       as: :activity
  88     )
  89   end
  90
  91   defp restrict_unauthenticated?(true = _local_only) do
  92     Pleroma.Config.get([:restrict_unauthenticated, :timelines, :local])
  93   end
  94
  95   defp restrict_unauthenticated?(_) do
  96     Pleroma.Config.get([:restrict_unauthenticated, :timelines, :federated])
  97   end
  98
  99   # GET /api/v1/timelines/public
 100   def public(%{assigns: %{user: user}} = conn, params) do
 101     local_only = params[:local]
 102
 103     if is_nil(user) and restrict_unauthenticated?(local_only) do
 104       fail_on_bad_auth(conn)
 105     else
 106       activities =
 107         params
 108         |> Map.put(:type, ["Create"])
 109         |> Map.put(:local_only, local_only)
 110         |> Map.put(:blocking_user, user)
 111         |> Map.put(:muting_user, user)
 112         |> Map.put(:reply_filtering_user, user)
 113         |> ActivityPub.fetch_public_activities()
 114
 115       conn
 116       |> add_link_headers(activities, %{"local" => local_only})
 117       |> render("index.json",
 118         activities: activities,
 119         for: user,
 120         as: :activity
 121       )
 122     end
 123   end
 124
 125   defp fail_on_bad_auth(conn) do
 126     render_error(conn, :unauthorized, "authorization required for timeline view")
 127   end
 128
 129   defp hashtag_fetching(params, user, local_only) do
 130     tags =
 131       [params[:tag], params[:any]]
 132       |> List.flatten()
 133       |> Enum.uniq()
 134       |> Enum.reject(&is_nil/1)
 135       |> Enum.map(&String.downcase/1)
 136
 137     tag_all =
 138       params
 139       |> Map.get(:all, [])
 140       |> Enum.map(&String.downcase/1)
 141
 142     tag_reject =
 143       params
 144       |> Map.get(:none, [])
 145       |> Enum.map(&String.downcase/1)
 146
 147     _activities =
 148       params
 149       |> Map.put(:type, "Create")
 150       |> Map.put(:local_only, local_only)
 151       |> Map.put(:blocking_user, user)
 152       |> Map.put(:muting_user, user)
 153       |> Map.put(:user, user)
 154       |> Map.put(:tag, tags)
 155       |> Map.put(:tag_all, tag_all)
 156       |> Map.put(:tag_reject, tag_reject)
 157       |> ActivityPub.fetch_public_activities()
 158   end
 159
 160   # GET /api/v1/timelines/tag/:tag
 161   def hashtag(%{assigns: %{user: user}} = conn, params) do
 162     local_only = params[:local]
 163
 164     if is_nil(user) and restrict_unauthenticated?(local_only) do
 165       fail_on_bad_auth(conn)
 166     else
 167       activities = hashtag_fetching(params, user, local_only)
 168
 169       conn
 170       |> add_link_headers(activities, %{"local" => local_only})
 171       |> render("index.json",
 172         activities: activities,
 173         for: user,
 174         as: :activity
 175       )
 176     end
 177   end
 178
 179   # GET /api/v1/timelines/list/:list_id
 180   def list(%{assigns: %{user: user}} = conn, %{list_id: id} = params) do
 181     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 182       params =
 183         params
 184         |> Map.new(fn {key, value} -> {to_string(key), value} end)
 185         |> Map.put("type", "Create")
 186         |> Map.put("blocking_user", user)
 187         |> Map.put("user", user)
 188         |> Map.put("muting_user", user)
 189
 190       # we must filter the following list for the user to avoid leaking statuses the user
 191       # does not actually have permission to see (for more info, peruse security issue #270).
 192
 193       user_following = User.following(user)
 194
 195       activities =
 196         following
 197         |> Enum.filter(fn x -> x in user_following end)
 198         |> ActivityPub.fetch_activities_bounded(following, params)
 199         |> Enum.reverse()
 200
 201       render(conn, "index.json",
 202         activities: activities,
 203         for: user,
 204         as: :activity
 205       )
 206     else
 207       _e -> render_error(conn, :forbidden, "Error.")
 208     end
 209   end
 210 end