git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.Plugs.RateLimiter
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16
  17   # TODO: Replace with a macro when there is a Phoenix release with
  18   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  19   # in it
  20
  21   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  22   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  23   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  24   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  25   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  26
  27   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  28   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  29
  30   plug(Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug)
  31
  32   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  33
  34   # GET /api/v1/timelines/home
  35   def home(%{assigns: %{user: user}} = conn, params) do
  36     params =
  37       params
  38       |> Map.put("type", ["Create", "Announce"])
  39       |> Map.put("blocking_user", user)
  40       |> Map.put("muting_user", user)
  41       |> Map.put("user", user)
  42
  43     recipients = [user.ap_id | User.following(user)]
  44
  45     activities =
  46       recipients
  47       |> ActivityPub.fetch_activities(params)
  48       |> Enum.reverse()
  49
  50     conn
  51     |> add_link_headers(activities)
  52     |> render("index.json", activities: activities, for: user, as: :activity)
  53   end
  54
  55   # GET /api/v1/timelines/direct
  56   def direct(%{assigns: %{user: user}} = conn, params) do
  57     params =
  58       params
  59       |> Map.put("type", "Create")
  60       |> Map.put("blocking_user", user)
  61       |> Map.put("user", user)
  62       |> Map.put(:visibility, "direct")
  63
  64     activities =
  65       [user.ap_id]
  66       |> ActivityPub.fetch_activities_query(params)
  67       |> Pagination.fetch_paginated(params)
  68
  69     conn
  70     |> add_link_headers(activities)
  71     |> render("index.json", activities: activities, for: user, as: :activity)
  72   end
  73
  74   # GET /api/v1/timelines/public
  75   def public(%{assigns: %{user: user}} = conn, params) do
  76     local_only = truthy_param?(params["local"])
  77
  78     activities =
  79       params
  80       |> Map.put("type", ["Create", "Announce"])
  81       |> Map.put("local_only", local_only)
  82       |> Map.put("blocking_user", user)
  83       |> Map.put("muting_user", user)
  84       |> ActivityPub.fetch_public_activities()
  85
  86     conn
  87     |> add_link_headers(activities, %{"local" => local_only})
  88     |> render("index.json", activities: activities, for: user, as: :activity)
  89   end
  90
  91   def hashtag_fetching(params, user, local_only) do
  92     tags =
  93       [params["tag"], params["any"]]
  94       |> List.flatten()
  95       |> Enum.uniq()
  96       |> Enum.filter(& &1)
  97       |> Enum.map(&String.downcase(&1))
  98
  99     tag_all =
 100       params
 101       |> Map.get("all", [])
 102       |> Enum.map(&String.downcase(&1))
 103
 104     tag_reject =
 105       params
 106       |> Map.get("none", [])
 107       |> Enum.map(&String.downcase(&1))
 108
 109     _activities =
 110       params
 111       |> Map.put("type", "Create")
 112       |> Map.put("local_only", local_only)
 113       |> Map.put("blocking_user", user)
 114       |> Map.put("muting_user", user)
 115       |> Map.put("user", user)
 116       |> Map.put("tag", tags)
 117       |> Map.put("tag_all", tag_all)
 118       |> Map.put("tag_reject", tag_reject)
 119       |> ActivityPub.fetch_public_activities()
 120   end
 121
 122   # GET /api/v1/timelines/tag/:tag
 123   def hashtag(%{assigns: %{user: user}} = conn, params) do
 124     local_only = truthy_param?(params["local"])
 125
 126     activities = hashtag_fetching(params, user, local_only)
 127
 128     conn
 129     |> add_link_headers(activities, %{"local" => local_only})
 130     |> render("index.json", activities: activities, for: user, as: :activity)
 131   end
 132
 133   # GET /api/v1/timelines/list/:list_id
 134   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 135     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 136       params =
 137         params
 138         |> Map.put("type", "Create")
 139         |> Map.put("blocking_user", user)
 140         |> Map.put("user", user)
 141         |> Map.put("muting_user", user)
 142
 143       # we must filter the following list for the user to avoid leaking statuses the user
 144       # does not actually have permission to see (for more info, peruse security issue #270).
 145
 146       user_following = User.following(user)
 147
 148       activities =
 149         following
 150         |> Enum.filter(fn x -> x in user_following end)
 151         |> ActivityPub.fetch_activities_bounded(following, params)
 152         |> Enum.reverse()
 153
 154       render(conn, "index.json", activities: activities, for: user, as: :activity)
 155     else
 156       _e -> render_error(conn, :forbidden, "Error.")
 157     end
 158   end
 159 end