git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.Plugs.RateLimiter
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16
  17   # TODO: Replace with a macro when there is a Phoenix release with
  18   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  19   # in it
  20
  21   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  22   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  23   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  24   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  25   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  26
  27   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  28   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  29
  30   plug(Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug when action != :public)
  31
  32   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  33
  34   # GET /api/v1/timelines/home
  35   def home(%{assigns: %{user: user}} = conn, params) do
  36     params =
  37       params
  38       |> Map.put("type", ["Create", "Announce"])
  39       |> Map.put("blocking_user", user)
  40       |> Map.put("muting_user", user)
  41       |> Map.put("user", user)
  42
  43     recipients = [user.ap_id | User.following(user)]
  44
  45     activities =
  46       recipients
  47       |> ActivityPub.fetch_activities(params)
  48       |> Enum.reverse()
  49
  50     conn
  51     |> add_link_headers(activities)
  52     |> render("index.json", activities: activities, for: user, as: :activity)
  53   end
  54
  55   # GET /api/v1/timelines/direct
  56   def direct(%{assigns: %{user: user}} = conn, params) do
  57     params =
  58       params
  59       |> Map.put("type", "Create")
  60       |> Map.put("blocking_user", user)
  61       |> Map.put("user", user)
  62       |> Map.put(:visibility, "direct")
  63
  64     activities =
  65       [user.ap_id]
  66       |> ActivityPub.fetch_activities_query(params)
  67       |> Pagination.fetch_paginated(params)
  68
  69     conn
  70     |> add_link_headers(activities)
  71     |> render("index.json", activities: activities, for: user, as: :activity)
  72   end
  73
  74   # GET /api/v1/timelines/public
  75   def public(%{assigns: %{user: user}} = conn, params) do
  76     local_only = truthy_param?(params["local"])
  77
  78     cfg_key =
  79       if local_only do
  80         :local
  81       else
  82         :federated
  83       end
  84
  85     restrict? = Pleroma.Config.get([:restrict_unauthenticated, :timelines, cfg_key])
  86
  87     if not (restrict? and is_nil(user)) do
  88       activities =
  89         params
  90         |> Map.put("type", ["Create", "Announce"])
  91         |> Map.put("local_only", local_only)
  92         |> Map.put("blocking_user", user)
  93         |> Map.put("muting_user", user)
  94         |> ActivityPub.fetch_public_activities()
  95
  96       conn
  97       |> add_link_headers(activities, %{"local" => local_only})
  98       |> render("index.json", activities: activities, for: user, as: :activity)
  99     else
 100       render_error(conn, :unauthorized, "authorization required for timeline view")
 101     end
 102   end
 103
 104   def hashtag_fetching(params, user, local_only) do
 105     tags =
 106       [params["tag"], params["any"]]
 107       |> List.flatten()
 108       |> Enum.uniq()
 109       |> Enum.filter(& &1)
 110       |> Enum.map(&String.downcase(&1))
 111
 112     tag_all =
 113       params
 114       |> Map.get("all", [])
 115       |> Enum.map(&String.downcase(&1))
 116
 117     tag_reject =
 118       params
 119       |> Map.get("none", [])
 120       |> Enum.map(&String.downcase(&1))
 121
 122     _activities =
 123       params
 124       |> Map.put("type", "Create")
 125       |> Map.put("local_only", local_only)
 126       |> Map.put("blocking_user", user)
 127       |> Map.put("muting_user", user)
 128       |> Map.put("user", user)
 129       |> Map.put("tag", tags)
 130       |> Map.put("tag_all", tag_all)
 131       |> Map.put("tag_reject", tag_reject)
 132       |> ActivityPub.fetch_public_activities()
 133   end
 134
 135   # GET /api/v1/timelines/tag/:tag
 136   def hashtag(%{assigns: %{user: user}} = conn, params) do
 137     local_only = truthy_param?(params["local"])
 138
 139     activities = hashtag_fetching(params, user, local_only)
 140
 141     conn
 142     |> add_link_headers(activities, %{"local" => local_only})
 143     |> render("index.json", activities: activities, for: user, as: :activity)
 144   end
 145
 146   # GET /api/v1/timelines/list/:list_id
 147   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 148     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 149       params =
 150         params
 151         |> Map.put("type", "Create")
 152         |> Map.put("blocking_user", user)
 153         |> Map.put("user", user)
 154         |> Map.put("muting_user", user)
 155
 156       # we must filter the following list for the user to avoid leaking statuses the user
 157       # does not actually have permission to see (for more info, peruse security issue #270).
 158
 159       user_following = User.following(user)
 160
 161       activities =
 162         following
 163         |> Enum.filter(fn x -> x in user_following end)
 164         |> ActivityPub.fetch_activities_bounded(following, params)
 165         |> Enum.reverse()
 166
 167       render(conn, "index.json", activities: activities, for: user, as: :activity)
 168     else
 169       _e -> render_error(conn, :forbidden, "Error.")
 170     end
 171   end
 172 end