git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3]
  10
  11   alias Pleroma.Config
  12   alias Pleroma.Pagination
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ActivityPub
  15   alias Pleroma.Web.Plugs.EnsurePublicOrAuthenticatedPlug
  16   alias Pleroma.Web.Plugs.OAuthScopesPlug
  17   alias Pleroma.Web.Plugs.RateLimiter
  18
  19   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  20   plug(:skip_plug, EnsurePublicOrAuthenticatedPlug when action in [:public, :hashtag])
  21
  22   # TODO: Replace with a macro when there is a Phoenix release with the following commit in it:
  23   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  24
  25   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  26   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  27   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  28   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  29   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  30
  31   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  32   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  33
  34   plug(
  35     OAuthScopesPlug,
  36     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  37     when action in [:public, :hashtag]
  38   )
  39
  40   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.TimelineOperation
  41
  42   # GET /api/v1/timelines/home
  43   def home(%{assigns: %{user: user}} = conn, params) do
  44     params =
  45       params
  46       |> Map.put(:type, ["Create", "Announce"])
  47       |> Map.put(:blocking_user, user)
  48       |> Map.put(:muting_user, user)
  49       |> Map.put(:reply_filtering_user, user)
  50       |> Map.put(:announce_filtering_user, user)
  51       |> Map.put(:user, user)
  52       |> Map.put(:local_only, params[:local])
  53       |> Map.delete(:local)
  54
  55     activities =
  56       [user.ap_id | User.following(user)]
  57       |> ActivityPub.fetch_activities(params)
  58       |> Enum.reverse()
  59
  60     conn
  61     |> add_link_headers(activities)
  62     |> render("index.json",
  63       activities: activities,
  64       for: user,
  65       as: :activity,
  66       with_muted: Map.get(params, :with_muted, false)
  67     )
  68   end
  69
  70   # GET /api/v1/timelines/direct
  71   def direct(%{assigns: %{user: user}} = conn, params) do
  72     params =
  73       params
  74       |> Map.put(:type, "Create")
  75       |> Map.put(:blocking_user, user)
  76       |> Map.put(:user, user)
  77       |> Map.put(:visibility, "direct")
  78
  79     activities =
  80       [user.ap_id]
  81       |> ActivityPub.fetch_activities_query(params)
  82       |> Pagination.fetch_paginated(params)
  83
  84     conn
  85     |> add_link_headers(activities)
  86     |> render("index.json",
  87       activities: activities,
  88       for: user,
  89       as: :activity
  90     )
  91   end
  92
  93   defp restrict_unauthenticated?(true = _local_only) do
  94     Config.restrict_unauthenticated_access?(:timelines, :local)
  95   end
  96
  97   defp restrict_unauthenticated?(_) do
  98     Config.restrict_unauthenticated_access?(:timelines, :federated)
  99   end
 100
 101   # GET /api/v1/timelines/public
 102   def public(%{assigns: %{user: user}} = conn, params) do
 103     local_only = params[:local]
 104
 105     if is_nil(user) and restrict_unauthenticated?(local_only) do
 106       fail_on_bad_auth(conn)
 107     else
 108       activities =
 109         params
 110         |> Map.put(:type, ["Create"])
 111         |> Map.put(:local_only, local_only)
 112         |> Map.put(:blocking_user, user)
 113         |> Map.put(:muting_user, user)
 114         |> Map.put(:reply_filtering_user, user)
 115         |> Map.put(:instance, params[:instance])
 116         |> ActivityPub.fetch_public_activities()
 117
 118       conn
 119       |> add_link_headers(activities, %{"local" => local_only})
 120       |> render("index.json",
 121         activities: activities,
 122         for: user,
 123         as: :activity,
 124         with_muted: Map.get(params, :with_muted, false)
 125       )
 126     end
 127   end
 128
 129   defp fail_on_bad_auth(conn) do
 130     render_error(conn, :unauthorized, "authorization required for timeline view")
 131   end
 132
 133   defp hashtag_fetching(params, user, local_only) do
 134     # Note: not sanitizing tag options at this stage (may be mix-cased, have duplicates etc.)
 135     tags_any =
 136       [params[:tag], params[:any]]
 137       |> List.flatten()
 138       |> Enum.filter(& &1)
 139
 140     tag_all = Map.get(params, :all, [])
 141     tag_reject = Map.get(params, :none, [])
 142
 143     params
 144     |> Map.put(:type, "Create")
 145     |> Map.put(:local_only, local_only)
 146     |> Map.put(:blocking_user, user)
 147     |> Map.put(:muting_user, user)
 148     |> Map.put(:user, user)
 149     |> Map.put(:tag, tags_any)
 150     |> Map.put(:tag_all, tag_all)
 151     |> Map.put(:tag_reject, tag_reject)
 152     |> ActivityPub.fetch_public_activities()
 153   end
 154
 155   # GET /api/v1/timelines/tag/:tag
 156   def hashtag(%{assigns: %{user: user}} = conn, params) do
 157     local_only = params[:local]
 158
 159     if is_nil(user) and restrict_unauthenticated?(local_only) do
 160       fail_on_bad_auth(conn)
 161     else
 162       activities = hashtag_fetching(params, user, local_only)
 163
 164       conn
 165       |> add_link_headers(activities, %{"local" => local_only})
 166       |> render("index.json",
 167         activities: activities,
 168         for: user,
 169         as: :activity,
 170         with_muted: Map.get(params, :with_muted, false)
 171       )
 172     end
 173   end
 174
 175   # GET /api/v1/timelines/list/:list_id
 176   def list(%{assigns: %{user: user}} = conn, %{list_id: id} = params) do
 177     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 178       params =
 179         params
 180         |> Map.put(:type, "Create")
 181         |> Map.put(:blocking_user, user)
 182         |> Map.put(:user, user)
 183         |> Map.put(:muting_user, user)
 184         |> Map.put(:local_only, params[:local])
 185
 186       # we must filter the following list for the user to avoid leaking statuses the user
 187       # does not actually have permission to see (for more info, peruse security issue #270).
 188
 189       user_following = User.following(user)
 190
 191       activities =
 192         following
 193         |> Enum.filter(fn x -> x in user_following end)
 194         |> ActivityPub.fetch_activities_bounded(following, params)
 195         |> Enum.reverse()
 196
 197       render(conn, "index.json",
 198         activities: activities,
 199         for: user,
 200         as: :activity,
 201         with_muted: Map.get(params, :with_muted, false)
 202       )
 203     else
 204       _e -> render_error(conn, :forbidden, "Error.")
 205     end
 206   end
 207 end