git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1, skip_relationships?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug
  13   alias Pleroma.Plugs.OAuthScopesPlug
  14   alias Pleroma.Plugs.RateLimiter
  15   alias Pleroma.User
  16   alias Pleroma.Web.ActivityPub.ActivityPub
  17
  18   plug(:skip_plug, EnsurePublicOrAuthenticatedPlug when action in [:public, :hashtag])
  19
  20   # TODO: Replace with a macro when there is a Phoenix release with the following commit in it:
  21   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  22
  23   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  24   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  25   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  26   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  27   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  28
  29   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  30   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  31
  32   plug(
  33     OAuthScopesPlug,
  34     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  35     when action in [:public, :hashtag]
  36   )
  37
  38   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  39
  40   # GET /api/v1/timelines/home
  41   def home(%{assigns: %{user: user}} = conn, params) do
  42     params =
  43       params
  44       |> Map.put("type", ["Create", "Announce"])
  45       |> Map.put("blocking_user", user)
  46       |> Map.put("muting_user", user)
  47       |> Map.put("reply_filtering_user", user)
  48       |> Map.put("user", user)
  49
  50     recipients = [user.ap_id | User.following(user)]
  51
  52     activities =
  53       recipients
  54       |> ActivityPub.fetch_activities(params)
  55       |> Enum.reverse()
  56
  57     conn
  58     |> add_link_headers(activities)
  59     |> render("index.json",
  60       activities: activities,
  61       for: user,
  62       as: :activity,
  63       skip_relationships: skip_relationships?(params)
  64     )
  65   end
  66
  67   # GET /api/v1/timelines/direct
  68   def direct(%{assigns: %{user: user}} = conn, params) do
  69     params =
  70       params
  71       |> Map.put("type", "Create")
  72       |> Map.put("blocking_user", user)
  73       |> Map.put("user", user)
  74       |> Map.put(:visibility, "direct")
  75
  76     activities =
  77       [user.ap_id]
  78       |> ActivityPub.fetch_activities_query(params)
  79       |> Pagination.fetch_paginated(params)
  80
  81     conn
  82     |> add_link_headers(activities)
  83     |> render("index.json",
  84       activities: activities,
  85       for: user,
  86       as: :activity,
  87       skip_relationships: skip_relationships?(params)
  88     )
  89   end
  90
  91   # GET /api/v1/timelines/public
  92   def public(%{assigns: %{user: user}} = conn, params) do
  93     local_only = truthy_param?(params["local"])
  94
  95     cfg_key =
  96       if local_only do
  97         :local
  98       else
  99         :federated
 100       end
 101
 102     restrict? = Pleroma.Config.get([:restrict_unauthenticated, :timelines, cfg_key])
 103
 104     if restrict? and is_nil(user) do
 105       render_error(conn, :unauthorized, "authorization required for timeline view")
 106     else
 107       activities =
 108         params
 109         |> Map.put("type", ["Create", "Announce"])
 110         |> Map.put("local_only", local_only)
 111         |> Map.put("blocking_user", user)
 112         |> Map.put("muting_user", user)
 113         |> Map.put("reply_filtering_user", user)
 114         |> ActivityPub.fetch_public_activities()
 115
 116       conn
 117       |> add_link_headers(activities, %{"local" => local_only})
 118       |> render("index.json",
 119         activities: activities,
 120         for: user,
 121         as: :activity,
 122         skip_relationships: skip_relationships?(params)
 123       )
 124     end
 125   end
 126
 127   defp hashtag_fetching(params, user, local_only) do
 128     tags =
 129       [params["tag"], params["any"]]
 130       |> List.flatten()
 131       |> Enum.uniq()
 132       |> Enum.filter(& &1)
 133       |> Enum.map(&String.downcase(&1))
 134
 135     tag_all =
 136       params
 137       |> Map.get("all", [])
 138       |> Enum.map(&String.downcase(&1))
 139
 140     tag_reject =
 141       params
 142       |> Map.get("none", [])
 143       |> Enum.map(&String.downcase(&1))
 144
 145     _activities =
 146       params
 147       |> Map.put("type", "Create")
 148       |> Map.put("local_only", local_only)
 149       |> Map.put("blocking_user", user)
 150       |> Map.put("muting_user", user)
 151       |> Map.put("user", user)
 152       |> Map.put("tag", tags)
 153       |> Map.put("tag_all", tag_all)
 154       |> Map.put("tag_reject", tag_reject)
 155       |> ActivityPub.fetch_public_activities()
 156   end
 157
 158   # GET /api/v1/timelines/tag/:tag
 159   def hashtag(%{assigns: %{user: user}} = conn, params) do
 160     local_only = truthy_param?(params["local"])
 161
 162     activities = hashtag_fetching(params, user, local_only)
 163
 164     conn
 165     |> add_link_headers(activities, %{"local" => local_only})
 166     |> render("index.json",
 167       activities: activities,
 168       for: user,
 169       as: :activity,
 170       skip_relationships: skip_relationships?(params)
 171     )
 172   end
 173
 174   # GET /api/v1/timelines/list/:list_id
 175   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 176     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 177       params =
 178         params
 179         |> Map.put("type", "Create")
 180         |> Map.put("blocking_user", user)
 181         |> Map.put("user", user)
 182         |> Map.put("muting_user", user)
 183
 184       # we must filter the following list for the user to avoid leaking statuses the user
 185       # does not actually have permission to see (for more info, peruse security issue #270).
 186
 187       user_following = User.following(user)
 188
 189       activities =
 190         following
 191         |> Enum.filter(fn x -> x in user_following end)
 192         |> ActivityPub.fetch_activities_bounded(following, params)
 193         |> Enum.reverse()
 194
 195       render(conn, "index.json",
 196         activities: activities,
 197         for: user,
 198         as: :activity,
 199         skip_relationships: skip_relationships?(params)
 200       )
 201     else
 202       _e -> render_error(conn, :forbidden, "Error.")
 203     end
 204   end
 205 end