git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Web.ActivityPub.ActivityPub
  13
  14   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  15
  16   # GET /api/v1/timelines/home
  17   def home(%{assigns: %{user: user}} = conn, params) do
  18     params =
  19       params
  20       |> Map.put("type", ["Create", "Announce"])
  21       |> Map.put("blocking_user", user)
  22       |> Map.put("muting_user", user)
  23       |> Map.put("user", user)
  24
  25     recipients = [user.ap_id | user.following]
  26
  27     activities =
  28       recipients
  29       |> ActivityPub.fetch_activities(params)
  30       |> Enum.reverse()
  31
  32     conn
  33     |> add_link_headers(activities)
  34     |> render("index.json", activities: activities, for: user, as: :activity)
  35   end
  36
  37   # GET /api/v1/timelines/direct
  38   def direct(%{assigns: %{user: user}} = conn, params) do
  39     params =
  40       params
  41       |> Map.put("type", "Create")
  42       |> Map.put("blocking_user", user)
  43       |> Map.put("user", user)
  44       |> Map.put(:visibility, "direct")
  45
  46     activities =
  47       [user.ap_id]
  48       |> ActivityPub.fetch_activities_query(params)
  49       |> Pagination.fetch_paginated(params)
  50
  51     conn
  52     |> add_link_headers(activities)
  53     |> render("index.json", activities: activities, for: user, as: :activity)
  54   end
  55
  56   # GET /api/v1/timelines/public
  57   def public(%{assigns: %{user: user}} = conn, params) do
  58     local_only = truthy_param?(params["local"])
  59
  60     activities =
  61       params
  62       |> Map.put("type", ["Create", "Announce"])
  63       |> Map.put("local_only", local_only)
  64       |> Map.put("blocking_user", user)
  65       |> Map.put("muting_user", user)
  66       |> ActivityPub.fetch_public_activities()
  67       |> Enum.reverse()
  68
  69     conn
  70     |> add_link_headers(activities, %{"local" => local_only})
  71     |> render("index.json", activities: activities, for: user, as: :activity)
  72   end
  73
  74   # GET /api/v1/timelines/tag/:tag
  75   def hashtag(%{assigns: %{user: user}} = conn, params) do
  76     local_only = truthy_param?(params["local"])
  77
  78     tags =
  79       [params["tag"], params["any"]]
  80       |> List.flatten()
  81       |> Enum.uniq()
  82       |> Enum.filter(& &1)
  83       |> Enum.map(&String.downcase(&1))
  84
  85     tag_all =
  86       params
  87       |> Map.get("all", [])
  88       |> Enum.map(&String.downcase(&1))
  89
  90     tag_reject =
  91       params
  92       |> Map.get("none", [])
  93       |> Enum.map(&String.downcase(&1))
  94
  95     activities =
  96       params
  97       |> Map.put("type", "Create")
  98       |> Map.put("local_only", local_only)
  99       |> Map.put("blocking_user", user)
 100       |> Map.put("muting_user", user)
 101       |> Map.put("user", user)
 102       |> Map.put("tag", tags)
 103       |> Map.put("tag_all", tag_all)
 104       |> Map.put("tag_reject", tag_reject)
 105       |> ActivityPub.fetch_public_activities()
 106       |> Enum.reverse()
 107
 108     conn
 109     |> add_link_headers(activities, %{"local" => local_only})
 110     |> render("index.json", activities: activities, for: user, as: :activity)
 111   end
 112
 113   # GET /api/v1/timelines/list/:list_id
 114   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 115     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 116       params =
 117         params
 118         |> Map.put("type", "Create")
 119         |> Map.put("blocking_user", user)
 120         |> Map.put("user", user)
 121         |> Map.put("muting_user", user)
 122
 123       # we must filter the following list for the user to avoid leaking statuses the user
 124       # does not actually have permission to see (for more info, peruse security issue #270).
 125       activities =
 126         following
 127         |> Enum.filter(fn x -> x in user.following end)
 128         |> ActivityPub.fetch_activities_bounded(following, params)
 129         |> Enum.reverse()
 130
 131       render(conn, "index.json", activities: activities, for: user, as: :activity)
 132     else
 133       _e -> render_error(conn, :forbidden, "Error.")
 134     end
 135   end
 136 end