git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ActivityPub
  15
  16   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  17   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  18
  19   plug(Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug)
  20
  21   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  22
  23   # GET /api/v1/timelines/home
  24   def home(%{assigns: %{user: user}} = conn, params) do
  25     params =
  26       params
  27       |> Map.put("type", ["Create", "Announce"])
  28       |> Map.put("blocking_user", user)
  29       |> Map.put("muting_user", user)
  30       |> Map.put("user", user)
  31
  32     recipients = [user.ap_id | User.following(user)]
  33
  34     activities =
  35       recipients
  36       |> ActivityPub.fetch_activities(params)
  37       |> Enum.reverse()
  38
  39     conn
  40     |> add_link_headers(activities)
  41     |> render("index.json", activities: activities, for: user, as: :activity)
  42   end
  43
  44   # GET /api/v1/timelines/direct
  45   def direct(%{assigns: %{user: user}} = conn, params) do
  46     params =
  47       params
  48       |> Map.put("type", "Create")
  49       |> Map.put("blocking_user", user)
  50       |> Map.put("user", user)
  51       |> Map.put(:visibility, "direct")
  52
  53     activities =
  54       [user.ap_id]
  55       |> ActivityPub.fetch_activities_query(params)
  56       |> Pagination.fetch_paginated(params)
  57
  58     conn
  59     |> add_link_headers(activities)
  60     |> render("index.json", activities: activities, for: user, as: :activity)
  61   end
  62
  63   # GET /api/v1/timelines/public
  64   def public(%{assigns: %{user: user}} = conn, params) do
  65     local_only = truthy_param?(params["local"])
  66
  67     activities =
  68       params
  69       |> Map.put("type", ["Create", "Announce"])
  70       |> Map.put("local_only", local_only)
  71       |> Map.put("blocking_user", user)
  72       |> Map.put("muting_user", user)
  73       |> ActivityPub.fetch_public_activities()
  74       |> Enum.reverse()
  75
  76     conn
  77     |> add_link_headers(activities, %{"local" => local_only})
  78     |> render("index.json", activities: activities, for: user, as: :activity)
  79   end
  80
  81   # GET /api/v1/timelines/tag/:tag
  82   def hashtag(%{assigns: %{user: user}} = conn, params) do
  83     local_only = truthy_param?(params["local"])
  84
  85     tags =
  86       [params["tag"], params["any"]]
  87       |> List.flatten()
  88       |> Enum.uniq()
  89       |> Enum.filter(& &1)
  90       |> Enum.map(&String.downcase(&1))
  91
  92     tag_all =
  93       params
  94       |> Map.get("all", [])
  95       |> Enum.map(&String.downcase(&1))
  96
  97     tag_reject =
  98       params
  99       |> Map.get("none", [])
 100       |> Enum.map(&String.downcase(&1))
 101
 102     activities =
 103       params
 104       |> Map.put("type", "Create")
 105       |> Map.put("local_only", local_only)
 106       |> Map.put("blocking_user", user)
 107       |> Map.put("muting_user", user)
 108       |> Map.put("user", user)
 109       |> Map.put("tag", tags)
 110       |> Map.put("tag_all", tag_all)
 111       |> Map.put("tag_reject", tag_reject)
 112       |> ActivityPub.fetch_public_activities()
 113       |> Enum.reverse()
 114
 115     conn
 116     |> add_link_headers(activities, %{"local" => local_only})
 117     |> render("index.json", activities: activities, for: user, as: :activity)
 118   end
 119
 120   # GET /api/v1/timelines/list/:list_id
 121   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 122     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 123       params =
 124         params
 125         |> Map.put("type", "Create")
 126         |> Map.put("blocking_user", user)
 127         |> Map.put("user", user)
 128         |> Map.put("muting_user", user)
 129
 130       # we must filter the following list for the user to avoid leaking statuses the user
 131       # does not actually have permission to see (for more info, peruse security issue #270).
 132
 133       user_following = User.following(user)
 134
 135       activities =
 136         following
 137         |> Enum.filter(fn x -> x in user_following end)
 138         |> ActivityPub.fetch_activities_bounded(following, params)
 139         |> Enum.reverse()
 140
 141       render(conn, "index.json", activities: activities, for: user, as: :activity)
 142     else
 143       _e -> render_error(conn, :forbidden, "Error.")
 144     end
 145   end
 146 end