git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14
  15   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  16   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  17
  18   plug(Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug)
  19
  20   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  21
  22   # GET /api/v1/timelines/home
  23   def home(%{assigns: %{user: user}} = conn, params) do
  24     params =
  25       params
  26       |> Map.put("type", ["Create", "Announce"])
  27       |> Map.put("blocking_user", user)
  28       |> Map.put("muting_user", user)
  29       |> Map.put("user", user)
  30
  31     recipients = [user.ap_id | user.following]
  32
  33     activities =
  34       recipients
  35       |> ActivityPub.fetch_activities(params)
  36       |> Enum.reverse()
  37
  38     conn
  39     |> add_link_headers(activities)
  40     |> render("index.json", activities: activities, for: user, as: :activity)
  41   end
  42
  43   # GET /api/v1/timelines/direct
  44   def direct(%{assigns: %{user: user}} = conn, params) do
  45     params =
  46       params
  47       |> Map.put("type", "Create")
  48       |> Map.put("blocking_user", user)
  49       |> Map.put("user", user)
  50       |> Map.put(:visibility, "direct")
  51
  52     activities =
  53       [user.ap_id]
  54       |> ActivityPub.fetch_activities_query(params)
  55       |> Pagination.fetch_paginated(params)
  56
  57     conn
  58     |> add_link_headers(activities)
  59     |> render("index.json", activities: activities, for: user, as: :activity)
  60   end
  61
  62   # GET /api/v1/timelines/public
  63   def public(%{assigns: %{user: user}} = conn, params) do
  64     local_only = truthy_param?(params["local"])
  65
  66     activities =
  67       params
  68       |> Map.put("type", ["Create", "Announce"])
  69       |> Map.put("local_only", local_only)
  70       |> Map.put("blocking_user", user)
  71       |> Map.put("muting_user", user)
  72       |> ActivityPub.fetch_public_activities()
  73       |> Enum.reverse()
  74
  75     conn
  76     |> add_link_headers(activities, %{"local" => local_only})
  77     |> render("index.json", activities: activities, for: user, as: :activity)
  78   end
  79
  80   # GET /api/v1/timelines/tag/:tag
  81   def hashtag(%{assigns: %{user: user}} = conn, params) do
  82     local_only = truthy_param?(params["local"])
  83
  84     tags =
  85       [params["tag"], params["any"]]
  86       |> List.flatten()
  87       |> Enum.uniq()
  88       |> Enum.filter(& &1)
  89       |> Enum.map(&String.downcase(&1))
  90
  91     tag_all =
  92       params
  93       |> Map.get("all", [])
  94       |> Enum.map(&String.downcase(&1))
  95
  96     tag_reject =
  97       params
  98       |> Map.get("none", [])
  99       |> Enum.map(&String.downcase(&1))
 100
 101     activities =
 102       params
 103       |> Map.put("type", "Create")
 104       |> Map.put("local_only", local_only)
 105       |> Map.put("blocking_user", user)
 106       |> Map.put("muting_user", user)
 107       |> Map.put("user", user)
 108       |> Map.put("tag", tags)
 109       |> Map.put("tag_all", tag_all)
 110       |> Map.put("tag_reject", tag_reject)
 111       |> ActivityPub.fetch_public_activities()
 112       |> Enum.reverse()
 113
 114     conn
 115     |> add_link_headers(activities, %{"local" => local_only})
 116     |> render("index.json", activities: activities, for: user, as: :activity)
 117   end
 118
 119   # GET /api/v1/timelines/list/:list_id
 120   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 121     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 122       params =
 123         params
 124         |> Map.put("type", "Create")
 125         |> Map.put("blocking_user", user)
 126         |> Map.put("user", user)
 127         |> Map.put("muting_user", user)
 128
 129       # we must filter the following list for the user to avoid leaking statuses the user
 130       # does not actually have permission to see (for more info, peruse security issue #270).
 131       activities =
 132         following
 133         |> Enum.filter(fn x -> x in user.following end)
 134         |> ActivityPub.fetch_activities_bounded(following, params)
 135         |> Enum.reverse()
 136
 137       render(conn, "index.json", activities: activities, for: user, as: :activity)
 138     else
 139       _e -> render_error(conn, :forbidden, "Error.")
 140     end
 141   end
 142 end